Perl

[Résolu] HTML::Parser, balises avec attribut

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : [Résolu] HTML::Parser, balises avec attribut

Gavrinis

Open your mind

Bonjour,

Je dois parser un fichier HTML afin de récupérer les valeurs entre <td>, mais seulement quand le td est suivi de l'attribut align="left" --> <td align="left">.
J'ai récupéré sur le web un code utilisant HTML::Parser et tenté de l'adapter mais en vain.
Il me retourne le contenu de tous les td et pas seulement ceux contenant l'attribut left.

Voici une partie du code :

Code :

#!$(which perl) -w
use HTML::Parser;
sub parsing {
my $state = '';
# @personnes = ( [nom,adresse,tel,apb], [nom,adresse,tel,apb] );
my @personnes = ();
# ("nom", "adresse", "tel", "apb" )
my @personne = ();
# "nom"
my $item = '';
# Initialisation du parser.
my $p = HTML::Parser->new(api_version => 3);
# Ouverture d'une balise.
$p->handler(
start => sub {
my ($tag, $args) = shift;
$state = 'TABLE' if $tag eq 'table';
$state = 'TR' if $tag eq 'tr';
$state = 'TD' if $tag eq 'td';
if ($state eq 'TD' and defined($args->{align}) and $args->{align} eq 'left')
{
$item .= shift;
}
}, "tagname,text"
);
$p->handler(
default => sub {
$item .= shift if $state eq 'TD';
}, "text"
);
# Fermeture d'une balise.
$p->handler(
end => sub {
my $tag = shift;
$state = '' if $tag eq 'table';
if ($tag eq 'td')
{
$state = 'TR';
push @personne, $item;
$item = '';
}
if ($tag eq 'tr')
{
$state = 'TABLE';
push @personnes, [@personne];
@personne = ();
}
}, "tagname"
);
# Recupere le code HTML passe en parametre.
undef $/;
my $data = $_[0];
## parse it (this calls each handler as necessary)
$p->parse($data);
## now dump out the Perl structures
use Data::Dumper;
for my $row (@personnes)
{
print Dumper($row);
}
}
&parsing();

L'HTML :

Code :

<table border="0">
<tr>
<td>
<div id="title" align="center">
<h2><b>Garde</b></h2>
</div>
<div id="info"></div>
<div id="map" style="width: 730px; height: 550px">
</div>
</td>
</tr>
<tr>
<td align="center">
<div id="directions"></div>
<table><tr><td height="1" class="LineGrey"></td></tr><tr><td align="left"><br /><span class="styleGreen">garde </span><br /><br /><b>Tata</b> (Tata)    Chaussée de Tata 41    1360 TxxxxxxxxS <br /><b>Tel. :</b> xxx/xxxxxx     <b>Numéro :</b> xxxxxx<br /><br /></td></tr><tr><td height="1" class="LineGrey"></td></tr><tr><td align="left"><br /><span class="styleGreen"> garde </span><br /><br /><b>Tbtb (Tbtb)</b> (Tbtb)    Rue Tbtb 43    5020 Txxxxxx <br /><b>Tel. :</b> xxxxxxxxx     <b>Numéro :</b> xxxxxx<br /><br /></td></tr><tr><td height="1" class="LineGrey"></td></tr><tr><td align="left"><br /><span class="styleGreen"> garde </span><br /><br /><b>Tctc</b> (Tctc)    Rue Tctc 22    1450 Cxxxxxxx <br /><b>Tel. :</b> xxxxxxxxx     <b>Numéro :</b> xxxxxx<br /><br /></td></tr><tr><td height="1" class="LineGrey"></td></tr><tr><td align="left"><br /><span class="styleGreen"> garde </span><br /><br /><b>Tdtd</b> (Tdtd)    Chaussée Tdtd 40    5140 Sxxxxxxxxx <br /><b>Tel. :</b> xxxxxxxxx     <b>Numéro :</b> xxxxxx<br /><br /></td></tr><tr><td height="1" class="LineGrey"></td></tr><tr><td align="left"><br /><span class="styleGreen"> garde </span><br /><br /><b>Tete</b> (Tete)    Rue Tete 30    5020 Vxxxxxxxxxxx <br /><b>Tel. :</b> xxxxxxxxx     <b>Numéro :</b> xxxxxx<br /><br /></td></tr><tr><td height="1" class="LineGrey"></td></tr><tr><td height="1" class="LineGrey"></td></tr></table><br /><br />
<script>
document.getElementById('directions').style.display = 'none'
</script>
</td>
</tr>
</table>

