Forum |  HardWare.fr | News | Articles | PC | S'identifier | S'inscrire | Shop Recherche
3513 connectés 

  FORUM HardWare.fr
  Windows & Software
  Logiciels

  Cherche outil freeware de tri/recherche de fichiers sur un serveur

 
 


 Mot :   Pseudo :  
 
Bas de page
Auteur Sujet :

Cherche outil freeware de tri/recherche de fichiers sur un serveur

n°2441264
flashy_fib​er
Posté le 19-06-2006 à 16:40:22  profilanswer
 

J'ai l'intention de faire du tri sur un serveurs de fichiers afin d'optimiser l'espace disque et je recherche un freeware permettant de faire des recherches de fichiers selon criteres (Taille en Mo, Date d'ancienneté, Modification, Derniers accès...etc...).  
Voilà si vous avez des outils en freeware à conseiller, merci d'avance

Message cité 1 fois
mood
Publicité
Posté le 19-06-2006 à 16:40:22  profilanswer
 

n°2441287
Tihz
Posté le 19-06-2006 à 17:08:22  profilanswer
 

Salut,
 
La recherche integré a Windows fait tout ça ! ;)


---------------
Tihz
n°2441288
Wolfman
Modérateur
Lobo'tomizado
Posté le 19-06-2006 à 17:09:07  profilanswer
 

Très bon : Treesize Professional

Message cité 1 fois
Message édité par Wolfman le 19-06-2006 à 17:24:19
n°2441289
lebig
Posté le 19-06-2006 à 17:10:02  profilanswer
 

cela dépend du résultat que tu souhaites
 
sinon il y a l'utilitaire robocopy de Microsoft http://www.microsoft.com/downloads [...] laylang=en

n°2442033
flashy_fib​er
Posté le 20-06-2006 à 14:26:26  profilanswer
 

Wolfman a écrit :

Très bon : Treesize Professional


 
D'acc il a vraiment plein d'options de recherche intéressantes mais que dans la version shareware, dommage.....Et j'en cherche qui aurait comme options "derniere modification", "dernier accès" si possible (comme le fait Treesize Pro mais en freeware :)

n°2442038
Wolfman
Modérateur
Lobo'tomizado
Posté le 20-06-2006 à 14:31:15  profilanswer
 

Si tu as besoin du soft pour une durée limitée, la version shareware te suffira.

n°2442183
Dji-Pih
Posté le 20-06-2006 à 16:28:04  profilanswer
 

flashy_fiber a écrit :

