[arduino] Topic Unique blabla @ Arduino

Recherche :

Mot : Pseudo : Filtrer Aller à la page :
Page : 1 2 3 4 5 .. 166 167 168 .. 266 267 268 269 270 271 Page Suivante Page Précédente Bas de page
Auteur	Sujet : [arduino] Topic Unique blabla @ Arduino

hush hush

je savais que ça te plairait

Reprise du message précédent :
[:eponge]

SuperSic a écrit :

:hello:

- Il a le matos de base pour l'électronique (fer à souder, étain, breadboard, ... ) ?
- niveau capteur, temperature + humidité, c'est le meme capteur (DHT22 de mémoire). Tu peux y ajouter un capteur pour vérifier l'humidité du sol
- concernant "sur un écran à distance dans la maison ou dans la serre", ça dépend aussi de la distance serre-maison

J'ai pris ça pour commencer: https://www.amazon.fr/gp/product/B0 [...] UTF8&psc=1
Y a pas mal de capteurs et composants pour débuter et tout le matos pour prototyper (breadboard, cables...)
ça fait quelques jours que je l'ai reçu et pour le moment, j'en suis très content (y a pas mal de doc et examples de projets avec chaque composants)

Je pense que ça te coutera aussi cher que d'acheter uniquement les composants dont il aura besoin

Publicité

PierrotLeDingue

Yes we KANTE !

Merci. Bon après tout vu que c'est pour se lancer autant apprendre les bases avec un kit. C'est pas plus mal.

hyperboleske

Bonjour

Je reviens avec mon petit projet de serre et je butte sur un truc qui est, je pense, pourtant tout con.

L'idée est d'allumer progressivement le ruban LED pour simuler le lever de soleil et l'éteindre progressivement pour le coucher de soleil.
Ca, c'est bon, j'y arrive en utilisant un module RTC.
Cependant, j'essaye de prendre en compte l'allumage si je branche tout le bouzin en pleine journée.

