Changer nom element et garder les namespaces

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : Changer nom element et garder les namespaces

tahrky

Bonjour à tous,

Je travaille en XSLT, et je souhaite recopier un élément et changer son nom. Sauf que je perds les namespaces (ajouté automatiquement par XSLT) dans la manip.

Dans ce cas là, j'ai bien un élément avec le nouveau nom et le contenu qu'il faut, mais il n'a pas les xlmns nécessaires.

Code :

<xsl:for-each select="//unit | //reinforcement | //roe | //object">
<xsl:element name="object">
<xsl:copy-of select="@*"/>
<xsl:copy-of select="*"/>
</xsl:element>
</xsl:for-each>

Et là, j'ai bien les namespaces ajoutés automatiquement, mais evidemment pas le bon nom.

Code :

<xsl:for-each select="//unit | //reinforcement | //roe | //object">
<xsl:copy-of select="."/>
</xsl:for-each>

Mon problème est que je ne peux pas me permettre d'ajout les namespaces à la main, parce qu'il y en a bien trop. Je cherche donc à automatiser, si quelqu'un serait capable de m'aider .

Merci d'avance.

Publicité

Xavier_OM

Monarchiste régicide (fr quoi)

Si tu renommes sur place j'aurais tenté un truc tout bête comme ça moi :

Renommer aaa en bbb :

<xsl:template match="aaa">
<bbb>
<xsl:apply-templates/>
</bbb>
</xsl:template>

Voire :

<xsl:template match="aaa">
<xsl:element name="bbb" namespace="{namespace-uri()}">
<xsl:apply-templates select="@* | node()" />
</xsl:element>
</xsl:template>

Mais bon pas de raison que la première version touche les namespaces je pense.

---------------
Il y a autant d'atomes d'oxygène dans une molécule d'eau que d'étoiles dans le système solaire.

tahrky

Ça ne fonctionne pas, voici avec des screens ce que j'obtiens, ce sera peut-être plus clair ? Je m'y suis peut-être mal pris.

La j'ai le namespace où il faut, mais pas d'élement renommé :

La, je n'ai pas le namespace automatiquement ajouté par XSLT :

Le apply-templates ne fonctionne pas du tout ici.

Xavier_OM

Monarchiste régicide (fr quoi)

Au lieu de mettre des screenshots d'un cas réel, tu devrais mettre du texte représentant un cas simple de ce que tu veux faire (et qui ne marche pas).

Pour transformer un document xml avec xslt c'est en général mieux d'utiliser d'utiliser <xsl:template match=".... et xsl:apply-templates plutôt que de faire des <xsl:for-each

Exemple de ce que tu pourrais poster :

1. Un morceau d'xml type

Code :

<?xml version="1.0" encoding="UTF-8"?>
<root name="Coucou">
    <foo id="42">
        <bar id="42" />
    </foo>
</root>

Le bout d'xsl qui va avec :

Code :

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:exslt="urn:schemas-microsoft-com:xslt"
>
    <!-- generic rule : copy as if -->
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>
 
    <!-- specific rule : foo becomes FOO -->
    <xsl:template match="foo">
        <FOO>
            <xsl:apply-templates/>
        </FOO>
    </xsl:template>
</xsl:stylesheet>

Et ce que tu obtiens en sortie : xsltproc test.xsl test.xml

Code :

<?xml version="1.0"?>
<root name="Coucou">
    <FOO xmlns:exslt="urn:schemas-microsoft-com:xslt">
        <bar id="42"/>
    </FOO>
</root>

Message cité 1 fois
Message édité par Xavier_OM le 18-09-2020 à 12:29:05

---------------
Il y a autant d'atomes d'oxygène dans une molécule d'eau que d'étoiles dans le système solaire.

tahrky

Xavier_OM a écrit :

Au lieu de mettre des screenshots d'un cas réel, tu devrais mettre du texte représentant un cas simple de ce que tu veux faire (et qui ne marche pas).