J'ai l'intention de faire du tri sur un serveurs de fichiers afin d'optimiser l'espace disque et je recherche un freeware permettant de faire des recherches de fichiers selon criteres (Taille en Mo, Date d'ancienneté, Modification, Derniers accès...etc...).
Voilà si vous avez des outils en freeware à conseiller, merci d'avance


Voici le VBScript que j'utilise (donc testé...) avec ROBOCOPY Version XP010 pour lister, copier, déplacer et synchroniser des fichiers sur mon serveur :

 
Code :
  1. '-------------------------------------------------------------
  2. ' Utilitaire :        ROBOCOPY22.vbs (version 2.2)
  3. ' But Ial:        Faciliter et automatiser l'utilisation de la commande DOS robocopy.exe.
  4. '            Cet utilitaire sera utilisé essentiellement pour analyser et purger les fichiers
  5. '            utilisateurs sur le serveur de fichiers.
  6. ' But IIaire :    approfondir le langage de script VBS
  7. ' Installation :    1/ Ce script sur le bureau du serveur de fichier
  8. '            2/ robocopy.exe XP010 (Ressource Kit XP) dans le répertoire %windir%
  9. ' Auteur :        J.Philippe SOSSON
  10. ' Versions    1.0    Menu + options de base : copier, déplacer, lister, synchroniser,
  11. '            critères selon la taille des fichiers, date de modification
  12. '        2.0    * Optimisation du code : Fonctions, procédures, tableaux et constantes
  13. '            * Ajout du critère selon la date d'accès
  14. '            * Correction de la fonction Mirroir : /MIR ne fonctionne pas avec l'option /XX
  15. '        2.1    * Ajout de l'option R) pour répéter la dernière commande
  16. '            * Modification de la sortie de l'utilitaire
  17. '        2.2    * Ajout de la gestion des messages en sortie de robocopy
  18. '            * Ajout d'un filtre sur les fichiers
  19. '-------------------------------------------------------------
  21. '------ Déclaration des variables et des constantes
  22. Option Explicit '------ Forcer la déclaration des variables
  24. Dim wsh, fso, FichierJournal
  25. Const C_Lecture = 1, C_Ecriture = 2
  26. Const C_FichierJournal = "c:\robocopy.txt"
  28. Dim CmdeRobocopy
  29. Dim ChoixMenu
  30. Dim SaisieDossier, SaisieFichier, SaisieDate, SaisieTaille, Validation
  32. Dim T_SelectionDossier(1)
  33. Const C_DossierSource = 0, C_DossierDestination = 1
  35. Dim T_SelectionDate(1, 3)
  36. Const C_DateOption = 0, C_DateTexte = 1
  37. Const C_DateAccesAnterieure = 0, C_DateAccesPosterieure = 1, C_DateModificationAnterieure = 2, C_DateModificationPosterieure = 3
  39. Dim T_SelectionTaille(1, 1)
  40. Const C_TailleOption = 0, C_TailleTexte = 1
  41. Const C_TailleMin = 0, C_TailleMax = 1
  43. Dim  CodeRetour, Bit, T_MessageRetour(5)
  45. '------ Déclaration des fonctions et procédures
  46. Function SelectionDossier(TypeDossier)
  47.     Do
  48.         SaisieDossier = InputBox("Dossier" & T_SelectionDossier(TypeDossier), "ROBOCOPY" )
  49.     Loop Until fso.FolderExists(SaisieDossier)
  50.     SelectionDossier = " " & SaisieDossier
  51. End Function
  53. Function SelectionFichier()
  54.     SaisieFichier = InputBox("Tri sur les fichiers" & Chr(10) & "Caratères génériques acceptés, *.* par défaut", "ROBOCOPY" )
  55.     If Len(SaisieFichier) > 0 Then
  56.         SelectionFichier = " " & SaisieFichier
  57.     End If
  58. End Function
  60. Function ChoixDate()
  61.     '------ Filtre sur les dates d'accès OU les dates de modification
  62.     If MsgBox("Souhaitez-vous trier les fichiers sur les dates d'accès", vbYesNo + vbQuestion, "ROBOCOPY" ) = vbYes Then
  63.         ChoixDate = SelectionDate(C_DateAccesAnterieure)
  64.         ChoixDate = ChoixDate & SelectionDate(C_DateAccesPosterieure)
  65.     Else
  66.         If MsgBox("Souhaitez-vous trier les fichiers sur les dates de modification", vbYesNo + vbQuestion, "ROBOCOPY" ) = vbYes Then
  67.             ChoixDate = SelectionDate(C_DateModificationAnterieure)
  68.             ChoixDate = ChoixDate & SelectionDate(C_DateModificationPosterieure)
  69.         End If
  70.     End If
  71. End Function
  73. Function SelectionDate(TypeDate)
  74.     Do
  75.         Validation = 0
  76.         SaisieDate = InputBox("Fichiers dont la date" & T_SelectionDate(C_DateTexte, TypeDate) & Chr(10) _
  77.                     & "Bouton [Annuler] si aucune, sinon JJ/MM/AAAA", "ROBOCOPY" )
  78.         If Len(SaisieDate) = 0 Then
  79.             Validation = vbYes
  80.         Else
  81.             if Len(SaisieDate) = 10 Then
  82.                 If IsNumeric(Right(SaisieDate,4)) And IsNumeric(Mid(SaisieDate,4,2)) And IsNumeric(Left(SaisieDate,2)) Then
  83.                     Validation = MsgBox("Veuillez confirmer : fichiers dont la date" _
  84.                                     & T_SelectionDate(C_DateTexte, TypeDate) & " à " & SaisieDate, vbYesNo + vbExclamation, "ROBOCOPY" )
  85.                     If Validation = vbYes Then
  86.                         SaisieDate = Right(SaisieDate,4) & Mid(SaisieDate,4,2) & Left(SaisieDate,2)
  87.                         SelectionDate = T_SelectionDate(C_DateOption, TypeDate) & SaisieDate
  88.                     End If
  89.                 End If
  90.             End If
  91.         End If
  92.     Loop Until Validation = vbYes
  93. End Function
  95. Function ChoixTaille()
  96.     If MsgBox("Souhaitez-vous trier les fichiers sur la taille", vbYesNo + vbQuestion, "ROBOCOPY" ) = vbYes Then
  97.         ChoixTaille = SelectionTaille(C_TailleMin)
  98.         ChoixTaille = ChoixTaille & SelectionTaille(C_TailleMax)
  99.     End If
  100. End Function
  102. Function SelectionTaille(TypeTaille)
  103.     Do
  104.         Validation = 0
  105.         SaisieTaille = InputBox("Fichiers dont la taille est" & T_SelectionTaille(C_TailleTexte, TypeTaille) & Chr(10) _
  106.                             & "Bouton [Annuler] si aucune, sinon X (en Go)", "ROBOCOPY" )
  107.         If Len(SaisieTaille) = 0 Then
  108.             Validation = vbYes
  109.         Else
  110.             If IsNumeric(SaisieTaille) Then
  111.                 Validation = MsgBox("Veuillez confirmer : fichiers dont la taille est" _
  112.                                 & T_SelectionTaille(C_TailleTexte, TypeTaille) & " à " & SaisieTaille & " Go" _
  113.                                 , vbYesNo + vbExclamation, "ROBOCOPY" )
  114.                 If Validation = vbYes Then
  115.                     SelectionTaille = T_SelectionTaille(C_TailleOption, TypeTaille) & Cstr(Clng(SaisieTaille)*1024*1024)
  116.                 End If
  117.             End If
  118.         End If
  119.     Loop Until Validation = vbYes
  120. End Function
  122. Function Journal()
  123.     Journal = " /LOG:c:\robocopy.log /NDL" 'Fichier journal et contenu
  124.     If MsgBox("Souhaitez-vous un affichage de l'exécution de la commande dans la console windows" _
  125.                 , vbYesNo + vbQuestion, "ROBOCOPY" ) = vbYes Then
  126.         Journal = Journal & " /ETA /TEE"
  127.     End If
  128. End Function
  130. Sub ArchiveCommande(CmdeRobocopy, TypeAcces)
  131.     Set FichierJournal = fso.OpenTextFile(C_FichierJournal, TypeAcces, True)
  132.     If TypeAcces = C_Lecture Then
  133.         CmdeRobocopy = FichierJournal.ReadLine
  134.     Else
  135.         FichierJournal.WriteLine CmdeRobocopy
  136.     End If
  137.     FichierJournal.Close
  138. End Sub
  139.    
  140. Function MessageRetour(CodeRetour)
  141.     If CodeRetour = 0 Then
  142.         MessageRetour = T_MessageRetour(5)
  143.     Else
  144.         For Bit = 0 To 4
  145.             If (CodeRetour And (2^Bit)) = (2^Bit) Then
  146.                 MessageRetour = MessageRetour & T_MessageRetour(Bit)
  147.             End If
  148.         Next
  149.     End If
  150. End Function
  151.    
  152. Sub ExecuteCommande(CmdeRobocopy)
  153.     If MsgBox("Souhaitez-vous exécuter la commande suivante :" & Chr(10) _
  154.                 & CmdeRobocopy, vbYesNo + vbExclamation, "ROBOCOPY" ) = vbYes Then
  155.         CodeRetour = wsh.Run(CmdeRobocopy, 1, True) '------ Execution avec attente de la fin de la commande
  156.         MsgBox MessageRetour(CodeRetour), vbOKOnly, "ROBOCOPY"
  157.         wsh.Run("notepad.exe c:\robocopy.log" ) '------ Ouverture du fichier journal
  158.         ArchiveCommande CmdeRobocopy, C_Ecriture
  159.     End If
  160. End Sub
  162. '------ Initialisation des variables
  163. Set wsh = CreateObject("WScript.Shell" )
  164. Set fso = CreateObject("Scripting.FileSystemObject" )
  166. T_SelectionDossier(C_DossierSource) = " Source"
  167. T_SelectionDossier(C_DossierDestination) = " Destination"
  169. T_SelectionDate(C_DateOption, C_DateAccesAnterieure) = " /MINLAD:"
  170. T_SelectionDate(C_DateOption, C_DateAccesPosterieure) = " /MAXLAD:"
  171. T_SelectionDate(C_DateOption, C_DateModificationAnterieure) = " /MINAGE:"
  172. T_SelectionDate(C_DateOption, C_DateModificationPosterieure) = " /MAXAGE:"
  173. T_SelectionDate(C_DateTexte, C_DateAccesAnterieure) = " d'accès est antérieure"
  174. T_SelectionDate(C_DateTexte, C_DateAccesPosterieure) = " d'accès est postérieure"
  175. T_SelectionDate(C_DateTexte, C_DateModificationAnterieure) = " de modification est antérieure"
  176. T_SelectionDate(C_DateTexte, C_DateModificationPosterieure) = " de modification est postérieure"
  178. T_SelectionTaille(C_TailleOption, C_TailleMin) = " /MIN:"
  179. T_SelectionTaille(C_TailleOption, C_TailleMax) = " /MAX:"
  180. T_SelectionTaille(C_TailleTexte, C_TailleMin) = " supérieure"
  181. T_SelectionTaille(C_TailleTexte, C_TailleMax) = " inférieure"
  183. T_MessageRetour(0) = "Un ou plusieurs fichiers ont été copiés avec succès. "
  184. T_MessageRetour(1) = "Certains fichiers ou dossiers sont en EXTRA (Absent de la source, mais présent dans la destination). " & _
  185.             "Visualiser le fichier journal afin d'effectuer des opérations si nécessaire (sauf en cas de listage). "
  186. T_MessageRetour(2) = "Certains fichiers ou dossiers sont en dissonance. Visualiser le fichier journal afin d'effectuer des opérations si nécessaire. "
  187. T_MessageRetour(3) = "Certains fichiers ou dossiers n'ont pas pu être copiés (malgré le nombre et le délai des reprises spécifiés). "
  188. T_MessageRetour(4) = "Erreur sérieuse. Robocopy n'a copié aucun fichier. C'est une erreur d'utilisation de la commande " & _
  189.             "ou une erreur due aux privilèges d'accès insuffisants sur les dossiers sources ou destinations. "
  190. T_MessageRetour(5) = "Aucune erreur et aucune copie : les dossiers sources et destinations sont synchronisés. "
  192. '------ MAIN ------
  193. Do
  194.     CmdeRobocopy = "ROBOCOPY"
  195.     '------ CHOIX DE L'ACTION ------
  196.     ChoixMenu = UCase(InputBox("Votre choix :" & Chr(10) & Chr(10) _
  197.                 & "C) Copier des fichiers" & Chr(10) _
  198.                 & "D) Déplacer des fichiers" & Chr(10) _
  199.                 & "L) Lister des fichiers" & Chr(10) _
  200.                 & "M) Synchroniser des fichiers (Mirroir)" & Chr(10) _
  201.                 & "R) Répéter la dernière commande" & Chr(10) _
  202.                 & Chr(10) & "Bouton [Annuler] ou [Entrée] sans valeur pour Quitter" _
  203.                 ,"ROBOCOPY" ))
  205.     Select Case ChoixMenu
  206.         Case "C" '------ Copier des fichiers
  207.             CmdeRobocopy = CmdeRobocopy & SelectionDossier(C_DossierSource)
  208.             CmdeRobocopy = CmdeRobocopy & SelectionDossier(C_DossierDestination)
  209.             CmdeRobocopy = CmdeRobocopy & SelectionFichier()
  210.             CmdeRobocopy = CmdeRobocopy & ChoixDate()
  211.             CmdeRobocopy = CmdeRobocopy & ChoixTaille()
  212.             CmdeRobocopy = CmdeRobocopy & " /COPYALL /S /ZB" '------ Action a réaliser
  213.             CmdeRobocopy = CmdeRobocopy & " /R:3 /W:60" '------ Nombre et délai pour une reprise de l'action en cas d'échec
  214.             CmdeRobocopy = CmdeRobocopy & Journal()
  215.             ExecuteCommande CmdeRobocopy
  217.         Case "D" '------ Déplacer des fichiers
  218.             CmdeRobocopy = CmdeRobocopy & SelectionDossier(C_DossierSource)
  219.             CmdeRobocopy = CmdeRobocopy & SelectionDossier(C_DossierDestination)
  220.             CmdeRobocopy = CmdeRobocopy & SelectionFichier()
  221.             CmdeRobocopy = CmdeRobocopy & ChoixDate()
  222.             CmdeRobocopy = CmdeRobocopy & ChoixTaille()
  223.             CmdeRobocopy = CmdeRobocopy & " /COPYALL /S /ZB /MOVE" '------ Action a réaliser
  224.             CmdeRobocopy = CmdeRobocopy & " /R:3 /W:60" '------ Nombre et délai pour une reprise de l'action en cas d'échec
  225.             CmdeRobocopy = CmdeRobocopy & Journal()
  226.             ExecuteCommande CmdeRobocopy
  228.         Case "L" '------ Lister des fichiers
  229.             CmdeRobocopy = CmdeRobocopy & SelectionDossier(C_DossierSource)
  230.             CmdeRobocopy = CmdeRobocopy & " C:\" '------ Destination bidon car listage uniquement...
  231.             CmdeRobocopy = CmdeRobocopy & SelectionFichier()
  232.             CmdeRobocopy = CmdeRobocopy & ChoixDate()
  233.             CmdeRobocopy = CmdeRobocopy & ChoixTaille()
  234.             CmdeRobocopy = CmdeRobocopy & " /COPY:D /S /L /XX" '------ Action a réaliser
  235.             CmdeRobocopy = CmdeRobocopy & " /R:0 /W:0" '------ Nombre et délai pour une reprise de l'action en cas d'échec
  236.             CmdeRobocopy = CmdeRobocopy & Journal()
  237.             ExecuteCommande CmdeRobocopy
  239.         Case "M" '------ Synchroniser des fichiers (Mirroir)
  240.             CmdeRobocopy = CmdeRobocopy & SelectionDossier(C_DossierSource)
  241.             CmdeRobocopy = CmdeRobocopy & SelectionDossier(C_DossierDestination)
  242.             CmdeRobocopy = CmdeRobocopy & " /COPYALL /E /ZB /MIR" '------ Action a réaliser
  243.             CmdeRobocopy = CmdeRobocopy & " /R:3 /W:60" '------ Nombre et délai pour une reprise de l'action en cas d'échec
  244.             CmdeRobocopy = CmdeRobocopy & Journal()
  245.             ExecuteCommande CmdeRobocopy
  247.         Case "R" '------ Répéter la dernière commande
  248.             If fso.FileExists(C_FichierJournal) Then
  249.                 ArchiveCommande CmdeRobocopy, C_Lecture
  250.                 ExecuteCommande(CmdeRobocopy)
  251.             Else
  252.                 MsgBox "Commande Impossible : c:\robocopy.txt est introuvable...", vbOKOnly, "ROBOCOPY"
  253.             End If
  255.         Case "" '------ Quitter par le bouton [Annuler] ou [Entrée] sans valeur
  256.             If MsgBox("Confirmation de l'abandon de l'utilitaire", vbYesNo + vbQuestion, "ROBOCOPY" ) = vbNo Then
  257.                 ChoixMenu = "On ne quitte pas la procédure"
  258.             End If
  260.         Case Else
  261.             MsgBox "Choix de menu incorrect...", vbOKOnly, "ROBOCOPY"
  263.     End Select
  264. Loop Until Len(ChoixMenu) = 0
 


Aller à :
Ajouter une réponse
  FORUM HardWare.fr
  Windows & Software
  Logiciels

  Cherche outil freeware de tri/recherche de fichiers sur un serveur

 

Sujets relatifs
cherche logiciel pour scanner secteurs défectueuxRésolu - Récupération de fichiers
cherche infos sur WRE54G pour agrandir reseauRemplacement de DD système
Install d'XP : plantage sur écran à noir apres la copie des fichiersRecherche bon site traitant de la sécurité et des audits.
débloqué un Controle ActivX sur windows 2003 serveurcherche un vieux pc pour pour faire un serveur web
metre 2 serveur web sur la meme ip 
Plus de sujets relatifs à : Cherche outil freeware de tri/recherche de fichiers sur un serveur

Forum MesDiscussions.Net, Version 2010.2
(c) 2000-2011 Doctissimo
Page générée en 0.149 secondes

Copyright © 1997-2025 Groupe LDLC (Signaler un contenu illicite / Données personnelles)