Dans le code ci-dessous, j'ai retiré tout ce qui ne concerne pas l'éclairage (je n'ai pas mis les fonctions ON/OFF progressif non plus pour plus de visibilité)

Donc, le problème que je n'arrive pas à résoude, c'est dans le void setup(). Comment faire pour voir si je me trouve après l'heure programmée d'allumage et avant l'heure programmée d'extinction ? Pour le moment, j'utilise un if mais uniquement sur l'heure, pas sur une précision de la partie minute.

En fonctionnement nominal :
Quand le programme détecte que heure=7 et minute=30, alors il lance l'allumage.
Quand le programme détecte que heure=19 et minute=00, alors il lance l'extinction.

QUand je branche l'arduino, il déroule donc le void setup() :
- Si heure est > 7 et heure < ou = à 19 alors il lance l'allumage.

et ce que j'aimerai arrive pas à faire ça :
- Si heure est > 7 avec minute >30 et heure <ou= à 19 avec minute <ou=15, alors il lance l'allumage.

Code :

int StartHeure = 7; //heure de démarrage des LEDs
int StartMin = 30; //minutes de démarrage des LEDs
int EndHeure = 19; //heure extinction des LEDs
int EndMin = 15; //minutes extinction des LEDs
void setup() {
Serial.begin(9600); // Start Serial
tmElements_t tm;
if (RTC.read(tm)) {
if ((tm.Hour>StartHeure) && (tm.Hour<=EndHeure)){ //Allumage d'un coup si on branche le systeme en pleine journée
LightsON();
}
}
}
void loop() {
tmElements_t tm;
SendDataToDomoticz();
if (RTC.read(tm)) {//--> Début de la boucle qui check l'heure pour allumer et eteindre le ruban LED
if ((tm.Hour==StartHeure) && (tm.Minute==StartMin)){ //Allumage de la lumiere a partir de 7h30 le matin
LightsON();
}
else if ((tm.Hour==EndHeure) && (tm.Minute==EndMin)){ //Extinction de la lumiere a partir de 19h30 le soir
LightsOFF();
}
}//<-- Fin de la boucle qui check l'heure pour allumer et eteindre le ruban LED
delay(2000);
}

Sinon pour le reste, je suis assez content pour le moment.
L'arduino se connecte via le port USB (série) au RPi 0 sur lequel un script .py vient récupérer les différentes infos et les envoie à mon serveur domoticz :
- Humidité ambiante
- Température ambiante
- humidité de la terre (quoi qu'il faille que je comprenne l'unité de mesure renvoyée par cette sonde)
- état ON/OFF/Lever de soleil/coucher de soleil du ruban LED
- Valeur d'intensité que j'applique à l'éclairage (pour voir où j'en sui dans l'éclairage
- Image de la webcam (mais ça, c'est directement sur le RPi)
Je ne me suis pas encore attaqué à la pompe à eau. Il faut que je regarde comment traiter l'info de la sonde d'humidité de la terre.

Message cité 1 fois

ObsydianKenobi

peloton suicida

C'est l'accumulation des if qui te pose souci? J'avoue ne pas trop comprendre ce qui te bloque.

Sinon pour simplifier les comparaisons entre heures, il est plus simple de tout convertir en minutes (Heure de démarrage S 7*60 + 30, S = 450, heure de fin E 19*60 + 15, E = 1155)

Si au démarrage D il est 8h23, bah 8*60+23 D = 503, suffit de comparer que D > S et D < E

Message cité 1 fois

---------------
Long-range goals keep you from being frustrated by short-term failures. RIP VC

hyperboleske

ObsydianKenobi a écrit :

L'accumulation des if ? non, aucun problème avec ça (Après, je suis preneur tous types d'optimisation de code)

Pour tout convertir en minute, j'allais venir en parler. Un collègue vient de me proposer ça aussi :jap:

Nitescent

C'est pas le "<=" qui devrait s'écrire "=<" ou une connerie comme ça ?
Je me fais tout le temps avoir avec ça :fou:

---------------
Photos astro sur Flickr | Observatoire astronomique à distance Youtube

JPlnx

hyperboleske a écrit :

Code :

int StartHeure = 7; //heure de démarrage des LEDs
int StartMin = 30; //minutes de démarrage des LEDs
int EndHeure = 19; //heure extinction des LEDs
int EndMin = 15; //minutes extinction des LEDs
void setup() {
Serial.begin(9600); // Start Serial
tmElements_t tm;
if (RTC.read(tm)) {
if ((tm.Hour>StartHeure) && (tm.Hour<=EndHeure)){ //Allumage d'un coup si on branche le systeme en pleine journée
LightsON();
}
}
}
void loop() {
tmElements_t tm;
SendDataToDomoticz();
if (RTC.read(tm)) {//--> Début de la boucle qui check l'heure pour allumer et eteindre le ruban LED
if ((tm.Hour==StartHeure) && (tm.Minute==StartMin)){ //Allumage de la lumiere a partir de 7h30 le matin
LightsON();
}
else if ((tm.Hour==EndHeure) && (tm.Minute==EndMin)){ //Extinction de la lumiere a partir de 19h30 le soir
LightsOFF();
}
}//<-- Fin de la boucle qui check l'heure pour allumer et eteindre le ruban LED
delay(2000);
}

Je pense que tu peux récrite ta boucle comme ça :

Code :

void loop() {
tmElements_t tm;
SendDataToDomoticz();
if (RTC.read(tm)) {//--> Début de la boucle qui check l'heure pour allumer et eteindre le ruban LED
if ((tm.Hour>=StartHeure) && (tm.Minute>=StartMin) && (tm.Hour<=EndHeure) && (tm.Minute<=EndMin) ){ //Allumage de la lumiere a partir de 7h30 le matin
LightsON();
}
else {
LightsOFF();
}
}//<-- Fin de la boucle qui check l'heure pour allumer et eteindre le ruban LED
delay(2000);
}

L'idée c'est de passer dans les fonctions ON / OFF systématiquement comme ça en pleine journée tu auras le bon état quelle que soit l'heure. Pour plus de lisibilité, je te conseille de sortir le test du if dans une fonction.

tomsoft

A 10h10, ton code ne marche pas

Message cité 1 fois

JPlnx

tomsoft a écrit :

A 10h10, ton code ne marche pas

damned, oui j'ai fait n'importe quoi, je rectifie ça dès que j'ai un peu de dipo :fou:

hyperboleske

Pour moi, à chaque boucle du loop, il va rentrer dans la fonction ON ou OFF tant qu'on est dans la plage horaire, non ?

edit : ok, c'est ce que tu précise.
Et dans cette fonction, je regarde si on est déjà allumé. Si non, alors on mets ON.

je vais sortir le en effet, et faire juste des appels de fonctions dans le void loop() ça sera plus simple à maniper en effet. :jap:

Message édité par hyperboleske le 06-12-2018 à 11:29:54

Publicité

tomsoft

Si tu gardais le fonctionnement en séparant tes heures des minutes faudrait :

Code :

if(heureActuelle > heureAllumage && heureActuelle < heureExtinction){
allumer();
} else if(heureActuelle == heureAllumage && minuteActuelle >= minuteAllumage){
allumer();
} else if (heureActuelle == heureExtinction && minuteActuelle < minuteExtinction){
allumer();
} else {
éteindre();
}

Ca c'est la version très comprehensible.

En version plus compactée ca donne :

Code :

if((heureActuelle > heureAllumage && heureActuelle < heureExtinction) || (heureActuelle == heureAllumage && minuteActuelle >= minuteAllumage) || (heureActuelle == heureExtinction && minuteActuelle < minuteExtinction)){
allumer();
} else {
éteindre();
}

hyperboleske

Je vais jouer avec la version compréhensible ce soir pour m'approprier le concept et je passerai à la compact après.
Merci ! :jap:

Message cité 2 fois

JPlnx

hyperboleske a écrit :

Je vais jouer avec la version compréhensible ce soir pour m'approprier le concept et je passerai à la compact après.
Merci ! :jap:

Voilà, le mieux c'est de récrire le truc à ta manière :-) En rectification de mon poste précédent, je t'aurais suggéré un truc comme ça :

Code :

if (( (tm.Hour*60 + tm.Minute) >= (StartHeure*60 + StartMin)
&& (tm.Hour*60 + tm.Minute) < (EndHeure*60 + EndMin)) ) {
allumer();
} else {
éteindre();
}

Message cité 1 fois

SuperSic

hyperboleske a écrit :

Je vais jouer avec la version compréhensible ce soir pour m'approprier le concept et je passerai à la compact après.
Merci ! :jap:

Tu te bases uniquement sur l'heure pour allumer/éteindre ? Tu ne prends pas en compte la luminosité ambiante ?
Accessoirement, je ne suis pas certains que ça soit utile de s'emmerder à allumer/éteindre progressivement le ruban LED. C'est plus respect du cycle jour/nuit qui doit être important pour les plantes.

Message cité 1 fois

---------------
"Les soldats vivent. Et se demandent pourquoi." Toubib (La Compagnie noire) | [TU] Pronomoo

hyperboleske

SuperSic a écrit :

Tu te bases uniquement sur l'heure pour allumer/éteindre ? Tu ne prends pas en compte la luminosité ambiante ?

La serre ne sera pas dans un lieu super éclairé.

SuperSic a écrit :

Accessoirement, je ne suis pas certains que ça soit utile de s'emmerder à allumer/éteindre progressivement le ruban LED. C'est plus respect du cycle jour/nuit qui doit être important pour les plantes.

Pas utile, je ne sais pas. Mais sympa à faire

---------------
Même si la bière est toujours vendue en bouteilles d'une pinte, cela n'entraîne pas que la bière soit constituée de parties indivisibles d'une pinte chacune.

hyperboleske

JPlnx a écrit :

Voilà, le mieux c'est de récrire le truc à ta manière :-) En rectification de mon poste précédent, je t'aurais suggéré un truc comme ça :

Code :

if (( (tm.Hour*60 + tm.Minute) >= (StartHeure*60 + StartMin)
&& (tm.Hour*60 + tm.Minute) < (EndHeure*60 + EndMin)) ) {
allumer();
} else {
éteindre();
}

Bon, j'ai pas eu le temps de tester quoique ce soit hier
Du coup je joue avec le code mais au boulot

question à la con : j'enregistre toutes mes valeurs "fixes" dans des variables en début de module. Pour moi c'est plus simple à manipuler pour les retrouver et les modifier surtout si je les utilise à plusieurs endroits. Il n'y a pas de risque particulier à faire comme ça ? (outre le remplissage de la mémoire)

Message cité 1 fois

JPlnx

hyperboleske a écrit :

Clairement c'est pas optimal (mais peut-être que le compilateur est suffisamment malin pour que ça change rien au final).
C'est tout con mais une variable fixe ça s'appelle une constante
Et dans le cas de l'arduino, le plus simple c'est d'utiliser les #defines : http://www.mon-club-elec.fr/pmwiki [...] ain.Define

Message cité 1 fois

Natopsi

☄️Just end it already!☄️

Heureusement le mot clé const est là pour préciser explicitement une constante, et même constexpr en C++ :jap:

Message cité 1 fois

---------------
⚡ACH/VDS⚡HFRCoin◈1435mm⚡

hyperboleske

JPlnx a écrit :

Natopsi a écrit :

Heureusement le mot clé const est là pour préciser explicitement une constante, et même constexpr en C++ :jap:

Merci :jap:
J'ai utilisé pas mal de #define du coup. Mais en modifiant le nom pour être sûr de ne pas remplacer du texte qui ne devrait pas l'être

Je suis passé de ça :

Code :

int pl = 9; //Pin par laquelle est pilotée le ruban LED
int bght = 0; //Initialisation du brightness
int fade = 5; //Incrément utilisé pour allumer et eteindre progressivement les LEDs
int maxlum = 255; //Valeur maximale de la luminosite possible
int minlum = 0; //Valeur minimale de la luminosite possible
int StartHeure = 7; //heure de démarrage des LEDs
int StartMin = 30; //minutes de démarrage des LEDs
int EndHeure = 18; //heure extinction des LEDs
int EndMin = 25; //minutes extinction des LEDs
int PinSoil = A1; //sélection de la pin de mesure du capteur d'humidité de sol
int SensorSoil = 0; //initialisation de la valeur du capteur d'humidité de sol
int etatLEDS = 0; //initialisation de la variable qui indique a domoticz l'etat du ruban LED
int lever = 10; //Envoi 10 à domoticz pour indiquer que c'est le lever de soleil
int coucher = 20; //Envoi 20 à domoticz pour indiquer que c'est le coucher de soleil
int on = 30; //Envoi 30 à domoticz pour indiquer que les LEDs sont ON
int off = 0; //Envoi 30 à domoticz pour indiquer que les LEDs sont OFF
int timefade = 30000; //initialisation de la duree de la boucle qui fait varier la luminosite

à ça :

Code :

#define maxlum 255 //Valeur maximale de la luminosite possible
#define minlum 0 //Valeur minimale de la luminosite possible
#define StartHeure 7 //heure de démarrage des LEDs
#define StartMin 30 //minutes de démarrage des LEDs
#define EndHeure 18 //heure extinction des LEDs
#define EndMin 25 //minutes extinction des LEDs
#define PinSoil A1 //sélection de la pin de mesure du capteur d'humidité de sol
#define SensorSoil 0 //initialisation de la valeur du capteur d'humidité de sol
#define lever 10 //Envoi 10 à domoticz pour indiquer que c'est le lever de soleil
#define coucher 20 //Envoi 20 à domoticz pour indiquer que c'est le coucher de soleil
#define ledon 30 //Envoi 30 à domoticz pour indiquer que les LEDs sont ON
#define ledoff 0 //Envoi 0 à domoticz pour indiquer que les LEDs sont OFF
#define stepfade 5 //Incrément utilisé pour allumer et eteindre progressivement les LEDs
#define timefade 30000 //initialisation de la duree de la boucle qui fait varier la luminosite
const int pl = 9; //Pin par laquelle est pilotée le ruban LED
int bght = 0; //Initialisation du brightness qui va etre modifier
int etatLEDS = 0; //initialisation de la variable qui indique a domoticz l'etat du ruban LED

Ca fait plus propre...à mes yeux [:ddr555]

Natopsi

☄️Just end it already!☄️

Vu que les #define c'est du préprocesseur, met des parenthèses autour de tes valeurs. Ça évitera des conneries potentielles car si tu fait par exemple #define toto 1 et après écrit par erreur tata = toto1 au lieu de tata = toto+1, le compilateur va remplacer "toto" par "1" donc comprendra tata=11 et tu ne comprendra pas pourquoi ça merde. Alors que si tu fait #define toto (1), le compilateur,en voyant tata=(1)1 va s'arrêter car c'est pas conforme.

Message cité 1 fois
Message édité par Natopsi le 07-12-2018 à 11:42:26

---------------
⚡ACH/VDS⚡HFRCoin◈1435mm⚡

JPlnx

Nickel, au passage tu peux éventuellement nommer les constantes en majuscule si tu veux te rapprocher des conventions ;-)
#define LED_OFF 0
#define STEP_FAD 5
Bon courage !

