Comment sélectionner des onglets à partir d'une variable

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : Comment sélectionner des onglets à partir d'une variable

courcelpipof

Bonjour,

Je travaille sous Excel et j'essaie de programmer une sélection d'onglet à partir d'une variable (onglet). L'erreur "l'indice n'appartient pas à la sélection" apparaît pour la dernière ligne de commande :

Sub TEST()

Dim onglet As String

onglet = "1, 2"

Sheets(Array(onglet)).Select

End Sub

Je pense que c'est un problème de type de données. Est-ce que quelqu'un peut m'aider sur ce problème. Merci d'avance

Publicité

Laebruhtra

Salut,
Tu n'étais pas bien loin en effet.
Le Array va renvoyer à une variable de type variant, à partir d'arguments (arglist). onglet ne peut donc être string.

Essaie comme ça:

Code :

Sub Select_Onglet()
Dim onglet As Variant
onglet = Array(1, 2, 3)
Sheets(onglet).Select
End Sub

Au plaisir

Message édité par Laebruhtra le 14-05-2014 à 13:37:46

---------------
Mon topal ACH/VDS

Marc L

Bonjour,

qui plus est peut se faire directement sans variable …

courcelpipof

Merci Laebruhtra pour ta réponse mais cela m'amène à un autre souci :
Ma variable dépend de conditions : En fait, selon les valeurs de certaines cellules je dois imprimer certains onglets.
Voici ci dessous mon programme complet. l'onglet 1 doit être toujours imprimé et les autres onglets dépendent de la valeur des cellules "RESULTxx".
J'ai par ce fait créer une variable de type string.

Sub impression()

'Création de la variable onglet

Dim onglet As String

onglet = "1"

'Conditions pour la sélection des onglets

If Range("RESULT1" ).Value <> 0 Then
onglet = onglet & ", 2"
End If

If Range("RESULT2" ).Value <> 0 Then
onglet = onglet & ", 3"
End If

If Range("RESULT3" ).Value <> 0 Then
onglet = onglet & ", 4"
End If

'etc.......

Sheets(onglet).Select

'Impression

ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, _
IgnorePrintAreas:=False

'Réinitialisation des onglets

Sheets(Array(1)).Select

End Sub

Sincères salutations

Marc L

En fait, il y a maldonne dès la ligne n° … Ah zut ! Le code n'a pas été balisé !

Merci d'éditer le message et de baliser le code grâce à l'icône dédiée conformément aux règles du forum …

courcelpipof

Désolé, je suis nouveau, je n'ai pas encore l'habitude des us et coutumes de ce site. Voici le code balisé :

Code :

Sub impression()
'Création de la variable onglet
Dim onglet As String
onglet = "1"
'Conditions pour la sélection des onglets
If Range("RESULT1" ).Value <> 0 Then
onglet = onglet & ", 2"
End If
If Range("RESULT2" ).Value <> 0 Then
onglet = onglet & ", 3"
End If
If Range("RESULT3" ).Value <> 0 Then
onglet = onglet & ", 4"
End If
'etc.......
Sheets(onglet).Select
'Impression
ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, _
IgnorePrintAreas:=False
'Réinitialisation des onglets
Sheets(Array(1)).Select
End Sub

Marc L

Un tableau (Array) est nécessaire mais du texte est utilisé … La fonction Split convertit le texte en tableau :

Code :

Sub Impression()
Onglet$ = "1"
For N = 1 To 4
If Range("RESULT" & N).Value <> 0 Then Onglet = Onglet & " " & N + 1
Next
Worksheets(Split(Onglet)).Select
ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False
Worksheets(1).Select
End Sub

Message cité 1 fois

courcelpipof

Marc L a écrit :

Un tableau (Array) est nécessaire mais du texte est utilisé … La fonction Split convertit le texte en tableau :

Code :

Sub Impression()
Onglet$ = "1"
For N = 1 To 4
If Range("RESULT" & N).Value <> 0 Then Onglet = Onglet & " " & N + 1
Next
Worksheets(Split(Onglet)).Select
ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False
Worksheets(1).Select
End Sub

Merci, pour ton aide mais j'ai un message d'erreur qui apparait :
J'ai retranscrit ton programme, je l' ai adapté à mes besoins ça donne ceci :

Code :

