[VBS][RESOLU][SCRIPT]Script de suppression de fichiers temporaires

Recherche :

Sujet(s) à lire :
- Récuperer une ligne d'un fichier texte dans une variable

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : [VBS][RESOLU][SCRIPT]Script de suppression de fichiers temporaires

nixnbk

Strip the flesh salt the wound

Bonjour,

J'ai créé un script pour dégager des fichiers temporaires du disque c:\ et ainsi gagner de la place de manière automatique.

MERCI à : magicbuzz

Le code fonctionne de la manière suivante :

Création d'un cmdline.bat à la racine de c:\
Si c:\temp existe, alors on rajoute au .bat une ligne de suppression pour le contenu du répertoire
si c:\tmp existe, alors on rajoute au .bat une ligne de suppression pour le contenu du répertoire
si c:\%windir%\temp existe, alors on rajoute au .bat une ligne de suppression pour le contenu du répertoire
Pour chaque répertoire de KBwindows ($xxxx$) contenu dans %windir%, si son ancienneté est de plus de 2 mois, alors on rajoute au .bat une ligne de suppression pour le répertoire et son contenu
Pour chaque repertoire de c:\documents and settings\, si le répertoire "c:\documents and settings\repertoire\local settings\temp" existe, alors on rajoute au .bat une ligne de suppression pour le contenu du répertoire
on ferme le cmdline.bat
on quitte le script en exécutant cmdline.bat

Voici le code :

Code :

'-------------------------------------------------------------------------
' SCRIPT DE SUPPRESSION DE FICHIERS TEMPORAIRES
' AUTEUR : nixnbk
'-------------------------------------------------------------------------
 
'-------------------------------------------------------------------------
' DECLARATION DES VARIABLES
'-------------------------------------------------------------------------
dim CmdLine, folder,fdocuments
dim WINDIR
 
Set WshShell = WScript.CreateObject("WScript.Shell" )
WINDIR = WshShell.ExpandEnvironmentStrings("%WinDir%" )
 
Set fso = CreateObject("Scripting.FileSystemObject" )
Set MyFile = fso.CreateTextFile("c:\CmdLine.bat" , True)
 
 
'-------------------------------------------------------------------------
' SUPPRESSION pour C:\TEMP
'-------------------------------------------------------------------------
folder = "c:\temp"
if fso.FolderExists(folder) then
    CmdLine = "del " & folder & "\*.* /Q /F /S"
    MyFile.WriteLine(CmdLine)
end if
 
'-------------------------------------------------------------------------
' SUPPRESSION pour C:\TMP
'-------------------------------------------------------------------------
folder = "c:\tmp"
 
if fso.FolderExists(folder) then
    CmdLine = "del " & folder & "\*.* /Q /F /S"
    MyFile.WriteLine(CmdLine)
end if
 
'-------------------------------------------------------------------------
' SUPPRESSION pour %WINDIR%\TEMP
'-------------------------------------------------------------------------
folder = WINDIR & "\temp"
 
if fso.FolderExists(folder) then
    CmdLine = "del " & folder & "\*.* /Q /F /S"
    MyFile.WriteLine(CmdLine)
end if
 
'----------------------------------------------------------------------------------
' SUPPRESSION pour %WINDIR%\$xxx$ (KB WINDOWS) si plus vieux que 2 mois (60 jours)
'----------------------------------------------------------------------------------
if fso.FolderExists(WINDIR) then
    For Each folder in fso.GetFolder(WINDIR).SubFolders
        If Len(folder.Name) > 2 and Right(folder.Name, 1) = "$" and Left(folder.Name, 1) = "$" and folder.DateLastModified < DateAdd("d", -60, Now()) Then
            CmdLine = "rmdir " & folder & " /S /Q"
            MyFile.WriteLine(CmdLine)
        End If
   Next
End if
 
'-------------------------------------------------------------------------
' SUPPRESSION pour C:\DOCUMENTS AND SETTINGS\%USER%\LOCAL SETTINGS\TEMP
'-------------------------------------------------------------------------
fdocuments = "c:\documents and settings\"
if fso.FolderExists(fdocuments) then
    For Each folder in fso.GetFolder(fdocuments).SubFolders
        folder = folder & "\Local Settings\temp"
        if fso.FolderExists(folder) then
            CmdLine = "del """ & folder & "\*.*"" /Q /F /S"
            MyFile.WriteLine(CmdLine)
        end if
    next