Pour transformer un document xml avec xslt c'est en général mieux d'utiliser d'utiliser <xsl:template match=".... et xsl:apply-templates plutôt que de faire des <xsl:for-each

Merci pour ton aide, j'ai appris XSLT seul alors je travaille probablement de la mauvaise manière.

Je cherche à prendre un XML entrant, qui correspond à un message A, et à le transformer en message B, avec une structure entièrement différente. Je n'arrive pas à poser le problème avec un cas simple comme tu le demandes. Les exemples simplifiés trouvés sur le net ne répondent pas à ma question.

Message cité 1 fois

Xavier_OM

Monarchiste régicide (fr quoi)

tahrky a écrit :

J'ai posté dans mon message précédent le genre de choses qu'il faudrait que tu postes ici pour qu'on comprenne ton problème :jap:

---------------
Il y a autant d'atomes d'oxygène dans une molécule d'eau que d'étoiles dans le système solaire.

tahrky

Voilà mon fichier XML en entrée simplifié, je laisse l'arborescence pour montrer qu'il y a plusieurs endroits ou on peut trouver les elements.

Code :

<?xml version="1.0" encoding="utf-8"?>
<nc1opordain:NC1_OPORD-AIN xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:nc1opordain="urn:fra:nc1:message:opordain">
<taskOrganisation>
<member>
<reinforcement xmlns:nc1reinforcement="urn:fra:nc1:objet:reinforcement" xsi:type="nc1reinforcement:ReinforcementType">
<tacticalData>
<name>Nom-D1239</name>
</tacticalData>
</reinforcement>
</member>
<member>
<unit xmlns:nc1unit="urn:fra:nc1:objet:unit" xsi:type="nc1unit:UnitType">
<tacticalData>
<name>Nom-D1289</name>
</tacticalData>
</unit>
</member>
</taskOrganisation>
<_3_execution>
<D_artillerySupport>
<D1_fieldArtillery>
<reinforcements>
<reinforcement xmlns:nc1reinforcement="urn:fra:nc1:objet:reinforcement" xsi:type="nc1reinforcement:ReinforcementType">
<tacticalData>
<comment>b</comment>
</tacticalData>
</reinforcement>
</reinforcements>
</D1_fieldArtillery>
</D_artillerySupport>
</_3_execution>
</nc1opordain:NC1_OPORD-AIN>

Voici mon XSLT :

Code :

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:fn="http://www.w3.org/2005/xpath-functions"
xmlns:nc1messagelibre="urn:fra:nc1:message:messagelibre"
xmlns:nc1opordain="urn:fra:nc1:message:opordain"
exclude-result-prefixes="xs fn"
version="2.0">
<xsl:output
method="xml"
encoding="UTF-8"
indent="yes"
omit-xml-declaration="no"
/>
<xsl:strip-space elements="*" />
<xsl:template match="nc1opordain:NC1_OPORD-AIN//@*|node()" mode="OpordAINToMessageLibre">
<xsl:element name="nc1messagelibre:NC1_MessageLibre">
<xsl:namespace name="xsi" select="'http://www.w3.org/2001/XMLSchema-instance'"/>
<xsl:copy-of select="@*"/>
<xsl:element name="subject">
<xsl:value-of select="'OPORD-AIN'"/>
</xsl:element>
<xsl:element name="body">
<xsl:element name="mixedText">
<xsl:variable name="var" select="*"/>
<xsl:apply-templates select="$var" mode="serialize"/>
</xsl:element>
<xsl:element name="objects">
<xsl:for-each select="//unit | //reinforcement | //roe | //object">
<xsl:apply-templates select="." />
</xsl:for-each>
</xsl:element>
</xsl:element>
</xsl:element>
</xsl:template>
<xsl:template match="*" mode="serialize">
<xsl:text><</xsl:text>
<xsl:value-of select="name()"/>
<xsl:text>></xsl:text>
<xsl:apply-templates mode="serialize"/>
<xsl:text></</xsl:text>
<xsl:value-of select="name()"/>
<xsl:text>></xsl:text>
</xsl:template>
<xsl:template match="text()" mode="serialize">
<xsl:value-of select="."/>
</xsl:template>
</xsl:stylesheet>