Message cité 1 fois
Message édité par JPlnx le 07-12-2018 à 12:03:07

hyperboleske

Natopsi a écrit :

[:verdascobvious:4] Pas con

JPlnx a écrit :

Nickel, au passage tu peux éventuellement nommer les constantes en majuscule si tu veux te rapprocher des conventions ;-)
#define LED_OFF 0
#define STEP_FAD 5
Bon courage !

Done :jap:

hyperboleske

Salut !

Je viens de tester toutes les dernières modifs conseillées ici et ça tourne ! [:dawa]

Il me reste un dernier soucis.

sur l'arduino, j'ai une fonction qui envoi via le port série(USB) les infos au RPi :

Code :

#include <Time.h>
#include <TimeLib.h>
#include <DS1307RTC.h>
#include <Wire.h>
#include "DHT.h"
#define MAXLUM 255 //Valeur maximale de la luminosite possible
#define MINLUM 0 //Valeur minimale de la luminosite possible
#define STARTHEURE 07 //heure de démarrage des LEDs
#define STARTMIN 30 //minutes de démarrage des LEDs
#define ENDHEURE 19 //heure extinction des LEDs
#define ENDMIN 00 //minutes extinction des LEDs
#define PINSOIL A1 //sélection de la pin de mesure du capteur d'humidité de sol
#define LEVER 10 //Envoi 10 à domoticz pour indiquer que c'est le LEVER de soleil
#define COUCHER 20 //Envoi 20 à domoticz pour indiquer que c'est le COUCHER de soleil
#define ONLED 30 //Envoi 30 à domoticz pour indiquer que les LEDs sont ON
#define OFFLED 0 //Envoi 0 à domoticz pour indiquer que les LEDs sont OFF
#define STEPFADE 5 //Incrément utilisé pour allumer et eteindre progressivement les LEDs
#define FADETIME 500 //initialisation de la duree de la boucle qui fait varier la luminosite
const int pl = 9; //Pin par laquelle est pilotée le ruban LED
int BGHT = 0; //Initialisation du brightness qui va etre modifier
int ETATLEDS = 0; //initialisation de la variable qui indique a domoticz l'etat du ruban LED
int SENSORSOIL = 0; //initialisation de la valeur du capteur d'humidité de sol
String MESSAGE = ""; //Initialisation du MESSAGE envoye par le port Serie/USB a domoticz sur le RPi
DHT dht;
void setup() {
Serial.begin(9600); // Start Serial
pinMode(pl, OUTPUT); // Pin utilisée pour les LED, declaree comme un output:
dht.setup(13); // Pin utilisée pour la sonde DHT
LightCheckOn(); //On verifie l'heure pour allumer si on est en pleine journee
}
void loop() {
SendDataToDomoticz(); //On appelle la fonction qui permet d'envoyer les infos au serveur domoticz du raspberry
CheckTimeLED(); //Appel de la fonction qui regarde l'heure pour allumer ou eteindre le ruban LED
delay(2000);
}
void CheckTimeLED(){
tmElements_t tm;
if (RTC.read(tm)) {//--> Début de la boucle qui check l'heure pour allumer et eteindre le ruban LED
if ((tm.Hour==STARTHEURE) && (tm.Minute==STARTMIN)){ //Allumage de la lumiere a partir de l'heure definie
LightsON();
}
else if ((tm.Hour==ENDHEURE) && (tm.Minute==ENDMIN)){ //Extinction de la lumiere a partir de l'heure definie
LightsOFF();
}
}
}
void LightsON(){ //Fonction qui allume les LEDs
while(BGHT<MAXLUM){ //tant que la luminosite commandée est inferieure à 255 on boucle
SendDataToDomoticz(); //A chaque boucle on envoit les infos a domoticz
ETATLEDS = LEVER; //On enregistre l'etat LEVER DE SOLEIL des LEDs
BGHT=BGHT+STEPFADE; //On incremente la luminosite de la valeur fade à chaque boucle
analogWrite(pl, BGHT); //on commande le ruban LED
delay(FADETIME); //Allumage progressif toutes les 25s
}
ETATLEDS = ONLED; //On enregistre l'etat ON des LEDs
}
void LightsOFF(){ //Fonction qui éteint les LEDs
while(BGHT>MINLUM){ //tant que la luminosite commandée est superieure a 0 on boucle
SendDataToDomoticz(); //A chaque boucle on envoit les infos a domoticz
ETATLEDS = COUCHER; //On enregistre l'etat COUCHER DE SOLEIL des LEDs
BGHT=BGHT-STEPFADE; //On diminue la luminosite de la valeur fade à chaque boucle
analogWrite(pl, BGHT); //on commande le ruban LED
delay(FADETIME); //Extinction progressive toutes les 25s
}
ETATLEDS = OFFLED; //On enregistre l'etat OFF des LEDs
}
void LightCheckOn(){
tmElements_t tm;
if (RTC.read(tm)) { //Allumage d'un coup si on branche le systeme en pleine journée
if (( (tm.Hour*60 + tm.Minute) >= (STARTHEURE*60 + STARTMIN) && (tm.Hour*60 + tm.Minute) < (ENDHEURE*60 + ENDMIN)) ) {
BGHT = MAXLUM; //on force la luminosite au max
analogWrite(pl, BGHT);
ETATLEDS = ONLED; //On enregistre l'etat ON des LEDs
}
}
}
void SendDataToDomoticz(){
delay(dht.getMinimumSamplingPeriod());
float humidity = dht.getHumidity(); //enregistre l'humidite ambiante
float temperature = dht.getTemperature(); //enregistre la temperature ambiante
SENSORSOIL = analogRead(PINSOIL); //Enregistre l'humidite du sol
//ENVOI DES INFOS AU RASPBERRY :
Serial.print(humidity, 1);
Serial.print("," );
Serial.print(temperature, 1);
Serial.print("," );
Serial.print(SENSORSOIL, 1);
Serial.print("," );
Serial.print(ETATLEDS);
Serial.print("," );
Serial.print(BGHT);
Serial.print("," );
Serial.println("END" );
//FIN DE L ENVOI DES INFOS AU RASPBERRY
}