end if
 
 
'-------------------------------------------------------------------------
' FIN SCRIPT ET EXECUTION DU FICHIER BAT
'-------------------------------------------------------------------------
MyFile.Close
Set MyFile = Nothing
Set fso = Nothing
Return = WshShell.Run ("c:\CmdLine.bat",10,TRUE)

Je mets ici le message original :
-----------------------------------------------------------------------------------------------------------
-----------------------------------------------------------------------------------------------------------
Bonjour,

Je suis en train de tenter de réaliser un script VBS pour supprimer des répertoires selon une date d'ancienneté.

Globalement le script est OK, sauf qu'on ma demandé de supprimer des répertoires présents dans %windir% et donc ça devient vachement sensible.

En gros je voudrais tester et supprimer tous les répertoires %windir%\$*$
(exemple : $hfmig$ $ntuninstallKB123456$ etc.)
Je peux pas nommer les KB à la main, parce que y'en a trop et que c'est trop long.
Et apparemment le répertoire %windir%\$*$ ça fonctionne pas.
(je stocke dans un array le string : %windir%\$*$)

J'ai fait des tests sous le cmd, ça fonctionne avec la commande dir (dir %windir%\$*$)

Ma question est donc : comment je peux stocker dans un array chaque ligne de résultat de mon dir ?

Une idée ?

Je fais également mes recherches de mon coté.
Quand j'aurai résolu mon problème je ferai un tuto en premier post.

Bonne journée,

Nix.

Message édité par nixnbk le 18-06-2009 à 10:53:07

---------------
I'll feed your skin snacks to my cockatiel!

Publicité

nixnbk

Strip the flesh salt the wound

Bon comme j'arrive pas à récupérer directement depuis le shell, je me suis orienté sur quelque chose de plus simple :

en gros depuis mon vbs, j'éxécute la commande dir et la stocke dans un fichier de résultats :
dir %windir%\$*$ /A:h /B > d:\scripts\recupdir.txt

l'argument /A:h affiche les éléments cachés, et /B donne des résultats abrégés.

J'ai donc un fichier avec dedans ceci :

$hf_mig$
$NtServicePackUninstall$
$NtUninstallKB915800-v4$
$NtUninstallKB923561$
$NtUninstallKB940157$
$NtUninstallKB952004$
$NtUninstallKB963093$
$NtUninstallKB967715$
$NtUninstallKB968537$
$NtUninstallKB970238$

Comment je peux récupérer le fichier ligne par ligne dans mon array en vbs ?

---------------
I'll feed your skin snacks to my cockatiel!

MagicBuzz

Pourquoi tu utilises pas l'objet de FileSystemObject ?

nixnbk

Strip the flesh salt the wound

J'ai oublié de préciser que je suis une bille en vbs, et que jusqu'ici je ne fais qu'adapter des scripts déja existant en modifiant quelques fonctions par ci par la.

Comment ça fonctionne l'objet fileSystemObject ?

EDIT : Je vient de trouver ce que c'est que le fso... et j'ai vu un opentextfile dedans.

Message édité par nixnbk le 17-06-2009 à 12:00:51

---------------
I'll feed your skin snacks to my cockatiel!

nixnbk

Strip the flesh salt the wound

Par contre je vois pas comment après avoir ouvert mon fichier texte je peux récupérer chaque ligne.

Je vois bien une boucle basée sur un retour du nombre de ligne dans laquelle je rentre dans l'array chaque ligne....
Mais je vois pas quelle commande utiliser pour retourner le nombre de lignes dans le fichier ou récupérer la ligne 1,2,3 etc.

---------------
I'll feed your skin snacks to my cockatiel!

MagicBuzz

http://devguru.com/technologies/vbscript/14048.asp
http://devguru.com/technologies/vbscript/13990.asp
etc.

en jouant avec Folders, tu pourras sans problème parcourir la liste des $KBxxxxx$ de ton répertoire, et en faire ce que tu veux

nixnbk

Strip the flesh salt the wound

En fait j'ai trouvé le moyen de récupérer les ligne d'un fichier texte sur le sujet suivant :
http://forum.hardware.fr/hfr/Progr [...] m#t1360217

Le problème c'est de boucler les lignes.

En gros l'algo que je veux appliquer :

chemin = c:\monfichier.txt
fichier = opentextfile(chemin,1)
pour chaque ligne de fichier.txt non vide
ligne= fichier.readline
Si %windir%\ligne.datelastmodified plus vieux que 2 mois Alors
actions à réaliser
endif
fin boucle

