Perl

certain conditions ne menacant

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : certain conditions ne menacant

Henri772

Salut a tous

j'ai un code traite le fichier de depart (src_sys.xml) et me renvoit les noms 'name'(attr_name) sur la pemiere ligne de mon fichier de sortie tout en splitant le nom du fichier de depart.(ceci dans le premier Twig)

ensuite il va et traite les fichiers restant dans le second Twig. Pour ce fait il cherche les valeurs 'value' (attr_value) correspondant a chaque 'name':

-Dans le cas ou il n'existe pas dans le fichier entrain d'etre traite il ecrit en desous du 'name' correspondant 'fault'.

-Dans le cas ou un fichier-xml qui est entrain d'etre traite possede plus de 'name' que le fichier de depart (src_sys.xml) ignorer le 'name' et continue.

-Dans le cas ou un fichier-xml qui est entrain d'etre traite possede moin de 'name' que le fichier de depart (src_sys.xml) ecrire en desous du 'name' correspondant 'missing'

jusqu'ici mon code travaille un peu et mais j'ai du souci sur 2 points:

-par moment quand 'value' n'existe pas au lieu d'ecire 'fault' comme mensionne dans le code il ecrit '0'

-Et maintenant au niveau de 'missing' cela m'echappe aussi.

je ne sais pas si quelqu'un ici pourrai me venir en aide. Merci bien d'avance.

Code :

#!/usr/local/bin/perl -w
use strict;
use warnings;
use XML::Twig;
use Text::CSV;
use POSIX qw(strftime);
use autodie;
use File::Basename;
my $file1 = shift @ARGV;
my @files = glob( '../InputData/*.xml');
@files = grep { $_ ne $file1 } @files if defined $file1;
$file1 = basename '..\InputData\DEFAULT\src_sys.xml';
my $date_1 = strftime "%Y%m%d %H:%M:%S", localtime;
my $FileResult = '../CSV/DATA.csv';
open( my $Fhhtml, '>', $FileResult );
print $Fhhtml $date_1, "\n";
my $twig1= XML::Twig->new(
twig_handlers => {
'Par' => sub {
my $attr_name = $_->{'att'}->{'name'};
print $Fhhtml $attr_name . ", ";
},
},
);
print $Fhhtml( (split('_', $file1,2))[0] . ', ' );
$twig1->parsefile($file1 = '..\InputData\DEFAULT\src_sys.xml');
for my $file (@files) {
my $twig1 = XML::Twig->new(
twig_handlers => {
'Par' => sub {
my $attr_value = $_->{'att'}->{'value'} // 'fault';
unless (defined $_->{att}{name}) {
$attr_value = "missing"
}
print $Fhhtml $attr_value . ", ";
},
},
);
my $result = (split( '_', "\n$file", 2 ) )[0] . ', ';
$result =~ s/..\/InputData\///g;
print $Fhhtml($result);
$twig1->parsefile($file);
}
close $Fhhtml;

Code :

_________________src_sys______________
<?xml version="1.0" encoding="UTF-8"?>
<Profile origin="get" version="2.0" date="2013-07-021:49:13Z">
<Par name="cost" value="0">
<Target class="inter" inst="en0"/>
</Par>
<Par name="mic" value="0">
<Target class="inter" inst="en1"/>
</Par>
<Par name="mor" value="0">
<Target class="inter" inst="en2"/>
</Par>
<Par name="cost" value="0">
<Target class="inter" inst="lo0"/>
</Par>
<Par name="actived" value="0">
<Target class="inter" inst="en0"/>
</Par>
<Par name="edgd" value="0">
<Target class="inter" inst="en1"/>
</Par>
<Par name="activ" value="0">
<Target class="inter" inst="en2"/>
</Par>
</Profile>
_________________ABO________________
<?xml version="1.0" encoding="UTF-8"?>
<Profile origin="get" version="2.0" date="2013-07-021:49:13Z">
<Par name="cost" value="0">
<Target class="inter" inst="en0"/>
</Par>
<Par name="mic">
<Target class="inter" inst="en1"/>
</Par>
<Par name="mor" value="ce">
<Target class="inter" inst="en2"/>
</Par>
<Par name="cost" value="A0">
<Target class="inter" inst="lo0"/>
</Par>
<Par name="actived" value="10">
<Target class="inter" inst="en0"/>
</Par>
<Par name="edgd" value="out">
<Target class="inter" inst="en1"/>
</Par>
<Par name="activ">
<Target class="inter" inst="en2"/>
</Par>
</Profile>
__________________ABI_________________
<?xml version="1.0" encoding="UTF-8"?>
<Profile origin="get" version="2.0" date="2013-07-021:49:13Z">
<Par name="cost" value="1">
<Target class="inter" inst="en0"/>
</Par>
<Par name="mic" value="A">
<Target class="inter" inst="en1"/>
</Par>
<Par name="mor" value="B">
<Target class="inter" inst="en2"/>
</Par>
<Par name="cost" value="C">
<Target class="inter" inst="lo0"/>
</Par>
<Par name="actived">
<Target class="inter" inst="en0"/>
</Par>
<Par name="mac" value="E">
<Target class="inter" inst="en1"/>
</Par>
<Par name="edgd" value="F">
<Target class="inter" inst="en1"/>
</Par>
<Par name="activ" value="G">
<Target class="inter" inst="en2"/>
</Par>
</Profile>
_________________ABA_________________
<?xml version="1.0" encoding="UTF-8"?>
<Profile origin="get" version="2.0" date="2013-07-021:49:13Z">
<Par name="cost" value="40">
<Target class="inter" inst="en0"/>
</Par>
<Par name="mic" value="ae">
<Target class="inter" inst="en1"/>
</Par>
<Par name="mor" value="0">
<Target class="inter" inst="en2"/>
</Par>
<Par name="cost">
<Target class="inter" inst="lo0"/>
</Par>
<Par name="actived" value="da">
<Target class="inter" inst="en0"/>
</Par>
<Par name="activ" value="ka">
<Target class="inter" inst="en2"/>
</Par>
</Profile>

