Forum |  HardWare.fr | News | Articles | PC | S'identifier | S'inscrire | Shop Recherche
1702 connectés 

  FORUM HardWare.fr
  Programmation
  VB/VBA/VBS

  [VBA excel] incrémentation et impréssion automatique

 
 


 Mot :   Pseudo :  
 
Bas de page
Auteur Sujet :

[VBA excel] incrémentation et impréssion automatique

n°2100460
mc3donald
www.warrock-team.clanfree.net
Posté le 08-09-2011 à 21:04:49  profilanswer
 

Bonjour,
 
Voila je vous expose ma problématique :
 
Je travaille actuellement dans une boite de transport une partie de mon travaille quotidien est d'imprimer des "fiches palettes", le nombre d'impressions peuvent varier entre 50 et 200 par jours (1 fiche par clients).
 
Une fiche comporte 6 données différentes présentent dans un tableau excel qui mes transmis touts les jours la structure du tableau ne change jamais.
 
Ces données incrémentées automatiquement dans la "fiches palettes" grâce a des Recherchev, en remplissant une seule donnée.
 
Ma problématique a l'heure actuelle est que je voudrais que l'incrémentation et l'impression des fiches soit automatique grâce a des macros.
 
BDD :
http://imageshack.us/photo/my-images/687/bdde.png/
 
Fichier a incrémenter et imprimer en x exemplaire :
http://imageshack.us/photo/my-images/856/fichierpalette.png/
Cdlt.
 
Mc3donald.

Message cité 1 fois
mood
Publicité
Posté le 08-09-2011 à 21:04:49  profilanswer
 

n°2100728
otobox
Maison fondée en 2005
Posté le 10-09-2011 à 12:39:38  profilanswer
 

mc3donald a écrit :

Bonjour,
 
Voila je vous expose ma problématique :
 
Je travaille actuellement dans une boite de transport une partie de mon travaille quotidien est d'imprimer des "fiches palettes", le nombre d'impressions peuvent varier entre 50 et 200 par jours (1 fiche par clients).
 
Une fiche comporte 6 données différentes présentent dans un tableau excel qui mes transmis touts les jours la structure du tableau ne change jamais.
 
Ces données incrémentées automatiquement dans la "fiches palettes" grâce a des Recherchev, en remplissant une seule donnée.
 
Ma problématique a l'heure actuelle est que je voudrais que l'incrémentation et l'impression des fiches soit automatique grâce a des macros.
 
BDD :
http://imageshack.us/photo/my-images/687/bdde.png/
 
Fichier a incrémenter et imprimer en x exemplaire :
http://imageshack.us/photo/my-images/856/fichierpalette.png/
Cdlt.
 
Mc3donald.


Ça ne me semble pas trop difficile à faire, mais j'ai un peu du mal à comprendre le problème  

Citation :

Ces données incrémentées automatiquement dans la "fiches palettes" grâce a des Recherchev, en remplissant une seule donnée.


 [:mcwimpy_ban4]  
 