Une idée pour le bouclage ?

Message édité par nixnbk le 17-06-2009 à 15:23:45

---------------
I'll feed your skin snacks to my cockatiel!

MagicBuzz

Franchement, tu ferais une boucle sur les items de Folders, ça serait quand même plus propre...

Message cité 1 fois

nixnbk

Strip the flesh salt the wound

MagicBuzz a écrit :

Franchement, tu ferais une boucle sur les items de Folders, ça serait quand même plus propre...

J'vois pas trop comment faire...

voici ou j'en suis dans mon script pour l'instant :

Code :

dim CmdLine,CmdDir
dim ligne
dim chemintxt = "c:\recupdir.txt"
Set WshShell = WScript.CreateObject("WScript.Shell" )
Set fso = CreateObject("Scripting.FileSystemObject" )
Set MyFile = fso.CreateTextFile("c:\CmdLine.bat" , True)
set folderpath = "c:\temp"
if fso.FolderExists(folderpath)
CmdLine = "del " & folderpath & "\*.* /Q /F /S"
MyFile.WriteLine(CmdLine)
end if
folderpath = "c:\tmp"
if fso.FolderExists(folderpath)
CmdLine = "del " & folderpath & "\*.* /Q /F /S"
MyFile.WriteLine(CmdLine)
end if
folderpath = "%windir%\tmp"
if fso.FolderExists(folderpath)
CmdLine = "del " & folderpath & "\*.* /Q /F /S"
MyFile.WriteLine(CmdLine)
end if
set DirFile = fso.createTextFile("c:\dirline.bat", True)
CmdDir = "dir %windir%\$*$ /A:h /B >" & chemintxt
DirFile.WriteLine(CmdDir)
DirFile.Close
set DirFile = CreateObject("WScript.Shell" )
DirFile.run("c:\dirline.bat",TRUE)
if fso.FileExists(chemintxt) then
set ouvrir=fso.opentextfile(chemintxt,1)
'boucle de 1 a nombre de lignes' dans recupdir.txt
ligne = ouvrir.readline
folderpath = "%windir%\" & ligne
if DateDiff("d",fso.GetFolder(folderpath).DateLastModified,date() ) > JOUR then
CmdLine = "rmdir " & folderpath & " /S /Q"
MyFile.WriteLine(CmdLine)
end if
'fin boucle
end if
MyFile.Close
Set MyFile = Nothing
Set fso = Nothing
Return = WshShell.Run (sourcepath & "\CmdLine.bat",10,TRUE)

Pour la boucle je cherche mais j'trouve toujours pas

---------------
I'll feed your skin snacks to my cockatiel!

MagicBuzz

Un truc du genre :

Code :

Option Explicit
 
Const WINDIR = "c:\windows"
Dim fso
Dim wsh
 
Dim fol
 
Set fso = CreateObject("Scripting.FileSystemObject" )
Set wsh = WScript.CreateObject("WScript.Shell" )
 
If fso.FolderExists(WINDIR) Then
    For Each fol in fso.GetFolder(WINDIR).SubFolders
        If Len(fol.Name) > 2 and Right(fol.Name, 1) = "$" and Left(fol.Name, 1) = "$" and fol.DateLastModified < DateAdd("d", -60, Now()) Then
            fso.DeleteFolder(fol)
        End If
    Next
    MsgBox("OK" )
Else
    MsgBox("On a un problème là..." )
End if

Publicité

nixnbk

Strip the flesh salt the wound

En gros ton script teste pour chaque sous répertoire du windir si il contient + que 2 caractères, si son premier et dernier caractère est "$" ...
C'est bien ça ?

vais tenter d'adapter ça...

Par contre il y a un problème avec ta variable windir : si on est sous 2000 alors le windir = c:\winnt.
Résultat on se prend le msgbox : "on a un problème la..."
Ya pas moyen de travailler avec %windir% plutôt que de la définir en dur ?

Merci en tout cas pour le temps passé.

Message édité par nixnbk le 17-06-2009 à 16:55:49

---------------
I'll feed your skin snacks to my cockatiel!

MagicBuzz

ben j'ai essayé, mais pas trouvé pour récupérer %windir%

cependant, fso a un GetSpecialFolder().
j'imagine qu'un truc genre fso.GetSpecialFolder("windir" ) devrait bien aider

nixnbk

Strip the flesh salt the wound

