XSLT

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : XSLT

billouxs

Bonsoir tout le monde,

Donc voila je coince depuis un moment pour transformer mon fichier xml en html.
Le problème c'est j'arrive pas à mettre les titres et prix des livres pour chaque éditeurs,
voici mon code xml :

Code :

<?xml version="1.0" encoding="utf-8" ?>
<livres>
<livre isbn="2841771482" annee="2002">
<titre>Comprendre XSLT</titre>
<auteur>Bernd Amann</auteur>
<auteur>Philippe Rigaux</auteur>
<resume>les webmastres d’aujourd’hui cherche</resume>
</livre>
<livre isbn="2841772373" annee="2003">
<titre>Pratique de MYSQL et PHP</titre>
<auteur>Philippe Rigaux </auteur>
</livre>
<livre isbn="2841779754" annee="1988">
<titre>Savoir Programmer</titre>
<auteur>Marc Lemaire</auteur>
<auteur>Laurence Cesarini</auteur>
<auteur>Dan Vodislav</auteur>
<resume>Programmation pour les nuls</resume>
</livre>
<livre isbn="2456652271" annee="1994">
<titre>Base de donnée Mysql/Oracle</titre>
<auteur>Brahim Derdouri</auteur>
<auteur>Mohammed Naîmi</auteur>
</livre>
<livre isbn="2456652401" annee="2004">
<titre>Architecture des Ordinateurs</titre>
<auteur>Bennoît Miramond</auteur>
</livre>
<livre isbn="2456651054" annee="2009">
<titre>Logique et Programmation Logique</titre>
<auteur>Yannick Kergosien</auteur>
<auteur>Hans Rugh</auteur>
<auteur>Christian Daveau</auteur>
<auteur>Laura Hernandez</auteur>
</livre>
<livre isbn="2456659083" annee="2000">
<titre>Developpement Web</titre>
<auteur>Sebastien Chavanel</auteur>
<auteur>Programmation Systeme</auteur>
</livre>
<livre isbn="2456651121" annee="2012">
<titre>Réseau et Déploiment</titre>
<auteur>Dntt</auteur>
</livre>
<editeur nom="0'Reilly">
<isbn prix="18">2841772373</isbn>
<isbn prix="33">2841771482</isbn>
<isbn prix="14">2841779754</isbn>
</editeur>
<editeur nom="Dunod">
<isbn prix="18">2456652271</isbn>
<isbn prix="53">2456652401</isbn>
<isbn prix="13">2456651054</isbn>
<isbn prix="23">2456659083</isbn>
<isbn prix="10">2456651121</isbn>
</editeur>
</livres>

Code :

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<html>
<head>
<title>Exemple de sortie HTML</title>
<meta http-equiv="Content-Type" content="text/html; charset=ISO-8859-1" />
</head>
<body>
<xsl:for-each select="//editeur">
<xsl:value-of select="@nom" /> (
<xsl:value-of select="count(isbn)" /> Livres)
<ol><xsl:for-each select="//livre">
<li><xsl:if test="@isbn = //editeur/isbn">
<xsl:value-of select="titre" />
(<xsl:value-of select="@annee" /> )
<xsl:value-of select="//editeur/isbn/@prix" /> euros,
nombre d'auteurs : <xsl:value-of select="count(auteur)" />
</xsl:if>
</li>
</xsl:for-each>
</ol>
</xsl:for-each>
</body>
</html>
</xsl:template>
</xsl:stylesheet>

et voila le résultat en html :

0'Reilly ( 3 Livres)

1.Comprendre XSLT (2002) 18 euros, nombre d'auteurs : 2
2.Pratique de MYSQL et PHP (2003) 18 euros, nombre d'auteurs : 1
3.Savoir Programmer (1988) 18 euros, nombre d'auteurs : 3
4.Base de donnée Mysql/Oracle (1994) 18 euros, nombre d'auteurs : 2
5.Architecture des Ordinateurs (2004) 18 euros, nombre d'auteurs : 1
6.Logique et Programmation Logique (2009) 18 euros, nombre d'auteurs : 4
7.Developpement Web (2000) 18 euros, nombre d'auteurs : 2
8.Réseau et Déploiment (2012) 18 euros, nombre d'auteurs : 1

Dunod ( 5 Livres)

1. Comprendre XSLT (2002) 18 euros, nombre d'auteurs : 2
2.Pratique de MYSQL et PHP (2003) 18 euros, nombre d'auteurs : 1
3.Savoir Programmer (1988) 18 euros, nombre d'auteurs : 3
4.Base de donnée Mysql/Oracle (1994) 18 euros, nombre d'auteurs : 2
5.Architecture des Ordinateurs (2004) 18 euros, nombre d'auteurs : 1
6.Logique et Programmation Logique (2009) 18 euros, nombre d'auteurs : 4
7.Developpement Web (2000) 18 euros, nombre d'auteurs : 2
8.Réseau et Déploiment (2012) 18 euros, nombre d'auteurs : 1

alors que le résultat devrait ressembler a ceci :

0'Reilly ( 3 Livres)

1.Comprendre XSLT (2002) 18 euros, nombre d'auteurs : 2
2.Pratique de MYSQL et PHP (2003) 33 euros, nombre d'auteurs : 1
3.Savoir Programmer (1988) 14 euros, nombre d'auteurs : 3

Dunod ( 5 Livres)

1.Base de donnée Mysql/Oracle (1994) 18 euros, nombre d'auteurs : 2
2.Architecture des Ordinateurs (2004) 53 euros, nombre d'auteurs : 1
3.Logique et Programmation Logique (2009) 13 euros, nombre d'auteurs : 4
4.Developpement Web (2000) 23 euros, nombre d'auteurs : 2
5.Réseau et Déploiment (2012) 10 euros, nombre d'auteurs : 1

