Bonjour,  
j'arrive à recuperer la date de la facon suivante sous Windows XP:
 
On Error Resume Next
 
strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2" )
 
Set colItems = objWMIService.ExecQuery("Select * from Win32_LocalTime" )
 
For Each objItem in colItems
    Wscript.Echo "Day: " & objItem.Day
    Wscript.Echo "Day of Week: " & objItem.DayOfWeek
    Wscript.Echo "Hour: " & objItem.Hour
    Wscript.Echo "Minute: " & objItem.Minute
    Wscript.Echo "Month: " & objItem.Month
    Wscript.Echo "Quarter: " & objItem.Quarter
    Wscript.Echo "Second: " & objItem.Second
    Wscript.Echo "Week in Month: " & objItem.WeekInMonth
    Wscript.Echo "Year: " & objItem.Year
    Wscript.Echo
Next
 
Mais le probleme c'est que cela ne fonctionne pas avec Windows 2000....  
Où est le problème je ne comprends pas trop...  
Merci d'avance  

Win32_LocalTime n'est pas reconnue sous 2k.  
Utilise la classe Win32_OperatingSystem avec une mise en forme de sa propriété LocalDateTime; à moins que le format UTC te convienne mieux .
...
strComputer = "."  
Set objWMIService = GetObject("winmgmts:" _  
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2" )  
Set colItems = objWMIService.ExecQuery("Select * from Win32_OperatingSystem" )
For Each objItem in colItems
    TempsLocal = objItem.LocalDateTime
    An = Left(TempsLocal, 4)
    Mois = Mid(TempsLocal, 5, 2)
    Jour = Mid(TempsLocal, 7, 2)
    Heures = Mid(TempsLocal, 9, 2)
    Minutes = Mid(TempsLocal, 11, 2)
    Secondes = Mid(TempsLocal, 13, 2)
Next
 
La_Date = Jour & "/" & Mois & "/" & An
Le_Temps =  Heures & ":" & Minutes & ":" & Secondes
 
Wscript.Echo La_Date & " " & Le_Temps

MERCI beaucoup!!
je sais pas comment j'aurais pu trouver sans toi!!
As tu un bon site concernant le VBS où toutes les variables Windows etc... sont repertoriés?
 
Merci encore

Tu as notamment ici... sinon: ce ne sont pas les liens qui manquent ...