trouvé pour le windir :
dim WINDIR
Set WshShell = WScript.CreateObject("WScript.Shell" )
WINDIR = WshShell.ExpandEnvironmentStrings("%WinDir%" )

---------------
I'll feed your skin snacks to my cockatiel!

nixnbk

Strip the flesh salt the wound

bon grâce à ton bout de code j'ai pu finir mon script. Le voici :

Code :

dim CmdLine, folder
dim WINDIR
 
Set WshShell = WScript.CreateObject("WScript.Shell" )
WINDIR = WshShell.ExpandEnvironmentStrings("%WinDir%" )
 
Set fso = CreateObject("Scripting.FileSystemObject" )
Set MyFile = fso.CreateTextFile("c:\CmdLine.bat" , True)
folder = "c:\temp"
set DirFile = fso.createTextFile("c:\dirline.bat", True)
 
 
if fso.FolderExists(folder) then
    CmdLine = "REM del " & folder & "\*.* /Q /F /S"
    MyFile.WriteLine(CmdLine)
end if
 
folder = "c:\tmp"
 
if fso.FolderExists(folder) then
    CmdLine = "REM del " & folder & "\*.* /Q /F /S"
    MyFile.WriteLine(CmdLine)
end if
 
folder = WINDIR & "\temp"
 
if fso.FolderExists(folder) then
    CmdLine = "REM del " & folder & "\*.* /Q /F /S"
    MyFile.WriteLine(CmdLine)
end if
 
if fso.FolderExists(WINDIR) then
    For Each folder in fso.GetFolder(WINDIR).SubFolders
        If Len(folder.Name) > 2 and Right(folder.Name, 1) = "$" and Left(folder.Name, 1) = "$" and folder.DateLastModified < DateAdd("d", -60, Now()) Then
            CmdLine = "REM rmdir " & folder & " /S /Q"
            MyFile.WriteLine(CmdLine)
       End If
   Next
End if
CmdLine = "pause"
MyFile.WriteLine(CmdLine)
MyFile.Close
Set MyFile = Nothing
Set fso = Nothing
Return = WshShell.Run ("c:\CmdLine.bat",10,TRUE)

Et le .bat de résultat :

REM del c:\tmp\*.* /Q /F /S
REM del C:\WINDOWS\temp\*.* /Q /F /S
REM rmdir C:\WINDOWS\$NtServicePackUninstall$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB952069_WM9$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB954459$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB954600$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB955069$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB955839$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB956802$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB957097$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB958215$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB958687$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB958690$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB959772_WM11$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB960225$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB960714$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB960715$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB961118$ /S /Q
REM rmdir C:\WINDOWS\$NtUninstallKB967715$ /S /Q
pause

J'ai vérifié tout fonctionne. J'enlève les REM et je met le sujet en résolu.

Merci magicbuzz.

---------------
I'll feed your skin snacks to my cockatiel!

nixnbk

Strip the flesh salt the wound

J'viens de me rendre compte qu'il manque encore toute une partie à mon script :
Faudrait aussi que je vide les repertoire temp de chaque user.
donc en gros : récupérer pour chaque sous répertoire de c:\documents and settings\ (variable windows ???) le répertoire \local settings\temp et le vider.

Je commence à chercher. Globalement niveau Algo ça devrait pas changer des masses de celui des Kb windows.

---------------
I'll feed your skin snacks to my cockatiel!

nixnbk

Strip the flesh salt the wound

Problème résolu, modification du premier post et publication du code.

n'hésitez pas à me faire un retour si on peut améliorer le code.

Bonne journée,

nix.

---------------
I'll feed your skin snacks to my cockatiel!

FORUM HardWare.fr

Programmation

VB/VBA/VBS

[VBS][RESOLU][SCRIPT]Script de suppression de fichiers temporaires

Sujets relatifs
[RESOLU]JTable : colorier ligne ou cellule selon critère de provenance	probleme pour parser des dates [résolu]
[Résolu] MySQL : LEFT JOIN et GROUP BY - récupérer la dernière valeur	Macro : Chercher les bons fichiers de liaisons.
[VBS] Récuperer contenu fichier texte dans une variable:	[Résolu] Comment bien structurer mes classes ?
[Resolu]Problème de compilation API MYSQL	C# et langages de script
[RESOLU] - [JTree] Ne pas afficher tous les noeuds
Plus de sujets relatifs à : [VBS][RESOLU][SCRIPT]Script de suppression de fichiers temporaires

Page générée en 0.115 secondes