Et voilà ce que je cherche à retrouver à la fin :

Code :

<?xml version="1.0" encoding="UTF-8"?>
<nc1messagelibre:NC1_MessageLibre xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:nc1messagelibre="urn:fra:nc1:message:messagelibre">
<subject>OPORD-AIN</subject>
<mixedText/>
<body>
<objects>
<object xmlns:nc1reinforcement="urn:fra:nc1:objet:reinforcement" xsi:type="nc1reinforcement:ReinforcementType">
<tacticalData>
<name>Nom-D1239</name>
</tacticalData>
</object>
<object xmlns:nc1unit="urn:fra:nc1:objet:unit" xsi:type="nc1unit:UnitType">
<tacticalData>
<name>Nom-D1289</name>
</tacticalData>
</object>
<object xmlns:nc1reinforcement="urn:fra:nc1:objet:reinforcement" xsi:type="nc1reinforcement:ReinforcementType">
<tacticalData>
<comment>b</comment>
</tacticalData>
</object>
</objects>
</body>
</nc1messagelibre:NC1_MessageLibre>

J'espère que ce sera plus clair et suffisant . J'aurais du mal à simplifier plus. J'ai laissé le minimum pour comprendre ma situation, en esperant que ce soit suffisant !
Merci beaucoup de tenter de m'aider en tout cas .

Xavier_OM

Monarchiste régicide (fr quoi)

Parfait c'est beaucoup plus clair comme ça, je regarde ton xsl et je te dis ce que je trouve.

---------------
Il y a autant d'atomes d'oxygène dans une molécule d'eau que d'étoiles dans le système solaire.

Xavier_OM

Monarchiste régicide (fr quoi)

Un truc comme ça devrait te mettre sur la bonne voie :

Code :

<?xml version="1.0" encoding="UTF-8"?>
    <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns:xs="http://www.w3.org/2001/XMLSchema"
        xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
        xmlns:fn="http://www.w3.org/2005/xpath-functions"
        xmlns:nc1messagelibre="urn:fra:nc1:message:messagelibre"
        xmlns:nc1opordain="urn:fra:nc1:message:opordain"
        xmlns:nc1reinforcement="urn:fra:nc1:message:reinforcement"
        exclude-result-prefixes="xs fn"
        version="2.0">

        <xsl:output
            method="xml"
            encoding="UTF-8"
            indent="yes"
            omit-xml-declaration="no"
        />
            <xsl:strip-space elements="*" />

            <!-- identity rule : copy as if -->
            <xsl:template match="@*|node()">
                <xsl:copy>
                    <xsl:apply-templates select="@*|node()" />
                </xsl:copy>
            </xsl:template>


            <!-- what happens when we encounter a child of 'member' -->
            <xsl:template match="//member/*" >
                <xsl:element name="object">
                    <!-- copy all attributes from matched node -->
                    <xsl:copy-of select="@*"/>

                    <!-- let the identity rule do the job for the rest -->
                    <xsl:apply-templates />
                </xsl:element>
            </xsl:template>

            <!-- everything starts here -->
            <xsl:template match='/'>
                <xsl:element name="nc1messagelibre">
                    <xsl:element name='subject'>
                        <xsl:value-of select='name(node())'/>
                    </xsl:element>

                    <xsl:element name='mixedText'/>

                    <xsl:element name='body'>
                        <xsl:element name='objects'>
                            <!-- search for all 'member/xxx' anywhere below root -->
                            <xsl:apply-templates select='//member/*' />
                        </xsl:element>
                    </xsl:element>
                </xsl:element>
            </xsl:template>

        </xsl:stylesheet>

Une chose importante sur les namespaces : tous les nœuds héritent des attributs xmlns de leur parents