Code :

_____________________output__________________________
src cost mic mor cost actived edgd activ
ABO 0 fault ce A0 10 out fault
ABI 1 A B C fault F G
ABA 40 ae 0 fault da missing ka

Message édité par Henri772 le 08-12-2015 à 17:05:25

Publicité

gilou

Modérateur
Modzilla

Déjà, avec Par dans les xml et Parameter dans le twig, ça doit marcher du tonnerre :sarcastic:

A+,

Message cité 1 fois

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Henri772

gilou a écrit :

Déjà, avec Par dans les xml et Parameter dans le twig, ça doit marcher du tonnerre :sarcastic:

A+,

salut Guiou c'est un probleme de nomenclture au fait des le depart c'etait paramater, j'ai change et oublie de le change en publiant cela ici
merci bien de la remarque

gilou

Modérateur
Modzilla

Un exemple de solution qui marche sur tes données

Code :

#!/usr/local/bin/perl
use Modern::Perl;
use autodie;
use XML::Twig;
use Data::Dumper;
use File::Basename;
 
# parametrage externe
my $arg_file = shift @ARGV;
my $sys_file = '..\InputData\DEFAULT\src_sys.xml';
my @files = glob('..\InputData\*.xml');
@files = grep { $_ ne $arg_file } @files if defined $arg_file;
my $result_file = '..\CSV\DATA.csv';
 
# On recupere le liste des noms d'attributs
my @sys_names;
my $sys_twig = XML::Twig->new( twig_handlers => { 'Par' => sub { push @sys_names, $_->{'att'}->{'name'}; }});
$sys_twig->parsefile($sys_file);
 