Pouvez-vous m'aider s'il vous plait ?
Merci :jap:

Message édité par Gavrinis le 28-06-2011 à 10:22:52

Publicité

gilou

Modérateur
Modosaurus Rex

Bon, j'ai fait des modifs et un test rapide:

Code :

#!$(which perl) -w
use HTML::Parser;
 
sub parsing {
   my $state = '';
   # @personnes = ( [nom,adresse,tel,apb], [nom,adresse,tel,apb] );
   my @personnes = ();
   # ("nom", "adresse", "tel", "apb" )
   my @personne = ();
   # "nom"
   my $item = '';
   # Initialisation du parser.
   my $p = HTML::Parser->new(api_version => 3);
   # Ouverture d'une balise.
   $p->handler(
      start => sub {
         my $tag = shift;
         my $args = shift;
         $state = 'TABLE' if $tag eq 'table';
         $state = 'TR' if $tag eq 'tr';
         $state = 'TD' if $tag eq 'td';
         if ($state eq 'TD' and defined($args->{align}) and $args->{align} eq 'left')
         {
        $state = 'TD1';
         }
      }, "tagname, attr"
   );
   $p->handler(
      default => sub {
         $item .= shift if $state eq 'TD1';
      }, "text"
   );
   # Fermeture d'une balise.
   $p->handler(
      end => sub {
         my $tag = shift;
         $state = '' if $tag eq 'table';
         if ($tag eq 'td')
         {
        if ($state eq 'TD1') {push @personne, $item;}
            $state = 'TR';
            $item = '';
         }
         if ($tag eq 'tr')
         {
            $state = 'TABLE';
        if (@personne+0) {
          push @personnes, [@personne];
        }
            @personne = ();
         }
      }, "tagname"
   );
   # Recupere le code HTML passe en parametre.
   undef $/;
   my $data = $_[0];
   ## parse it (this calls each handler as necessary)
   $p->parse($data);
   ## now dump out the Perl structures
   use Data::Dumper;
   for my $row (@personnes)
   {
      print Dumper($row);
   }
}
&parsing();

1) Si tu voulais les attributs, il fallait passer "tagname, attr" au handler de start.
2) Faut faire un shift pour chacun de tes arguments, un (a, b) = shift ne devrait remplir que a a priori je crois.
3) Faut ajouter un cas particulier quand tu as le TD avec l'attribut voulu pour detecter ça et accumuler le texte dans le handler par défaut (ici: TD1)

Il y a peut être d'autres moyens de faire ça avec ce module, mais je ne le connais pas bien.

Bon, il te reste plus qu'à parser correctement chaque ligne de @personnes pour en extraire les champs.

A+,

Message édité par gilou le 23-06-2011 à 16:56:23

---------------
There's more than what can be linked! -- Le capitaine qui ne veut pas obéir à la carte finira par obéir aux récifs. -- Il ne faut plus dire Sarkozy, mais Sarkozon -- (╯°□°)╯︵ ┻━┻

gueuledange

Smokin chroniı̸̸̸̸̸̸̸̸̸̸̸̸̸̸̸̸̸̸̨̨̨̨̨̨c

Ce serait pas plus simple avec un sed, awk ou autre?

gilou

Modérateur
Modosaurus Rex