Donc ces deux choses sont strictement équivalentes :

Code :

<root xmlns:ct-ext="http://test.com/test-ext">
  <ct-ext:case xmlns:ct-ext="http://test.com/test-ext">...</ct-ext:case>
</root>

<root xmlns:ct-ext="http://test.com/test-ext">
  <ct-ext:case>...</ct-ext:case>
</root>

Ça explique du coup que selon l'endroit où tu vas faire le <xsl-copy-of/> tu verras ou non apparaître les attributs xmlns des nœuds parents ou pas.

---------------
Il y a autant d'atomes d'oxygène dans une molécule d'eau que d'étoiles dans le système solaire.

tahrky

Merci pour ton aide, certaines choses sont un peu plus clair dans mon esprit, cependant, je me retrouve avec ça en sortie, ce qui ne fonctionne pas.

Code :

<object xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xsi:type="nc1reinforcement:ReinforcementType">
<tacticalData xmlns:nc1reinforcement="urn:fra:nc1:objet:reinforcement"
xmlns:nc1opordain="urn:fra:nc1:message:opordain">
<name>Nom-D1239</name>
</tacticalData>
</object>

c'est objet qui devrait avoir le xmlns:nc1reinforcement="urn:fra:nc1:objet:reinforcement", pas tacticalData. Le XSD de contrôle n'aime pas ça, et je n'arrive pas à remonter d'au moins un niveau l'information.

Merci encore beaucoup pour ton aide .

EDIT : Je peux régler le probleme en faisant une recherche de tous les namespaces dans le fichier, et les recopier comme attribut, je devrais y arriver. Cependant je reste curieux de savoir s'il est possible de faire ce que je cherche à faire ^^.

Merci beaucoup pour ton aide en tout cas.

Message cité 2 fois
Message édité par tahrky le 18-09-2020 à 16:34:13

Publicité

Xavier_OM

Monarchiste régicide (fr quoi)

tahrky a écrit :

Merci pour ton aide, certaines choses sont un peu plus clair dans mon esprit, cependant, je me retrouve avec ça en sortie, ce qui ne fonctionne pas.

Code :

<object xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xsi:type="nc1reinforcement:ReinforcementType">
<tacticalData xmlns:nc1reinforcement="urn:fra:nc1:objet:reinforcement"
xmlns:nc1opordain="urn:fra:nc1:message:opordain">
<name>Nom-D1239</name>
</tacticalData>
</object>

c'est objet qui devrait avoir le xmlns:nc1reinforcement="urn:fra:nc1:objet:reinforcement", pas tacticalData. Le XSD de contrôle n'aime pas ça, et je n'arrive pas à remonter d'au moins un niveau l'information. Il pourrait être au niveau de l'élément messageLibre, ça ne serait pas gênant, mais je ne peux pas me permettre de le mettre à la main, j'ai plusieurs dizaines de namespace à traiter, et je ne les connais pas à l'avance.

Merci encore beaucoup pour ton aide .

Tu peux peut-être éviter que les namespaces n'apparaissent en mettant copy-namespaces="no" dans la identity rule

Code :

<xsl:template match="@*|node()">
    <xsl:copy copy-namespaces="no" >
        <xsl:apply-templates select="@*|node()" />
    </xsl:copy>
</xsl:template>

vu que c'est elle qui copie tacticalData

---------------
Il y a autant d'atomes d'oxygène dans une molécule d'eau que d'étoiles dans le système solaire.

gilou

Modérateur
Modosaurus Rex