S'il vous plait aidez moi
MERCI

Publicité

gilou

Modérateur
Modosaurus Rex

En modifiant le moins possible ton code:

Code :

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:key name="ISBN" match="livre" use="@isbn"/>  

  <xsl:template match="/">
    <html>
      <head>
    <title>Exemple de sortie HTML</title>
    <meta http-equiv="Content-Type" content="text/html; charset=ISO-8859-1" />
      </head>
      <body>
    <xsl:for-each select="//editeur">  
      <b>
        <xsl:value-of select="@nom" /> (
        <xsl:value-of select="count(isbn)" /> Livres)
        <br/>
      </b>
      <ol><xsl:for-each select="isbn">
        <xsl:call-template name="livre">
        <xsl:with-param name="PRIX" select="@prix"/>
        <xsl:with-param name="LIVRE" select="key('ISBN', text())"/>
        </xsl:call-template>
      </xsl:for-each>
      </ol>
    </xsl:for-each>
      </body>
    </html>
  </xsl:template>

  <xsl:template name="livre">
    <xsl:param name="PRIX"/>  
    <xsl:param name="LIVRE"/>  
    <li><i><xsl:value-of select="$LIVRE/titre" /></i>
    (<xsl:value-of select="$LIVRE/@annee" /> )
    <xsl:value-of select="$PRIX" /> euros,
    nombre d'auteurs : <xsl:value-of select="count($LIVRE/auteur)" /></li>  
  </xsl:template>

</xsl:stylesheet>

Testé avec Saxon, et ça donne la sortie que tu désires.
J'ai écrit ça vite fait, il y a peut être plus élégant.
A+,

Message édité par gilou le 18-06-2012 à 03:18:43

---------------
There's more than what can be linked! -- Le capitaine qui ne veut pas obéir à la carte finira par obéir aux récifs. -- Il ne faut plus dire Sarkozy, mais Sarkozon -- (╯°□°)╯︵ ┻━┻

gilou

Modérateur
Modosaurus Rex

Bon, maintenant que je suis réveillé, quelques commentaires:

<xsl:key name="ISBN" match="livre" use="@isbn"/>
ça crée une sorte d'associative array, avec pour clé, la valeur de l'expression use dans le contexte du match, et comme valeur, une node list qui contiendra le match (et d'autres si on en rencontre plus tard avec la même valeur de clé).

<xsl:template name="livre">
<xsl:param name="PRIX"/>
<xsl:param name="LIVRE"/>
...
</xsl:template>
c'est comme une déclaration de fonction livre(PRIX, LIVRE) ou PRIX et LIVRE sont les deux parametres.
Dans le corps de la fonction, les paramètres sont représentés précédés d'un $: $LIVRE, $PRIX

<xsl:call-template name="livre">
<xsl:with-param name="PRIX" select="@prix"/>
<xsl:with-param name="LIVRE" select="key('ISBN', text())"/>
</xsl:call-template>
c'est comme l'appel de la fonction livre(@prix, key('ISBN', text()), ou la valeur des paramètres passés à l'appel est évaluée dans le contexte de l'appel.

Au vu de ton fichier xml, il était clair qu'on pouvait indexer les livres par leur valeur d'isbn, d'ou la déclaration de l'element xsl:key.

<xsl:for-each select="//editeur">
...
<xsl:for-each select="isbn">
...
</xsl:for-each>
</xsl:for-each>
permet de traiter les livres pour chaque éditeur.

On est obligé de passer par un template nommé, car il faut des infos venant de deux contextes différents, celui des livres, et celui de l'éditeur, pour le prix.
Si on n'avait pas besoin du prix, un template normal de traitement des livres aurait suffi, <xsl:template match="livre">... avec un appel <xsl:apply-template select="key('ISBN', text())"/> à la place du template nommé.

A+,

Message édité par gilou le 18-06-2012 à 11:32:21

rufo

Pas me confondre avec Lycos!

Y'aurait peut-être à revoir la structure du xml pour avoir toutes les infos nécessaires sous la balise <livre> pour que ça soit plus simple à traiter

Message cité 1 fois

---------------
Astres, outil de help-desk GPL : http://sourceforge.net/projects/astres, ICARE, gestion de conf : http://sourceforge.net/projects/icare, Outil Planeta Calandreta : https://framalibre.org/content/planeta-calandreta

billouxs

Bonjour ,

Merci guilou pour ta réponse si rapide et si explicite .

gilou

Modérateur
Modosaurus Rex

rufo a écrit :

Y'aurait peut-être à revoir la structure du xml pour avoir toutes les infos nécessaires sous la balise <livre> pour que ça soit plus simple à traiter

Parfois on n'a pas la maîtrise de ce genre de choses. Et c'est justement pour cela qu'il y a le xslt.
A+,

rufo

Pas me confondre avec Lycos!

tout à fait, mais il n'a pas indiqué qu'il n'avait pas la maîtrise du xml...

FORUM HardWare.fr

Programmation

XML/XSL

XSLT

Sujets relatifs
XSLT / XML : position d'un noeud	Modifier le fichier xml avec un feuille XSLT
[XSLT] déclaration de namespace et localisation attribut	transformation du fichier XML vers TEX avec XSLT
Transformer du XML en WSDL avec XSLT ?	Servlet +xml+xslt => flux rss = problèmes
XSLT: utilisation de la fonction position() dans <for-each> imbriqués	[XSLT 2.0] Récupérer le PATH d'un élément //LINE
Débutant XSLT	XSLT somme par type de produit
Plus de sujets relatifs à : XSLT

Page générée en 0.086 secondes