Sur le RPi, j'ai cela :

Code :

#!/usr/bin/env python
import serial
import os
import glob
import time
import requests
from requests.auth import HTTPBasicAuth
#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
# les parametres de Domoticz
#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
domoticz_ip='IP DU SERVEUR'
domoticz_port='PORT DU SERVEUR'
user=*********
password=***********
domoticz_idx_soilmoisture=12
domoticz_idx_dht22=7
domoticz_idx_etatLEDs=9
domoticz_idx_niveauLEDs=13
#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
# Initialisation du port serie
# Verifier ACM0 qui peut changer suivant la version raspbian et raspberry
#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
ser = serial.Serial('/dev/ttyACM0', 9600)
def maj_widget(val_url):
requete='http://'+domoticz_ip+':'+domoticz_port+val_url
#print requete
r=requests.get(requete,auth=HTTPBasicAuth(user,password))
if r.status_code != 200:
print "Erreur API Domoticz"
while i==1 :
####CA CLIGNOTE UNE FOIS AVANT D'ARRIVER ICI !######
message = ser.readline()
print(message)
hum,temp,soil,etatLEDs,niveauLEDs,end = message.split(',')
print('Humidite : ', hum)
print('Temperature : ', temp)
print('Soil moisture : ', soil)
print('Eclairage LEDs : ', etatLEDs)
print('Niveau LEDs : ', niveauLEDs)
url='/json.htm?type=command&param=udevice&idx='+str(domoticz_idx_dht22)+'&nvalue=0&svalue='+str('{0:0.1f};{1:0.1f};2').format(float(temp), float(hum))
maj_widget(url)
url='/json.htm?type=command&param=udevice&idx='+str(domoticz_idx_soilmoisture)+'&nvalue=0&svalue='+str('{0:0.1f};2').format(float(soil))
maj_widget(url)
#url='/json.htm?type=command&param=udevice&idx='+str(domoticz_idx_etatLEDs)+'&nvalue='+str(float(etatLEDs))
url='/json.htm?type=command&param=udevice&idx='+str(domoticz_idx_etatLEDs)+'&nvalue=0&svalue='+str(float(etatLEDs))
maj_widget(url)
url='/json.htm?type=command&param=udevice&idx='+str(domoticz_idx_niveauLEDs)+'&nvalue=0&svalue='+str(float(niveauLEDs))
maj_widget(url)
time.sleep(120)