Code :

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:fn="http://www.w3.org/2005/xpath-functions"
xmlns:nc1messagelibre="urn:fra:nc1:message:messagelibre"
xmlns:nc1opordain="urn:fra:nc1:message:opordain"
xmlns:nc1reinforcement="urn:fra:nc1:objet:reinforcement"
xmlns:nc1unit="urn:fra:nc1:objet:unit"
exclude-result-prefixes="xs fn nc1reinforcement nc1unit nc1opordain"
version="2.0">
<xsl:template match="/|@*|*" priority="-1">
<xsl:apply-templates select="@*|*"/>
</xsl:template>
<xsl:template match="nc1opordain:NC1_OPORD-AIN">
<nc1messagelibre:NC1_MessageLibre>
<subject>OPORD-AIN</subject>
<mixedText/>
<body>
<objects>
<xsl:apply-templates select="*"/>
</objects>
</body>
</nc1messagelibre:NC1_MessageLibre>
</xsl:template>
<xsl:template match="(reinforcement|unit)[tacticalData]">
<xsl:if test="@xsi:type">
<object>
<xsl:namespace name="{substring-before(@xsi:type, ':')}" select="concat('urn:fra:nc1:objet:', local-name())"/>
<xsl:copy-of select="@xsi:type"/>
<xsl:copy-of select="tacticalData" copy-namespaces="no"/>
</object>
</xsl:if>
</xsl:template>
</xsl:stylesheet>

Le seul truc un poil coton, c'est que la transfo a tendance a perdre la déclaration du namespace de la valeur d'attribut ou la mettre sur l'élément suivant si on ne le fait pas explicitement à la main.
Testé sous Oxygen. Le Texte/Grille d'une de tes captures d'écran me laisse supposer que c'est ce que tu utilises. Si oui, pourquoi ne pas faire du xsl 3.0, c'est quand même bien plus pratique.
Bon après, tu adaptes si il y a des choses plus paramétrées et simplifiées dans ce que tu fais.
Typiquement j'ai mis <xsl:template match="(reinforcement|unit)[tacticalData]"> mais ça pourrait tout aussi bien être <xsl:template match="*[tacticalData]"> je ne connais pas assez bien tes données pour trancher.

Un exemple de la manière dont j'aurais pu écrire ça en 3.0

Code :

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:nc1opordain="urn:fra:nc1:message:opordain"
xmlns:nc1messagelibre="urn:fra:nc1:message:messagelibre"
exclude-result-prefixes="xs nc1opordain"
version="3.0">
<xsl:mode name="#default" on-no-match="shallow-skip"/>
<xsl:strip-space elements="*"/>
<xsl:output indent="true"/>
<xsl:template match="/nc1opordain:*">
<xsl:element name="nc1messagelibre:NC1_MessageLibre">
<xsl:namespace name="xsi" select="'http://www.w3.org/2001/XMLSchema-instance'"/>
<subject><xsl:value-of select="substring-after(local-name(), 'NC1_')"/></subject>
<mixedText/>
<body>
<objects>
<xsl:apply-templates select="descendant::*[not(empty(@xsi:type))][tacticalData]" mode="tactical"/>
</objects>
</body>
</xsl:element>
</xsl:template>
<xsl:template match="*" mode="tactical">
<object>
<xsl:variable name="xsi-type-value-prefix" select="substring-before(@xsi:type, ':')" as="xs:string"/>
<xsl:namespace name="{$xsi-type-value-prefix}" select="namespace-uri-for-prefix($xsi-type-value-prefix, .)"/>
<xsl:copy-of select="@xsi:type"/>
<xsl:copy-of select="tacticalData" copy-namespaces="no"/>
</object>
</xsl:template>
</xsl:stylesheet>

tahrky a écrit :

Merci pour ton aide, certaines choses sont un peu plus clair dans mon esprit, cependant, je me retrouve avec ça en sortie, ce qui ne fonctionne pas.

Code :

<object xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xsi:type="nc1reinforcement:ReinforcementType">
<tacticalData xmlns:nc1reinforcement="urn:fra:nc1:objet:reinforcement"
xmlns:nc1opordain="urn:fra:nc1:message:opordain">
<name>Nom-D1239</name>
</tacticalData>
</object>