# On recupere le liste des noms d'attributs et la liste de leur valeurs pour chaque fichier
# Et on colle le tout dans un hash indexé par les noms de fichiers
my %hash;
foreach my $file (@files) {
  $hash{$file}{'att_names'} = [];
  $hash{$file}{'att_values'} = [];
  my $file_twig = XML::Twig->new( twig_handlers => { 'Par' => sub { push @{$hash{$file}{'att_names'}},  $_->{'att'}->{'name'};
                                            push @{$hash{$file}{'att_values'}}, ($_->{'att'}->{'value'} // 'fault'); }});
  $file_twig->parsefile($file);
}
 
# pour économiser le chargement d'un module
sub timestamp {
  my $i;
  return sprintf "%04d%02d%02d %02d:%02d:%02d", map {$_ + (1900,1,0,0,0,0)[$i++]} reverse ((localtime)[0..5]);
}
 
# On a tout, on va pouvoir traiter
open my $fhout, ">", $result_file;
print $fhout timestamp(), "\n";
print $fhout ((split(/_/, basename($sys_file)))[0]), "\t", join("\t", @sys_names), "\n";
 
foreach my $file (@files) {
  print $fhout  ((split(/\./, basename($file)))[0]);
  my $j = 0;
  foreach my $i (0..$#sys_names) {
    if ($hash{$file}{'att_names'}->[$j] and  $hash{$file}{'att_names'}->[$j] eq $sys_names[$i]) {
      print $fhout "\t", $hash{$file}{'att_values'}->[$j];
    }
    # une heuristique, il y a peut être mieux
    else {
      my $k = $j+1;
      while ($hash{$file}{'att_names'}->[$k] and  $hash{$file}{'att_names'}->[$k] ne $sys_names[$i]) {
        ++$k;
      }
      if ($hash{$file}{'att_names'}->[$k]) {
        $j = $k;
        print $fhout "\t", $hash{$file}{'att_values'}->[$j];
      }
      else {
        print $fhout "\t", "missing";
        --$j;
      }
    }
    ++$j;
  }
  print $fhout "\n";
}
close $fhout;

L'heuristique bête est:
Si j'en suis a traiter l'attribut A et que je trouve un attribut B la ou j'attendais le A, alors je cherche plus loin s'il y a un attribut A.
Si oui, je saute les attributs intermédiaires.
Sinon, je mets comme valeur 'missing' et je passe à l'attribut à traiter suivant.

A+,

Message édité par gilou le 08-12-2015 à 17:42:35

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Henri772

Salut Gilou,
Une fois de plus merci bien de ta proposition mais j'ai un souci avec ce code quand il traite les fichiers-xml il ya encore sur le fichier de sortie des champs vide je pense qu'il a un peu le meme probleme que le mien.
et ensuite aulieu de spliter il rajoute au nom du fichier 'base', bon cela je peus le regler.
et aussi je ne sais pas comment le caractere -> apparait a chaque fois qu'il ecrit un 'name' ou un 'value' dans le fichier de sortie.

gilou

Modérateur
Modzilla

Moi, avec les 4 fichiers de données que tu as fourni, j'obtiens ceci dans Data.csv:

20151208 17:27:09
src cost mic mor cost actived edgd activ
ABA 40 ae 0 fault da missing ka
ABI 1 A B C fault F G
ABO 0 fault ce A0 10 out fault

[:souk]

A+,

Message édité par gilou le 08-12-2015 à 23:58:08

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Henri772

Merci bien mais je ne comprend pas pourquoi ca ne marche pas de mon cote, c'est vraiment etrange

Henri772

j'aimerai bien te faire pavenir certain fichiers originaux pour que tu voye aussi ce que me revoit le code j'ai deja essaye de faire des changement malheureusement ca na marche pas.

Henri772

salut Gilou voila un apercu de ce que je recois

Message édité par Henri772 le 20-12-2015 à 16:09:56

gilou

Modérateur
Modzilla

Sur une simple image, je peux pas aider des masses.

A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Publicité

Henri772

ok voila certain de ces fichiers.xml que je t'envoi car j'ai essaye la ca me depasse .
tu peus change Par avec Parameter
et src_sys par default_value.xml

Message édité par Henri772 le 20-12-2015 à 16:09:12

gilou

Modérateur
Modzilla

Je comptais te suggérer la solution zippyshare, mais avec des fichiers dans un zip crypté dont tu m'aurais envoyé la clé en MP...
Je vais y jeter un oeil.

A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

gilou

Modérateur
Modzilla

Donc déjà pour que cela fonctionne, il y a un remplacements à effectuer:

my $sys_file = '..\InputData\DEFAULT\default_sysvalue.xml';

et pour le log,
# On a tout, on va pouvoir traiter
...
print $fhout ((split(/_/, basename($sys_file)))[0]), "\t", join("\t", @sys_names), "\n";
foreach my $file (@files) {
print $fhout (split(/_/, ((split(/\./, basename($file)))[0])))[0];

Et chez moi, ça fournit un DATA.csv (énorme, que je vais tacher de regarder un peu plus en détail)
Note: pour que ça marche, mon script est bien sur dans un répertoire Perl, qui est au même niveau que InputData (ie InputData, CSV et Perl sont dans un même répertoire).

A+,

Message édité par gilou le 09-12-2015 à 16:31:41

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Henri772

salut Gilou je comprend bien ce que tu veus dire par la. Car j'ai l'impression que le code fonctionne un peu comme le mien car par moment quand 'value' n'existe pas au lieu d'ecrire 'fault' il n'ecrit rien et ensuite avec le cas 'missing' on ne devait pas avoir des valeurs 'value' apres le dernier parametre 'name' .

A+

Message cité 1 fois
Message édité par Henri772 le 20-12-2015 à 16:10:20

gilou

Modérateur
Modzilla

Henri772 a écrit :

Mais la, c'est excel qui arrive pas a lire le bouzin en CSV et rien d'autre:
Tu
1) imprimes pas le timestamp
2) remplaces les \t séparateurs de champ par des ;
3) ouvres avec un excel récent (2013 par exemple; sur ma machine, ou je n'ai que excel 2003, ça passait pas, mais j'ai été tester sur une bécane plus récente et c'est passé sans pb)
Et tu verras qu'il y a rien qui dépasse, toutes les lignes ont la même longueur.
Dans la feuille, le seul truc qui m'inquiétait, c'est que je voyais des valeurs à vide, mais en fait, c'est que la valeur par défaut et les valeurs non par défaut étaient une chaine vide.

A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

gilou

Modérateur
Modzilla

Henri772 a écrit :

Merci bien j'aivais deja signifie un truc de ce genre a mon Maitre de stage que les fichiers me semblait pas identique et que par concequent une comparaison serait impossible. es ce qu'il serait possible d'ajouter le cas suivant : d'affecter l'instance au name lorsque les names son identique du genre

Code :

<Parameter name="max_vg_pbufs" value="524288" applyType="nextboot" reboot="true"><Target class="vg" instance="vg6dbzt04"/></Parameter>

max_vg_pbufs_inst_vg6dbzt04
524288
et ainsi de suite. Mais je sens que il sera maintenant difficile de retrouver le 'values' correspondante.
s'il te plait rend moi un service efface ses donnes il ne doivent malheureusement pas etres publie. Merci d'avance.
A+

Ben ça a pas grand sens quand les instances sont différentes et c'est problématiques: on ne saurait lesquelles sont communes au défaut et à un autre fichier qu'après avoir parsé tous les autres fichiers.

A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Henri772

ok, je vais essaye cela voir j'ai le 2013 sur une autre Machine au fait le firme travaille avec openOffice comme tu l'a remarque

Henri772

ca essaye un peu d'aller mais comme tu l'as aussi remarque il ya des vides et aussi il ya des 'missing' ecrit plusieurs fois dans un champ regarde l'image suivante

Message édité par Henri772 le 20-12-2015 à 16:12:17

Henri772

je pense que le probleme ne se situe pas vraiment au niveau du fait qu'il ait les memes noms regarde ce que me livrait mon code
il on tous les memes noms 'file' mais il effectue bien le trie

Message cité 1 fois
Message édité par Henri772 le 20-12-2015 à 16:12:33

gilou

Modérateur
Modzilla

Henri772 a écrit :

je pense que le probleme ne se situe pas vraiment au niveau du fait qu'il ait les memes noms regarde ce que me livrait mon code
il on tous les memes noms 'file' mais il effectue bien le trie
http://www.bilder-upload.eu/show.p [...] 683023.png

Oui, parce que la, le nom d'instance du target est discriminant et se retrouve dans les fichiers de données, mais ce n'est pas le cas partout.

A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Henri772

salut j'ai trouve pourquoi il ya des champs vide si tu regarde bien dans l'un des fichiers tu trouvera des valeuer ecrit ainsi value="" sachant que tout le valeurs sont ecritent entre les "" donc quand le code traite un fichier donc la value="" il ne trouve rien entre "" et il renvoi le vide. dans le cas ou il n'ya pas de value declare il revoi correctement 'fault' maintenant pourquoi il ecrit missing plusieurs fois dans un meme champs et pourquoi le resultat de notre fichier csv na pas une forme rectangülare und carree a ce niveau je m'explique il faudrait bien qu'aucune 'value' soit ecrit dans le fichier lorsque le 'name' n'existe pas. un peu comme sur cette image

A+

Message édité par Henri772 le 20-12-2015 à 16:11:44

gilou

Modérateur
Modzilla

> si tu regarde bien dans l'un des fichiers tu trouvera des valeuer ecrit ainsi value=""
C'est ce que je t'ai signalé il y a un bail. Mais dans mon code, une valeur "" donne un champ avec "" en sortie.

A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

gilou

Modérateur
Modzilla

Tiens donc, voila un code propre qui fait le boulot et que tu pourras modifier si le format de sortie ne te convient pas [pas sur que tu veuilles la ligne avec les valeurs par défaut, mais ça me semblait logique]. Le parsing est identique pour le fichier par défaut et ceux pour les données, donc ça devrait faciliter la compréhension.
Testé et vérifié sur tes données.

Code :

#!/usr/local/bin/perl
use Modern::Perl;
use autodie;
use XML::Twig;
use File::Basename;
use Data::Dumper;
 
# parametrage externe
my $arg_file = shift @ARGV;
my $default_file = '..\InputData\DEFAULT\default_sysvalue.xml';
my @files = glob('..\InputData\*.xml');
@files = grep { $_ ne $arg_file } @files if defined $arg_file;
my $result_file = '..\CSV\DATA.csv';
 
# pour économiser le chargement d'un module
sub timestamp {
  my $i;
  return sprintf "%04d%02d%02d %02d:%02d:%02d", map {$_ + (1900,1,0,0,0,0)[$i++]} reverse ((localtime)[0..5]);
}
 
# caractère séparateur pour l'criture dans le CSV résultat
my $sep_char = ";";
 
# On crée un identifiant unique pour ne pas clasher avec les noms d'attributs ou de fichier
# pour la liste des noms de catalogues et la liste des noms d'attributs dans un catalogue
my $uuid = '3F56E1C5-D6B9-1014-9A88-CDB8776B8231';
# Obtenu avec un générateur d'uuid
# Ou tout autre truc plus simple dont tu es sur que ça va jamais clasher avec les noms dans tes fichiers
 
# On traite d'abord $default_file
my %defaults;  # hash qui va contenir toute l'information utile parsée
$defaults{$uuid} = []; 
my $default_twig = XML::Twig->new( twig_handlers => { 'Parameter' => sub { my $cat_id = @{$defaults{$uuid}}[-1];
                                       my $name = $_->{'att'}->{'name'};
                                       # formatage spécial si on a un Target avec instance
                                       my $target = $_->first_child('Target');
                                       if ($target) {
                                         $name = $target->{'att'}->{'instance'}. '--' . $name ;
                                       }
                                       push @{$defaults{$cat_id}{$uuid}}, $name;
                                       # si on veut traiter le cas ou une valeur est égale à ""
                                       # il faut modifier ici
                                       $defaults{$cat_id}{$name} = $_->{'att'}->{'value'} // 'fault';}},
                   start_tag_handlers => { 'Catalog' => sub { my $cat_id = $_->{'att'}->{'id'};
                                          push @{$defaults{$uuid}}, $cat_id;
                                          $defaults{$cat_id}{$uuid} = [];} });
$default_twig->parsefile($default_file);
 
# structure du hash après parsing:
# $defaults{$uuid} est la liste des (id des) catalogues rencontrés
# et pour chaque catalogue $cat_id de cette liste
# $defaults{$cat_id}{$uuid} est la liste des (noms des) paramètres rencontrés dans le catalogue
# noter que s'il y a une target, le non est préfixé par l'instance du target
# et pour chaque paramètre $name de cette liste
# $defaults{$cat_id}{$name} est la valeur du paramètre (ou bien fault)
# faire ici un print Dumper(%defaults) si on veut visualiser la structure à la console
 
# On écrit en sortie ce qui a ét lu dans $default_file
open my $fhout, ">", $result_file;
# On écrit un timestamp en première ligne
print $fhout timestamp(), "\n";
# On écrit le nom (début du) du fichier par défaut
print $fhout ((split(/_/, basename($default_file)))[0]);
# puis la liste des noms d'attributs
foreach my $cat_id (@{$defaults{$uuid}}) {
  foreach my $name (@{$defaults{$cat_id}{$uuid}}) {
    print $fhout $sep_char, $name;
  }
}
print $fhout "\n";
# puis sur une nouvelle ligne, default, pour signifier la ligne des valeurs par défaut
print $fhout "default";
# puis les valeurs par défaut
foreach my $cat_id (@{$defaults{$uuid}}) {
  foreach my $name (@{$defaults{$cat_id}{$uuid}}) {
    print $fhout $sep_char, $defaults{$cat_id}{$name};
  }
}
print $fhout "\n";
 
# On traite maintenant les fichiers de données
foreach my $file (@files) {
  my %datas;  # hash qui va contenir toute l'information utile parsée
  $datas{$uuid} = [];
  my $datas_twig = XML::Twig->new( twig_handlers => { 'Parameter' => sub { my $cat_id = @{$datas{$uuid}}[-1];
                                       my $name = $_->{'att'}->{'name'};
                                       # formatage spécial si on a un Target avec instance
                                       my $target = $_->first_child('Target');
                                       if ($target) {
                                         $name = $target->{'att'}->{'instance'}. '--' . $name ;
                                       }
                                       push @{$datas{$cat_id}{$uuid}}, $name;
                                       # si on veut traiter le cas ou une valeur est égale à ""
                                       # il faut modifier ici
                                       $datas{$cat_id}{$name} = $_->{'att'}->{'value'} // 'fault';}},
                   start_tag_handlers => { 'Catalog' => sub { my $cat_id = $_->{'att'}->{'id'};
                                          push @{$datas{$uuid}}, $cat_id;
                                          $datas{$cat_id}{$uuid} = [];} });
  $datas_twig->parsefile($file);
 
  # et on écrit ce qui a été trouvé
  # d'abord le nom du fichier
  print $fhout  (split(/_/, ((split(/\./, basename($file)))[0])))[0];
  # puis la liste des valeurs
  foreach my $cat_id (@{$defaults{$uuid}}) {
    foreach my $name (@{$defaults{$cat_id}{$uuid}}) {
      print $fhout $sep_char, ($datas{$cat_id}{$name} // 'missing');
    }
  }
  print $fhout "\n";
}
close $fhout;

Bon, comme le forum et mon éditeur de texte n'ont pas la même notion de ce qu'est une tabulation, le formatage va sauter, mais j'ai la flemme de le refaire à la mimine.
EDIT: ah ben non, pour une fois, le formatage est resté à peu près bon.
A+,

Message édité par gilou le 09-12-2015 à 23:40:31

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

gilou

Modérateur
Modzilla

Un peu de détails

Code :

my %defaults;  # hash qui va contenir toute l'information utile parsée
$defaults{$uuid} = []; 
my $default_twig = XML::Twig->new( twig_handlers => { 'Parameter' => sub { my $cat_id = @{$defaults{$uuid}}[-1];
......
                   start_tag_handlers => { 'Catalog' => sub { my $cat_id = $_->{'att'}->{'id'};
                                          push @{$defaults{$uuid}}, $cat_id;
                                          $defaults{$cat_id}{$uuid} = [];} });

my %defaults; Je crée un hash
$defaults{$uuid} = []; Je crée une entrée pour la liste des catalogues: $defaults{$uuid} est (une référence à) une liste vide
Quand je trouve un nouveau catalogue
push @{$defaults{$uuid}}, $cat_id; Je mets son id (bref son nom) dans la liste des catalogues
$defaults{$cat_id}{$uuid} = []; puis je crée une entrée du hash global pour ce nom de catalogue, et pour cette entrée, je crée une sous entrée pour la liste des paramètres que je vais rencontrer dans le catalogue (et qui est donc créé comme vide au départ).

Code :

my $datas_twig = XML::Twig->new( twig_handlers => { 'Parameter' => sub { my $cat_id = @{$datas{$uuid}}[-1];
                                       my $name = $_->{'att'}->{'name'};
                                       
                                       push @{$datas{$cat_id}{$uuid}}, $name;
                                       
                                       $datas{$cat_id}{$name} = $_->{'att'}->{'value'} // 'fault';}},

Quand j'ai fini de parser un parametre
my $cat_id = @{$datas{$uuid}}[-1]; Je récupère le nom du catalogue courant, et
push @{$datas{$cat_id}{$uuid}}, $name; je colle le nom du paramètre dans la liste des paramètres du catalogue courant
$datas{$cat_id}{$name} = $_->{'att'}->{'value'} et j'associe le nom et la valeur dans le catalogue courant

A+,

Message édité par gilou le 09-12-2015 à 23:56:20

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Henri772

tres grand merci Gilou, ca fonctionne bien mais il ya quelque chose que je vais signale si c'est trop te demande, pas de probleme je reflechirait comment le resoudre a savoir comment supprime les 'value' qui n'on pas de 'name' correspondant, tout ce marque en bleu clair ne me sert a rien.

Merci bien des explications
A+

Message édité par Henri772 le 20-12-2015 à 16:11:18

gilou

Modérateur
Modzilla

C'est bizarre, chez moi, je n'ai aucun champ correspondant à un name sans valeur et tout est au clair dans excel:
voir ici dans l'image le dernier champ, il n'y a rien après.
Ça veut donc dire que tu as des trucs de la forme
<Parameter name="" value="fast_fail">
dans ton fichier par défaut?

Bon, c'est pas compliqué, tes names n'ont certainement pas "aucune valeur", ils ont une valeur réduite à la chaine vide "".
Donc ça va se faire à ce niveau la:

Code :

my $default_twig = XML::Twig->new( twig_handlers => { 'Parameter' => sub { my $cat_id = @{$defaults{$uuid}}[-1];
                                       my $name = $_->{'att'}->{'name'};
                                       # formatage spécial si on a un Target avec instance
                                       my $target = $_->first_child('Target');
                                       if ($target) {
                                         $name = $target->{'att'}->{'instance'}. '--' . $name ;
                                       }
                                       push @{$defaults{$cat_id}{$uuid}}, $name;
                                       # si on veut traiter le cas ou une valeur est égale à ""
                                       # il faut modifier ici
                                       $defaults{$cat_id}{$name} = $_->{'att'}->{'value'} // 'fault';}},

Une fois que tu as le name:
my $name = $_->{'att'}->{'name'};
Tu testes qu'il n'est pas vide avant de l'ajouter à la liste:
if ($name ne "" ) {
if ($target) {
$name = $target->{'att'}->{'instance'}. '--' . $name ;
}
push @{$defaults{$cat_id}{$uuid}}, $name;
# si on veut traiter le cas ou une valeur est égale à ""
# il faut modifier ici
$defaults{$cat_id}{$name} = $_->{'att'}->{'value'} // 'fault';
}
}},
et ça devrait rouler: comme on vire les paramètres sans nom, on vire du coup aussi leur valeurs.
Tu peux aussi reporter le même test dans le code de $datas_twig histoire d'avoir le même code pour les deux handlers (ça devrait pas influer sur ce qu'on obtient en sortie, mais autant avoir un code clair et homogène).

A+,

Message cité 1 fois
Message édité par gilou le 10-12-2015 à 12:21:26

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Henri772

gilou a écrit :

Code :

my $default_twig = XML::Twig->new( twig_handlers => { 'Parameter' => sub { my $cat_id = @{$defaults{$uuid}}[-1];
                                       my $name = $_->{'att'}->{'name'};
                                       # formatage spécial si on a un Target avec instance
                                       my $target = $_->first_child('Target');
                                       if ($target) {
                                         $name = $target->{'att'}->{'instance'}. '--' . $name ;
                                       }
                                       push @{$defaults{$cat_id}{$uuid}}, $name;
                                       # si on veut traiter le cas ou une valeur est égale à ""
                                       # il faut modifier ici
                                       $defaults{$cat_id}{$name} = $_->{'att'}->{'value'} // 'fault';}},

c'est vraiment etrange ce que cela marche bien chez toi et chez moi ca ne deonne pas, regarde J'ai effectuer le changement comme tu me l'a conceille malheursement c'est toujours sans changement

Code :

my $default_twig = XML::Twig->new( twig_handlers => { 'Parameter' => sub { my $cat_id = @{$defaults{$uuid}}[-1];
                                           my $name = $_->{'att'}->{'name'};
                                           # formatage spécial si on a un Target avec instance
                                           my $target = $_->first_child('Target');
                                           if ($name ne "" ) {
                                             if ($target) {
                                             $name = $target->{'att'}->{'instance'}. '--' . $name ;
                                           }
                                           push @{$defaults{$cat_id}{$uuid}}, $name;
                                           # si on veut traiter le cas ou une valeur est égale à ""
                                           # il faut modifier ici
                                           $defaults{$cat_id}{$name} = $_->{'att'}->{'value'} // 'fault';}}},

Code :

my $datas_twig = XML::Twig->new( twig_handlers => { 'Parameter' => sub { my $cat_id = @{$datas{$uuid}}[-1];
                                           my $name = $_->{'att'}->{'name'};
                                           # formatage spécial si on a un Target avec instance
                                           my $target = $_->first_child('Target');
                                           if ($name ne "" ) {
                                              if ($target) {
                                             $name = $target->{'att'}->{'instance'}. '--' . $name ;
                                           }
                                           push @{$datas{$cat_id}{$uuid}}, $name;
                                           # si on veut traiter le cas ou une valeur est égale à ""
                                           # il faut modifier ici
                                           $datas{$cat_id}{$name} = $_->{'att'}->{'value'} // 'fault';}}},

gilou

Modérateur
Modzilla

Vérifie alors que ça vient pas de ton excel (j'utilise excel 2013).
Sinon, je peux pas t'en dire plus vu que chez moi ça marche.
(mon perl est celui de Active State sur PC)

A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Henri772

Dit quelle perl- version est sur ton PC la j'ai la v5.16.3
A+

Message édité par Henri772 le 10-12-2015 à 15:07:22

gilou

Modérateur
Modzilla

Citation :

This is perl 5, version 20, subversion 2 (v5.20.2) built for MSWin32-x86-multi-thread-64int

Bref, la version courante (et à jour) de Active State. La v5.16, elle a plus de 3 ans.

A+,

Message édité par gilou le 10-12-2015 à 16:04:35

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Henri772

je demande cette initialisation je ne comprend pas cela

my $uuid = '3F56E1C5-D6B9-1014-9A88-CDB8776B8231';

gilou

Modérateur
Modzilla

C'est pour avoir un identifiant qui ne risque pas d'être trouvé comme un nom de catalogue ou un nom de paramètre (bref c'est un nom spécial pour coller la liste des catalogue, et pour chaque catalogue la liste des paramètres trouvés dedans comme des entrées de %defaults sans que ce soit confondu avec entrées de %defaults provenant de ce qui a ét lu dans le fichier.
Si tu regardes la structure en faisant
print Dumper(%defaults);
La ou je te l'ai indiqué, ça devrait être assez clair:
Sur un exemple bidon comme celui ci:

Code :

<?xml version="1.0" encoding="UTF-8"?>
<Profile origin="get" version="3.0.1" date="2015-12-02T11:44:17Z">
 <Catalog id="Catalogue1" version="2.0">
  <Parameter name="Parametre1" value="Valeur1"/>
  <Parameter name="Parametre2" value="Valeur2"/>
 </Catalog>
 <Catalog id="Catalogue2" version="2.0">
  <Parameter name="file" value="/dev/null">
   <Target class="example" instance="NetBios"/>
  </Parameter>
  <Parameter name="file" value="/dev/null">
   <Target class="example" instance="LanManager"/>
  </Parameter>
 </Catalog>
</Profile>

Ca donne en sortie de Dumper:

$VAR1 = 'Catalogue1';
$VAR2 = {
'Parametre1' => 'Valeur1',
'Parametre2' => 'Valeur2',
'3F56E1C5-D6B9-1014-9A88-CDB8776B8231' => [
'Parametre1',
'Parametre2'
]
};
$VAR3 = 'Catalogue2';
$VAR4 = {
'LanManager--file' => '/dev/null',
'NetBios--file' => '/dev/null',
'3F56E1C5-D6B9-1014-9A88-CDB8776B8231' => [
'NetBios--file',
'LanManager--file'
]
};
$VAR5 = '3F56E1C5-D6B9-1014-9A88-CDB8776B8231';
$VAR6 = [
'Catalogue1',
'Catalogue2'
];

Bref on a une structure

%defaults = { 'Catalogue1' => { 'Parametre1' => 'Valeur1',
'Parametre2' => 'Valeur2',
'3F56E1C5-D6B9-1014-9A88-CDB8776B8231' => [ 'Parametre1',
'Parametre2'
]
},
'Catalogue2' => { 'LanManager--file' => '/dev/null',
'NetBios--file' => '/dev/null',
'3F56E1C5-D6B9-1014-9A88-CDB8776B8231' => [ 'NetBios--file',
'LanManager--file'
]
},
'3F56E1C5-D6B9-1014-9A88-CDB8776B8231' => [ 'Catalogue1',
'Catalogue2'
]
}
}

Je suis obligé de maintenir ces listes avec '3F56E1C5-D6B9-1014-9A88-CDB8776B8231' afin d'avoir le bon ordre, car les clés d'un hash ne sont pas dans l'ordre ou elles ont été lues dans le fichier (en fait, elles sont même dans un ordre aléatoire qui change à chaque exécution dans les versions modernes de Perl)

A+,

Message édité par gilou le 10-12-2015 à 19:41:01

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Henri772

Merci bien de l'explication, j'ai essaye aussi avec le Dumper
j'ai meme change de version malheureusement toujours rien.
Mes sinceres remerciement a toi Gilou

Salut Gilou je pense que j'ai compris a quel niveau le probleme se trouve le probleme quand il rencontre les 'value' comme sur la foto

il ecrit cela dans plusieurs champs.

A-

Message édité par Henri772 le 20-12-2015 à 16:13:07

Henri772

Le probleme a ete resolu c'etait effectivement au niveau d'excel comme tu l'avais deja souligne. Quand on utilise la nouvelle version 2013 on n'a plus se probleme.

Publicité

FORUM HardWare.fr

Programmation

Perl

certain conditions ne menacant

Sujets relatifs
Copier une colonne sous conditions d'une autre colonne	Copie de cellules sous conditions.
Question pour les conditions et les variables	Programme VBA trouvant une valeur répondant à des conditions ET/OU
Fonction "si" à deux conditions	Envoyer plusieurs mails avec des conditions dans le message
Delete from avec conditions multiples	Problème formule à plusieurs conditions
[VBA]Calcul du nombre de lignes avec 3 conditions non numériques	Macro excel supprimer une ligne sous conditions
Plus de sujets relatifs à : certain conditions ne menacant

Page générée en 0.257 secondes