On voit bien que tu n'y connais rien.
Perl est beaucoup plus puissant et pratique que sed awk et autres (le jours ou j'ai découvert Perl, il y a plus de 20 ans, j'ai pu réécrire en un seul fichier simple une usine à gaz en script, sed, awk et autres dont plein de fichiers temporaires, que je faisais pour l'INRIA).
Pour parser du texte structuré ou pas, et la, c'est ce qu'il fait, il y a pas plus pratique que Perl.
A+,

Message cité 1 fois
Message édité par gilou le 23-06-2011 à 22:15:52

gueuledange

Smokin chroniı̸̸̸̸̸̸̸̸̸̸̸̸̸̸̸̸̸̸̨̨̨̨̨̨c

gilou a écrit :

Hmm pas la peine de le prendre personnellement... Je posais juste une question.

Et puis c'est normal qu'avec un "vrai langage" on ait plus de fonctionnalité et d'alternative qu'avec une simple commande (ou du sh) Mais dans beaucoup de cas un sed suffit, pas besoin de re-coder un parser a la main.

Message édité par gueuledange le 23-06-2011 à 22:28:57

gilou

Modérateur
Modosaurus Rex

Ah désolé si c'était juste une question. Je pensais que c'était une remarque sur un ton ironique.

Mais la il ne recode pas un parser, il en utilise un tout fait (use HTML::Parser) il associe juste quelques actions certains tokens reconnus par le parser.

Et dans les cas ou appeler sed suffit, bien souvent, c'est plus facile a coder en perl sur une ligne et a appeler comme on ferait pour sed.

A+,

Message édité par gilou le 23-06-2011 à 22:44:03

Gavrinis

Open your mind

Merci pour ton aide et tes explications Gilou, je n'en demandais pas autant, ça fonctionne parfaitement.

gilou

Modérateur
Modosaurus Rex

Juste un point de détail, évites d'appeler une routine perl avec &f();
f() est la manière moderne (et a moins que tu utilises un perl préhistorique, ça doit marcher), et l'appel &f(); désactive certaines fonctionnalités (la vérification des types des paramètre passés si la routine a un prototype à sa déclaration par exemple).
A+,

Gavrinis

Open your mind

Ok merci :jap: .

J'ai encore un soucis ... j'aimerais supprimer tous les &nbsp des éléments de mon tableau.
J'ai essayé ceci mais cela ne va pas .

Code :

@personne = map { $_ =~ s/\&nbsp//g; $_ } @personne;

gilou

Modérateur
Modosaurus Rex

Chez moi, ça marche, donc ton pb est ailleurs.

Code :

#!/usr/bin/perl
use strict;
use warnings;
 
my @personne;
$personne[0] = '<b>Tata</b>&nbsp;(Tata)&nbsp;&nbsp;&nbsp;&nbsp;Chaussée de Tata 41&nbsp;';
$personne[1] = "40&nbsp;&nbsp;&nbsp;&nbsp;5140 ";
 
@personne = map { s/\&nbsp;//g; $_} @personne; # pas besoin du $_ =~ ici
 
print $personne[0], "\n\n", $personne[1];

Fais aussi attention au fait que ta transformation va transformer 40    5140 en 405140, ce qui n'est peut être pas ce que tu désires.
s/\ (\ )*/ /g; serait peut être plus adapté.
A+,

Message édité par gilou le 24-06-2011 à 14:39:58

Publicité

Gavrinis

Open your mind

Encore merci, c'était tout bêtement une faute de frappe.
Pas de problème pour la transformation, car je supprime les &nbsp (pas le ; qui me servira de délimiteur).

FORUM HardWare.fr

Programmation

Perl

[Résolu] HTML::Parser, balises avec attribut

Sujets relatifs
[ActiveState]Comment executer les commandes perl sous ActiveState	Macro Excel pour transformer les cellules enrichis en html
Afficher résultats base mysql -> tableau html horizontal	Fabriquer un email en HTML
JPGRAPH ET HTML	Aide HTML/PHP/ SQL ( Urgent pour BAC:! )
Mail HTML super lent sous Outlook 2010	[HTML/CSS/Javascript] Problème d'affichage avec ie
bouton play, pause, java, html	Script, Dossier + Sous Dossier + "publication" page HTML
Plus de sujets relatifs à : [Résolu] HTML::Parser, balises avec attribut

Page générée en 0.121 secondes