Pour xmlns:nc1opordain, c'est parce que tu crée object (et toute sa hiérarchie au dessus) comme un nouvel élément, et de ce fait, il n'est pas lié aux namespaces de l'arbre de départ, qu'il ne connait pas. Mais la transformation, elle, elle sait que le namespace nc1opordain a été déclaré dans le contexte de tacticalData (qui lui figurait dans l'arbre de départ) et qu'il ne figure pas dans le contexte des ancêtres de tacticalData en sortie, donc elle fait alors la déclaration, car c'est la première opportunité qu'elle a de le faire. Pour éviter la déclaration du namespace en sortie, il faut faire un copy-namespaces a no, ce qui évitera d'avoir les déclarations de namespaces déclarés dans le contexte d'entrée et pas utilisés dans celui de sortie.
C'est aussi ce qui s'applique pour xmlns:nc1reinforcement et xmlns:nc1unit qui au traitement de tacticalData ont été déclarés dans le contexte d'entrée, mais pas encore dans celui de sortie.
Sur un nouvel élément tel que object ici, il faut directement faire la déclaration du namespace avec xsl:namespace. Et alors le namespace sera déclaré dans le contexte de sortie "au bon moment".

A+,

Message cité 1 fois
Message édité par gilou le 19-09-2020 à 19:12:52

---------------
There's more than what can be linked! -- Le capitaine qui ne veut pas obéir à la carte finira par obéir aux récifs. -- No jab ? No job ! -- (╯°□°)╯︵ ┻━┻

tahrky

gilou a écrit :

Code :

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:fn="http://www.w3.org/2005/xpath-functions"
xmlns:nc1messagelibre="urn:fra:nc1:message:messagelibre"
xmlns:nc1opordain="urn:fra:nc1:message:opordain"
xmlns:nc1reinforcement="urn:fra:nc1:objet:reinforcement"
xmlns:nc1unit="urn:fra:nc1:objet:unit"
exclude-result-prefixes="xs fn nc1reinforcement nc1unit nc1opordain"
version="2.0">
<xsl:template match="/|@*|*" priority="-1">
<xsl:apply-templates select="@*|*"/>
</xsl:template>
<xsl:template match="nc1opordain:NC1_OPORD-AIN">
<nc1messagelibre:NC1_MessageLibre>
<subject>OPORD-AIN</subject>
<mixedText/>
<body>
<objects>
<xsl:apply-templates select="*"/>
</objects>
</body>
</nc1messagelibre:NC1_MessageLibre>
</xsl:template>
<xsl:template match="(reinforcement|unit)[tacticalData]">
<xsl:if test="@xsi:type">
<object>
<xsl:namespace name="{substring-before(@xsi:type, ':')}" select="concat('urn:fra:nc1:objet:', local-name())"/>
<xsl:copy-of select="@xsi:type"/>
<xsl:copy-of select="tacticalData" copy-namespaces="no"/>
</object>
</xsl:if>
</xsl:template>
</xsl:stylesheet>

Code :

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:nc1opordain="urn:fra:nc1:message:opordain"
xmlns:nc1messagelibre="urn:fra:nc1:message:messagelibre"
exclude-result-prefixes="xs nc1opordain"
version="3.0">
<xsl:mode name="#default" on-no-match="shallow-skip"/>
<xsl:strip-space elements="*"/>
<xsl:output indent="true"/>
<xsl:template match="/nc1opordain:*">
<xsl:element name="nc1messagelibre:NC1_MessageLibre">
<xsl:namespace name="xsi" select="'http://www.w3.org/2001/XMLSchema-instance'"/>
<subject><xsl:value-of select="substring-after(local-name(), 'NC1_')"/></subject>
<mixedText/>
<body>
<objects>
<xsl:apply-templates select="descendant::*[not(empty(@xsi:type))][tacticalData]" mode="tactical"/>
</objects>
</body>
</xsl:element>
</xsl:template>
<xsl:template match="*" mode="tactical">
<object>
<xsl:variable name="xsi-type-value-prefix" select="substring-before(@xsi:type, ':')" as="xs:string"/>
<xsl:namespace name="{$xsi-type-value-prefix}" select="namespace-uri-for-prefix($xsi-type-value-prefix, .)"/>
<xsl:copy-of select="@xsi:type"/>
<xsl:copy-of select="tacticalData" copy-namespaces="no"/>
</object>
</xsl:template>
</xsl:stylesheet>

gilou a écrit :

Merci beaucoup, c'est plus clair dans ma tête, et j'ai un code qui fonctionne comme je cherchais à le faire ! .
Oui, j'utilise Oxygen, mais en version 16, qui ne permet de faire fonctionner que XSLT2. De toute façon, l'environnement de travail ne supporte pas XSLT3 actuellement, ce qui me restreint beaucoup.

Merci Xavier_OM et Gilou pour votre aide précieuse ! :jap:

Xavier_OM

Monarchiste régicide (fr quoi)

Gilou c'est l'meilleur de toute façon :jap:

---------------
Il y a autant d'atomes d'oxygène dans une molécule d'eau que d'étoiles dans le système solaire.

gilou

Modérateur
Modosaurus Rex

C'est ce qui me fait bouffer, le xsl.
En me relisant, je vois que je peux écrire cela en 2.0 et un chouia plus fonctionnel :

Code :

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xmlns:nc1opordain="urn:fra:nc1:message:opordain"
xmlns:nc1messagelibre="urn:fra:nc1:message:messagelibre"
exclude-result-prefixes="xs nc1opordain"
version="2.0">
<xsl:strip-space elements="*"/>
<xsl:output indent="true"/>
<xsl:template match="/|@*|*">
<xsl:apply-templates select="@*|*"/>
</xsl:template>
<xsl:template match="/nc1opordain:*">
<xsl:element name="nc1messagelibre:NC1_MessageLibre">
<xsl:namespace name="xsi" select="'http://www.w3.org/2001/XMLSchema-instance'"/>
<subject><xsl:value-of select="substring-after(local-name(), 'NC1_')"/></subject>
<mixedText/>
<body>
<objects>
<xsl:apply-templates/>
</objects>
</body>
</xsl:element>
</xsl:template>
<xsl:template match="*[not(empty(@xsi:type))][tacticalData]">
<object>
<xsl:variable name="xsi-type-value-prefix" select="substring-before(@xsi:type, ':')" as="xs:string"/>
<xsl:namespace name="{$xsi-type-value-prefix}" select="namespace-uri-for-prefix($xsi-type-value-prefix, .)"/>
<xsl:copy-of select="@xsi:type, tacticalData" copy-namespaces="no"/>
</object>
</xsl:template>
</xsl:stylesheet>

A+,

Message édité par gilou le 21-09-2020 à 22:19:09

---------------
There's more than what can be linked! -- Le capitaine qui ne veut pas obéir à la carte finira par obéir aux récifs. -- No jab ? No job ! -- (╯°□°)╯︵ ┻━┻

Xavier_OM

Monarchiste régicide (fr quoi)

J'en ai fait durant 8-12 mois ya 12 ans donc j'avoue c'est pas aussi fluide pour moi

---------------
Il y a autant d'atomes d'oxygène dans une molécule d'eau que d'étoiles dans le système solaire.

FORUM HardWare.fr

Programmation

XML/XSL

Changer nom element et garder les namespaces

Sujets relatifs
[Javascript] - Supprimer un élément ajouté dynamiquement	Changer de Imacros
Récupérer 2 élément à part dans des variable à partir d'un liste.	[FullCalendar] - Récupérer l'attribut className d'un élément mis en bg
[PHP] Garder uniquement les enregistrements présents dans un tableau	[ORACLE] Changer la table dont un trigger fait partie
[Résolu]Comment changer automatiquement/manuellement de feuille	Changer de MCU et importation des librairies / composants
Remerciement	Changer l'icone d'un répertoire
Plus de sujets relatifs à : Changer nom element et garder les namespaces

Page générée en 0.163 secondes