Sub Impression()
'Création de la variable onglet
Dim onglet As String
onglet$ = "1"
'Conditions pour la sélection des onglets
For N = 1 To 25
If Range("RESULT" & N).Value <> 0 Then onglet = onglet & " " & N + 1
Next
' A effacer
MsgBox onglet
Worksheets(Split(onglet)).Select
'Impression
ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, _
IgnorePrintAreas:=False
'Réinitialisation des onglets
Worksheets(1).Select
End Sub

Cela donne ceci en message box : 1 2 3 5
Et lorsque je valide la box, le message d'erreur apparaît : Erreur d'exécution "9" : L'indice n'appartient pas à la sélection
La ligne 21 se met en surbrillance. Est-ce un problème de format ? ou ne dois-je pas utiliser le format string en ligne 5 ?

Marc L

Autant pour moi, mea culpa !

En fait quand le tableau renvoyé est de type String, VBA s'attend aux noms des feuilles et non à pas leurs numéros (Index) :

Code :

Sub Impression()
Onglet$ = Worksheets(1).Name
For N = 1 To 25
If Range("RESULT" & N).Value <> 0 Then Onglet = Onglet & "¤" & Worksheets(N + 1).Name
Next
Worksheets(Split(Onglet, "¤" )).Select
ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False
Worksheets(1).Select
End Sub

Le Dim est inutile car déjà compris dans la ligne n°2 (sauf si contrainte instruction Option Explicit) …

Effectuer un double clic dans le cadre du code avant de procéder à sa copie …

Message cité 1 fois

courcelpipof

Marc L a écrit :

Autant pour moi, mea culpa !

En fait quand le tableau renvoyé est de type String, VBA s'attend aux noms des feuilles et non à pas leurs numéros (Index) :

Code :

Sub Impression()
Onglet$ = Worksheets(1).Name
For N = 1 To 25
If Range("RESULT" & N).Value <> 0 Then Onglet = Onglet & "¤" & Worksheets(N + 1).Name
Next
Worksheets(Split(Onglet, "¤" )).Select
ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, IgnorePrintAreas:=False
Worksheets(1).Select
End Sub

Le Dim est inutile car déjà compris dans la ligne n°2 (sauf si contrainte instruction Option Explicit) …

Effectuer un double clic dans le cadre du code avant de procéder à sa copie …

Ah merci beaucoup, ça fonctionne, j'ai été cependant obligé de rajouter le Dim. Et remerci pour avoir utiliser un peu de votre temps à mon problème.

Sincères salutations

Publicité

nicolasvba

Salut ! VBA bien ?

Une autre proposition de solution qui fonctionne.
Par exemple, pour copier les onglets qui commencent par "1", puis "2", puis"3"...

Code :

Sub test()
Dim MyArray() As String
Dim FileName As String
Dim ws As Worksheet
Dim WB As Workbook
Dim taille, i, X As Integer
'(...)
For i = 1 To 5
taille = 0
X = 0
'Dimensionne le tableau à la bonne taille
For Each ws In Worksheets
If Left(ws.Name, 1) = CStr(i) Then
ReDim MyArray(taille)
taille = taille + 1
End If
Next
'Alimente le tableau avec le nom de chaque onglet
For Each ws In Worksheets
If Left(ws.Name, 1) = CStr(i) Then
MyArray(X) = ws.Name
X = X + 1
End If
Next
If X <> 0 Then
FileName = "C:\Users\Public\Documents\Onglets_" & CStr(i) & ".xlsx"
Sheets(MyArray).Copy
ActiveWorkbook.SaveAs FileName:=FileName _
, FileFormat:=xlOpenXMLWorkbook, CreateBackup:=False
ActiveWindow.Close
End If
Next
End Sub

Message édité par nicolasvba le 14-08-2015 à 09:08:38

---------------
La cuillère n'existe pas

FORUM HardWare.fr

Programmation

VB/VBA/VBS

Comment sélectionner des onglets à partir d'une variable

Sujets relatifs
[python] nom de champ d'un dictionnaire en variable	$variable[col1] fonctionne avec PHP5.2 mais pas en 5.3
problème pour inserer des données dans une table à partir d'un Jframe	VBA simple : comment faire une série d'identifiant à partir d'un chiff
manipuler le web a partir des graphes ( en c++ )	variable dans levariable dans le Filtrer /filtres textuels /contient
passage d'une variable dans une autre Form	Macro cpier/coller differents onglets
la variable $_	Récupérer variable colonne tableau Batch
Plus de sujets relatifs à : Comment sélectionner des onglets à partir d'une variable

Page générée en 0.073 secondes