Bon, le python du RPi n'est pas optimisé mais ça marche.
Le seul problème, c'est au lancement du script python, mon arduino coupe pendant 1s la lumière du ruban LED.
Ensuite, tant que le script tourne sur le RPi, pas de soucis.
Seulement, je voudrais planifier ce script via CRON (toutes les 2min par exemple) au lieu de le faire tourner en permanence avec le time.sleep(120). Et donc si le script se lance par CON toutes les 2 minutes, la lumière va clignoter.
Qu'est-ce qui foire dans mon code arduino ou RPi ? [:klemton] Je suppose que ça à voir avec la coomunication avec le port série.

Message édité par hyperboleske le 09-12-2018 à 15:38:19

hyperboleske

En faisant un test, je vois que c'est quand le RPi fait ça :

Code :

ser = serial.Serial('/dev/ttyACM0', 9600)

une idée ?

rat de combat

attention rongeur méchant!

Il n'y a pas une histoire d'un des pins (DTR??) du port série qui est utilisé pour remettre à zéro l'Arduino? Tu as un scope? Branche le sur la broche 1 (Reset) du AVR qui est sur l'Arduino. Ca doit être possible de régler ça en coupant la bonne piste, par contre ça veut dire qu'on ne peut plus programmer l'Arduino. On pourrait mettre un interrupteur...