S'il s'agit de parcourir la liste BDD (je remet l'image en clair, tes liens sont pourris !)
http://img687.imageshack.us/img687/9125/bdde.png
et la mettre en forme chaque ligne pour l'imprimer tel que ceci :
http://img856.imageshack.us/img856/6189/fichierpalette.png
ça ne devrait pas poser de problème.
 
Tel que j'imagine ton problème, il faut avoir un fichier Excel, par exemple "Impression étiquette" où est déjà faite la mise en forme l'étiquette et qui contient la macro vba. Grâce à un bouton dans ce fichier, on sélectionne le fichier BDD à traiter et ensuite, ligne par ligne, la macro importe les données au bon endroit de l'étiquette et lance l'impression.
 
Est-ce cela que tu veux faire ?


---------------
OtObOxBlOg - - - Etre seul à avoir tort  c'est plus difficile, mais c'est bien plus beau que d'avoir raison avec une bande de cons
n°2100751
otobox
Maison fondée en 2005
Posté le 10-09-2011 à 15:29:29  profilanswer
 

Voilà un exemple qui correspond à ce que je décris dans mon message ci-dessus :
http://jiem51.perso.neuf.fr/prive/ [...] alette.zip  
Fichier zip de 238 Ko (244 042 octets) contenant :

  • BDD.xls -> La liste des données
  • Fiche palette.xls -> Le fichier excel contenant la macro et le template de l'étiquette.
  • incrémentation et impréssion automatique [VBA excel] - VB_VBA_VBS - Programmation - FORUM HardWare.fr.pdf -> Ce fil de message


Le code des macros du fichier Fiche palette.xls :

Code :
  1. Option Explicit
  3. '************************************************************************
  4. '** Ces macros permettent  d'imprimer  automatiquement des  étiquettes **
  5. '** renseignées à partir d'une données contenues dans un fichier Excel **
  6. '** extérieur.                                                         **
  7. '** Elle ne permet pas le choix de l'imprimante (qui est celle choisie **
  8. '** dans le gestionnaire d'imprimante).                                **
  9. '**                                                                    **
  10. '** Ecrites & testées sous Excel 2003, Win XP, 32bits.                 **
  11. '**                                                                    **
  12. '** Modifications, améliorations, redistribution fortement encouragées **
  13. '**                                                                    **
  14. '**                                                                    **
  15. '**                                               OtObOx - 10/09/2011  **
  16. '************************************************************************
  18. 'Ouvre un explorateur pour sélectionner un fichier Excel
  19. 'et lance l'impression
  20. Sub ChoixFichier()
  21. Dim strReponse
  22.     strReponse = Application.GetOpenFilename("Fichiers Excel (*.xls), *.xls", , "Sélectionner le fichier à imprimer" )
  23.     If strReponse = False Then
  24.         Cells(1, 1) = ""
  25.     Else
  26.         Cells(1, 1) = strReponse
  27.         ImprimerFichesPalette
  28.     End If
  29. End Sub
  31. 'Lance l'impression sans choisir le fichier à traiter
  32. Sub LancerImpression()
  33.     ImprimerFichesPalette
  34. End Sub
  36. 'Imprime les fiches palettes en fonction des données inscrites dans le
  37. 'classeur excel sélectionné dans la cellule A1
  38. Private Sub ImprimerFichesPalette()
  39. Dim xlDoc As Excel.Workbook
  40. Dim xlDon As Excel.Worksheet
  41. Dim xlEti As Excel.Worksheet
  42. Dim Ligne As Integer
  44. On Error GoTo ImprimerFichesPalette_Error
  46.     'Test pour vérifier si une adresse de fichier est sélectionnée et qu'elle est valide
  47.     Do
  48.         If Not IsEmpty(Cells(1, 1)) Then
  49.             If Dir(Cells(1, 1)) <> "" Then
  50.                 Exit Do
  51.             End If
  52.         Else
  53.             If MsgBox("Le fichier de données n'est pas valide !" & vbCr & "Voulez-vous en sélectionner un maintenant ?", vbYesNo, "Erreur fichier" ) = vbYes Then
  54.                 ChoixFichier
  55.             Else
  56.                 Exit Sub
  57.             End If
  58.         End If
  59.     Loop
  60.    
  61.     'Met en mémoire l'onglet contenant l'étiquette
  62.     Set xlEti = ThisWorkbook.Worksheets("Etiquette" )
  63.     'Définition de la zone d'impression
  64.     xlEti.PageSetup.PrintArea = "$A$4:$C$11"
  65.    
  66.     'Ouvre le fichier sélectionné
  67.     Set xlDoc = Workbooks.Open(Cells(1, 1))
  68.     'Met en mémoire l'onglet contenant les données (ici le 1er onglet)
  69.     Set xlDon = xlDoc.Worksheets(1) '(1) pour 1er onglet
  70.    
  71.     'Initialisation du n° de ligne contenant la 1ere donnée
  72.     Ligne = 2
  73.     'Parcourt la liste du 1er onglet tant que la cellule de la 1ere colone soit vide
  74.     Do While Not IsEmpty(xlDon.Cells(Ligne, 1))
  75.         With xlEti
  76.             'Recopie des données vers l'étiquette
  77.             .Cells(5, 1) = xlDon.Cells(Ligne, 1) 'N° tournée
  78.             .Cells(5, 2) = xlDon.Cells(Ligne, 4) 'Récépissé
  79.             .Cells(7, 1) = UCase(xlDon.Cells(Ligne, 2)) 'Destination en MAJUSCULE
  80.             '.Cells(7, 1) = xlDon.Cells(Ligne, 2) 'Destination tel qu'écrit dans la base de donnée
  81.             .Cells(9, 1) = UCase(xlDon.Cells(Ligne, 3)) 'Client en MAJUSCULE
  82.             '.Cells(9, 1) = xlDon.Cells(Ligne, 3) 'Client tel qu'écrit dans la base de donnée
  83.             .Cells(11, 1) = xlDon.Cells(Ligne, 5) 'Palette
  84.             .Cells(11, 3) = xlDon.Cells(Ligne, 6) 'Nb colis
  85.        
  86.             'Impression de l'étiquette
  87.             .PrintOut Copies:=1, Collate:=True
  88.            
  89.             'Ligne suivante
  90.             Ligne = Ligne + 1
  91.         End With
  92.     Loop
  93.     'Ferme le fichier de données
  94.     xlDoc.Close
  95.     'Libère les objets créés dans la mémoire
  96.     Set xlDon = Nothing
  97.     Set xlEti = Nothing
  98.     Set xlDoc = Nothing
  99.     'Annule la zone d'impression
  100.     ActiveSheet.PageSetup.PrintArea = ""
  102. On Error GoTo 0
  103. Exit Sub
  105. ImprimerFichesPalette_Error:
  106.     MsgBox "Erreur " & Err.Number & " (" & Err.Description & " )", vbCritical
  107. End Sub


---------------
OtObOxBlOg - - - Etre seul à avoir tort  c'est plus difficile, mais c'est bien plus beau que d'avoir raison avec une bande de cons

Aller à :
Ajouter une réponse
  FORUM HardWare.fr
  Programmation
  VB/VBA/VBS

  [VBA excel] incrémentation et impréssion automatique

 

Sujets relatifs
[ACCESS/VBA] Remplir une table reliée à une autre automatiquement[demande] envoi automatique de produit numerique
mise a jour automatique JTablepRESENTATION DES DONNEES DANS UN FORMULAIRE POUR IMPRESSION
Création page web avec update automatique du contenu[VBA]: variable static initialisation
VBA - Gestion de la fenêtre windows "Téléchargement de fichier"Concaténation de champ automatique avec conditions
VBA: La méthode de l'objet Worksheet a echoué 
Plus de sujets relatifs à : [VBA excel] incrémentation et impréssion automatique

Forum MesDiscussions.Net, Version 2010.2
(c) 2000-2011 Doctissimo
Page générée en 0.069 secondes

Copyright © 1997-2025 Groupe LDLC (Signaler un contenu illicite / Données personnelles)