problème de transmission de variables

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : problème de transmission de variables

baobazz

Bonjour,

dans une boucle j'effectue un

Code :

call batch.bat param1 param2

mais il ne prend en compte que le premier paramètre..quelqu'un peut-il m'éclairer?

voici mon batch:

Code :

@echo off
title installation sur les postes du service %1
::copie
for /F "eol=; tokens=1,2 delims=," %%a in (services\%1.txt) do (call copie.bat %%a %%b)
pause

malheureusement, dans mon batch copie.bat, le paramètre %%b n'est pas pris en compte...seul %%a l'est...

Pourtant, si jutiilise echo:

Code :

@echo off
title installation sur les postes du service %1
::copie
for /F "eol=; tokens=1,2 delims=," %%a in (services\%1.txt) do (echo %%a %%b)
pause

eh bien, %%b s'affiche bien...

comment faire?

:??:

Publicité

wackevat

Tu peux poster ton copie.bat ?

Il y a des espaces dans %%a et %%b ? Quote-les pour voir.

baobazz

que veux-tu dire par quoter?
quoter les espaces ou l'espace entre %%a et %%b ?

comment le faire?

voici le code de copie.bat:

Code :

@echo off
set ordi=%1
set agent=%2
title installation sur le poste %1 appartenant à l'utilisateur %2
SET /P confirm="Voulez-vous vraiment envoyer le pack vers l'ordinateur %ordi%? (O/N) "
if /i "%confirm%"=="N" GOTO ANNUL
echo.
if not exist \\%ordi%\C$\*.* goto PCABSENT
echo.
echo copie du pack sur le bureau de l'agent %agent%
xcopy /S pack "\\%ordi%\C$\Documents and Settings\All Users\Bureau"
if errorlevel 1 goto erreurCOPIE
echo.
goto fin
:ANNUL
echo envoi du pack annulé sur le poste %1 >> Logs\log.txt
echo édition du fichier log effectuée
goto fin
:PCABSENT
echo %ordi% absent. Vérifiez qu'il est bien démarré
echo %ordi% absent >> Logs\log.txt
echo édition du fichier log effectuée
goto fin
:erreurCOPIE
echo %ordi% de l'agent %agent%=> copie non OK>>Logs\log.txt
echo édition du fichier log effectuée
goto fin
:fin
echo.
echo fin de la copie

bref, je ne sais pas si ça va t'aider...

sinon, javais fait pour le batch précédent:

Code :

@echo off
title installation sur les postes du service %1
::copie
for /F "eol=; tokens=1,2 delims=," %%a in (services%1.txt) do (call copie.bat %%a %%b %1)
pause

et bizarrement, il prenait en compte le paramètre %1 de

Code :

call copie.bat %%a %%b %1

le paramètre %%a était pris en compte en tant que premier paramètre, pas %%b, et %1 en tant que deuxième paramètre

Message cité 1 fois
Message édité par baobazz le 20-06-2006 à 17:38:00

wackevat

baobazz a écrit :

que veux-tu dire par quoter?

Comme ça :

Code :

for /F "eol=; tokens=1,2 delims=," %%a in (services%1.txt) do (
echo a=----%%a---
echo b=----%%b---
call copie.bat "%%a" "%%b"
)

puis:

Code :

set ordi=%~1
set agent=%~2
echo ordi=----%ordi%---
echo agent=----%agent%---

baobazz

merci, nglechau!

à quoi servent les ~ de "set ordi=%~1"?

merci en tt cas!

wackevat

Ca permet d'enlever les guillemets des arguments que tu as fournis.

baobazz

super!!!

merci!

FORUM HardWare.fr

Programmation

Shell/Batch

problème de transmission de variables

Sujets relatifs
Probleme de compatiblité IE	[RESOLU] Problème méthode GET
Probleme avec un kit graphique	Problème d'infos MySQL
Problème taille pages sous dreanweaver (urgent !!)	Probleme de Permission lors de COPYFILE
Garder les variables POST après une redirection header	problème en C
[Resolu]Probleme de JScrollPane et JtextArea	[VBA] Problème avec RecordCount
Plus de sujets relatifs à : problème de transmission de variables

Page générée en 0.094 secondes