Message cité 1 fois
Message édité par rat de combat le 09-12-2018 à 15:51:57

hyperboleske

Ha non, pas de scope sous la main [:ddr555]

hyperboleske

rat de combat a écrit :

En effet

Citation :

Moreover, you have also noticed that when you uplaod the code in your Arduino board then the Arduino resets, another way of resetting Arduino is by opening the Serial Terminal in Arduino software, while connecting your Arduino board to your computer. As you open the Serial Terminal, the Arduino automatically gets reset.

https://www.theengineeringprojects. [...] cally.html
Je vais creuser un peu la question... j'ai pas fini de lire l'article.

SuperSic

Qu'est-ce qui te gene avec le sleep(120) ?

Message cité 1 fois

---------------
"Les soldats vivent. Et se demandent pourquoi." Toubib (La Compagnie noire) | [TU] Pronomoo

hyperboleske

SuperSic a écrit :

Qu'est-ce qui te gene avec le sleep(120) ?

Je ne sais pas, je prefère avoir un script qui tourne 1 fois toutes les 2 min plutot qu'en permanence.

Message cité 1 fois

hyperboleske

C'est bon, j'ai trouvé la parade :

un condensateur de 10µF entre une pin GND et la pin RESET :jap:

Message cité 1 fois

rat de combat

attention rongeur méchant!

hyperboleske a écrit :

un condensateur de 10µF entre une pin GND et la pin RESET :jap:

et tu peux toujours programmer l'Arduino avec ça? :??:

Message cité 1 fois

SuperSic

hyperboleske a écrit :

Je ne sais pas, je prefère avoir un script qui tourne 1 fois toutes les 2 min plutot qu'en permanence.

Il tourne pas vraiment s'il dort mais je comprend.

---------------
"Les soldats vivent. Et se demandent pourquoi." Toubib (La Compagnie noire) | [TU] Pronomoo

hyperboleske

rat de combat a écrit :

et tu peux toujours programmer l'Arduino avec ça? :??:

Pas tester encore, mais si besoin, j'ai juste un fil à retirer du breadboard.

hyperboleske

La serre tourne !
C'est pas super propre mais ça semble bien parti

Pour le moment, piment, citrouille et pépin de clémentine

Je ferais un topo/résumé complet dans la semaine avec codes et schémas

Message édité par hyperboleske le 09-12-2018 à 18:24:39

---------------
Même si la bière est toujours vendue en bouteilles d'une pinte, cela n'entraîne pas que la bière soit constituée de parties indivisibles d'une pinte chacune.

SuperSic

Cool de voir un projet qui avance

---------------
"Les soldats vivent. Et se demandent pourquoi." Toubib (La Compagnie noire) | [TU] Pronomoo

flat4power

salut à tous
je cherche depuis un moment maintenant mais sans trouver (alors que ca se trouve peut-être sous mon nez )
je voudrais que ma carte arduino connecté en BT avec mon téléphone soit capable de l'indiquer l'état de charge de ma batterie.
Quand on connecte son téléphone à la voiture ou pas mal d'autre accessoire on récupéré le niveau de charge de la batterie, mais je ne trouve pas les instructions ou commande afin de connaître ce niveau.
Faut il un profil particulier au module BT, bref j'avoue que je rame un peu avec ça
Si vous avez des pistes je suis preneur

Merci

Message cité 1 fois

m_vincent

flat4power a écrit :

via les commandes AT
AT+CBS si mes souvenirs sont bons

flat4power

ta mémoire n'est pas trop mauvaise
ca m'a bien aidé, c'est la command AT+CBC

reste a trouvé si un simple HC-05 peut envoyer cette commande au téléphone pour récupérer le niveau de charge parce que je ne veux pas que ce soit le module BT de mon arduino qui me réponde mais le device qui y sera connecté

Message édité par flat4power le 13-12-2018 à 21:44:16

m_vincent

il faut juste etablir une COM entre les 2, après tu fais ce que tu veux

_pollux_

Pan ! t'es mort

Salut,

Je reviens avec un MEGA suite à mon problème de mémoire sur l'UNO (utilisation de librairie graphique + carte SD + détecteur de poussière).

Plus de problème mémoire, mais un soucis avec le détecteur de poussière... il fonctionne bien avec l'UNO mais pas avec le MEGA (en gros, je ne détecte rien avec le MEGA alors que j'ai bien des retours sur l'UNO).

Le code est ici : https://github.com/AmphenolAdvanced [...] 1C_Int.ino

Je ne vois pas dans le programme ce qui pourrait faire que ça marche avec le UNO mais pas le MEGA...

J'ai viré toute la partie graphique parce que pas utile (i.e la librairie wire et arduino_gfx), ça fonctionne toujours sur le uno, mais pas sur le mega.

Si quelqu'un a une idée, je suis preneur

Message cité 1 fois
Message édité par _pollux_ le 18-12-2018 à 09:51:11

---------------
Le topic du sport électronique@hfr : watch the l33t !

_pollux_

Pan ! t'es mort

_pollux_ a écrit :

Salut,

Je reviens avec un MEGA suite à mon problème de mémoire sur l'UNO (utilisation de librairie graphique + carte SD + détecteur de poussière).

Plus de problème mémoire, mais un soucis avec le détecteur de poussière... il fonctionne bien avec l'UNO mais pas avec le MEGA (en gros, je ne détecte rien avec le MEGA alors que j'ai bien des retours sur l'UNO).

Le code est ici : https://github.com/AmphenolAdvanced [...] 1C_Int.ino

Je ne vois pas dans le programme ce qui pourrait faire que ça marche avec le UNO mais pas le MEGA...

J'ai viré toute la partie graphique parce que pas utile (i.e la librairie wire et arduino_gfx), ça fonctionne toujours sur le uno, mais pas sur le mega.

Si quelqu'un a une idée, je suis preneur

J'ai trouvé !

La blague, expliquée ici : http://rcarduino.blogspot.com/2013 [...] duino.html

En gros, les interruptions fonctionnent sur tous les ports digitaux de l'arduino uno, mais pas sur tous ceux du mega... en l’occurrence pas les ports 7 et 8 par défaut du programme que j'ai récupéré, ni évidemment les ports 2 et 3 que j'avais essayé pour test, mais uniquement les ports 10 à 15.

---------------
Le topic du sport électronique@hfr : watch the l33t !

Publicité

Page : 1 2 3 4 5 .. 166 167 168 .. 266 267 268 269 270 271

Page Suivante

Page Précédente

Haut de page

FORUM HardWare.fr

Electronique, domotique, DIY

Nano-ordinateur, microcontrôleurs, FPGA

[arduino] Topic Unique blabla @ Arduino

Sujets relatifs
* Réparations de vos appareils électroniques & electromenager *
Plus de sujets relatifs à : [arduino] Topic Unique blabla @ Arduino

Page générée en 0.257 secondes