Duplication enregistrement Access avec champs contenant plusieurs vale

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : Duplication enregistrement Access avec champs contenant plusieurs vale

gramlinz60

Bonjour,

je souhaiterais pouvoir dupliquer des lignes selon un champs comportant plusieurs valeurs.

exemple d'une ligne:

Colonne A (nom) : Dupont
Colonne B (prénom) : A
Colonne C (couleur) : rouge, vert, jaune

Je souhaiterais donc avoir 3 lignes :

Ligne 1 :
Colonne A (nom) : Dupont
Colonne B (prénom) : A
Colonne C (couleur) : rouge

Ligne 2 :
Colonne A (nom) : Dupont
Colonne B (prénom) : A
Colonne C (couleur) : vert

Ligne 3 :
Colonne A (nom) : Dupont
Colonne B (prénom) : A
Colonne C (couleur) : jaune

Quelqu'un aurait il une solution? (pour info je suis sous access 2003).

Merci d'avance.

Publicité

otobox

En vba, c'est possible. Je te conseille néanmoins de passer par 3 tables :
- une table nom (tabNoms)
- une table couleur (tabCouleurs)
- une table liant les noms et les couleurs (tabRefNomsCouleurs)

Ensuite, parcourir la table de départ et pour chaque ligne, enregistrer le nom & prénom dans la table nom, ensuite pour chaque couleur dans le champ Couleurs, extraire le nom de la couleur, la stocker dans la table couleur si elle n'existe pas et compléter la table des relations Noms<->Couleurs
Ensuite, une requête (reqNomsCouleurs) permet d'afficher le résultat :

Voilà ce que ça donne :

J'ai nommé ta table "Originale" et complètée tel que tu donnais ton exemple : 3 champs : nom, prénom et couleurs, les couleurs étant séparées entre elles par des virgules.

Ne pas oublier de lier les tables entre elles en appliquant l'intégrité différentielle.

Ensuite, créer un module et faire le copier-collé du code ci-dessous (double clic dans la fenêtre du code ci-dessous pour enlever les numéros de lignes avant de faire le copier-coller )

Code :

Option Compare Database
Option Explicit
Sub toto()
'Déclaration des variables :
'Objet base
Dim db As DAO.Database
'Objets tables
Dim tabOri As DAO.TableDef
Dim tabNom As DAO.TableDef
Dim tabCou As DAO.TableDef
Dim tabRel As DAO.TableDef
'Objets enregistrements
Dim rstOri As Recordset
Dim rstNom As Recordset
Dim rstCou As Recordset
Dim rstRel As Recordset
'Numériques entières
Dim i As Integer
Dim intIdNom As Integer 'Clé de la table tabNoms
Dim intIdCou As Integer 'Clé de la table tabCouleurs
'Chaines de caractères
Dim strChampCouleurs As String
Dim strSep As String
Dim strCar As String
Dim strCouleur As String
'Variant
Dim varCouleur As Variant
'Initialisation des variables :
'Base
Set db = CurrentDb
'Tables
Set tabOri = db.TableDefs("Originale" )
Set tabNom = db.TableDefs("tabNoms" )
Set tabCou = db.TableDefs("tabCouleurs" )
Set tabRel = db.TableDefs("tabRefNomsCouleurs" )
'Parcours de la table "Originale"
With tabOri
Set rstOri = .OpenRecordset
Set rstNom = tabNom.OpenRecordset
Set rstCou = tabCou.OpenRecordset
Set rstRel = tabRel.OpenRecordset
'rstOri.MoveFirst
'Pour chaque enregistrement de la table "Originale"
While Not rstOri.EOF
'Lecture du champ Nom et écriture de celui ci dans la table "tabNoms" :
rstNom.AddNew 'ouverture d'un enregistrement dans la table "tabNoms"
rstNom.Fields(1) = rstOri.Fields(0) 'Enregistrement du nom dans la table tabNoms
rstNom.Fields(2) = rstOri.Fields(1) 'Enregistrement du prénom dans la table tabNoms
intIdNom = rstNom.Fields(0) 'Clé de l'enregistrement créé
rstNom.Update 'Validation de l'enregistrement
'Lecture du champ Couleurs
strChampCouleurs = rstOri.Fields(2)
'Il faut décomposer la ligne pour extraire chaque couleur
'Le nom des couleurs est séparé par des vigules
strSep = ","
strCouleur = ""
For i = 1 To Len(strChampCouleurs) + 1
strCar = Mid$(strChampCouleurs, i, 1)
'Dès qu'un séparateur ou que la fin de la chaine est détecté, chercher dans
'la table "tabCouleurs" si la couleur existe
If strCar = strSep Or i = Len(strChampCouleurs) + 1 Then
varCouleur = DLookup("idCouleur", "tabCouleurs", "Couleur='" & Trim(strCouleur) & "'" )
If Not IsNull(varCouleur) Then
'Si la couleur est trouvée, alors inscrire la refCouleur dans la table relation
rstRel.AddNew
rstRel.Fields(1) = intIdNom 'Champs refIdNom
rstRel.Fields(2) = varCouleur 'Champs refIdCouleur
rstRel.Update 'Validation de la ligne
Else
'Sinon, inscrire la couleur dans la table couleur
rstCou.AddNew
rstCou.Fields(1) = Trim(strCouleur) 'Nom de la couleur sans espace dans le champ Couleur
intIdCou = rstCou.Fields(0)
rstCou.Update
'et inscrire la refCouleur dans la table relation
rstRel.AddNew
rstRel.Fields(1) = intIdNom 'Champs refIdNom
rstRel.Fields(2) = intIdCou 'Champs refIdCouleur
rstRel.Update 'Validation de la ligne
End If
strCouleur = "" 'Effacement de la couleur en cours
Else
strCouleur = strCouleur & strCar
End If
Next i
'Ligne suivante dans la table "Originale"
rstOri.MoveNext
Wend
End With
'Fermeture des objets :
'recordsets
Set rstOri = Nothing
Set rstNom = Nothing
Set rstCou = Nothing
Set rstRel = Nothing
'Tables
Set tabOri = Nothing
Set tabNom = Nothing
Set tabCou = Nothing
Set tabRel = Nothing
End Sub

Le code est commenté, ce qui m'évite de le faire maintenant !

C'est du code pour Access 97, je crois que pour 2003, il faut aussi insérer un gestionnaire d'erreur. A toi de le faire. Ce code fonctionne chez moi.

Trucs : tu peux changer le nom des tables pour mettre les tiens sur les lignes 34 à 37 et changer le caractère qui sépare le nom des couleurs à la ligne n°61 (variable strSep)

Résultat :

Bon courage

Message édité par otobox le 06-12-2008 à 13:10:53

gramlinz60

Je vais tester tout ça, de plus cela me paraît très clair.

Un grand merci à toi!

SuppotDeSaTante

Aka dje69r

Bonjour

OtObOx C'est assez génial de voir des posts comme le tiens ! :jap:

J'apporte juste ma petite contribution qui permet 'plus simplement', je pense, d'obtenir une table avec autant de lignes que de couleurs dans les enregistrements originaux.

Citation :

Function gramlinz60(NomDeTaTable, NomChamp_Nom, NomChamp_Prenom, NomChamp_Couleur) 'Le nom de ta table ou tu as tes lignes originales
'Les nom des champs Nom, Prenom et Couleur

'On enleve les alertes sur requetes action
DoCmd.SetWarnings False

'On créer une variable pour les guillemets, plus facile pour les integrer dans une chaine de requete
guil = Chr$(34)

'On compte le nombre d'enregistrement dans ta table originale
Set TableEnr = CurrentDb.OpenRecordset(NomDeTaTable)
Cpte = TableEnr.RecordCount

'on créé une table vierge avec Nom, Prenom et couleur
Query = "SELECT " & guil & guil & " AS NomP, " & guil & guil & " AS PrenomP, " & guil & guil & " AS Couleur INTO MultiLigne;"
DoCmd.RunSQL (Query)
'on vide cette meme table
Query = "DELETE MultiLigne.* FROM MultiLigne;"
DoCmd.RunSQL (Query)

'On se positionne sur le premier enregistrement de ta table originale
TableEnr.MoveFirst

'Pour chaque enregistrement on va ajouter une ligne avec la couleur dans la table créée
For x = 1 To Cpte

ValCouleur = TableEnr(NomChamp_Couleur)
Ex = InStr(1, ValCouleur, "," )

While Ex <> 0
LaCouleur = Trim(Mid(ValCouleur, 1, Ex - 1))

Query = "INSERT INTO MultiLigne ( NomP, PrenomP, Couleur ) SELECT " & guil & TableEnr(NomChamp_Nom) & guil & " AS Ex1, " & _
guil & TableEnr(NomChamp_Prenom) & guil & " AS Ex2, " & guil & LaCouleur & guil & " AS Ex3;"
DoCmd.RunSQL (Query)

ValCouleur = Trim(Right(ValCouleur, Len(ValCouleur) - Ex))
Ex = InStr(Ex, ValCouleur, "," )

Wend

Query = "INSERT INTO MultiLigne ( NomP, PrenomP, Couleur ) SELECT " & guil & TableEnr(NomChamp_Nom) & guil & " AS Ex1, " & _
guil & TableEnr(NomChamp_Prenom) & guil & " AS Ex2, " & guil & ValCouleur & guil & " AS Ex3;"
DoCmd.RunSQL (Query)

TableEnr.MoveNext
Next x

End Function

Je pars du principe que ta table originale se nomme 'Table', le champ nom 'Nom', le champ prénom 'Prenom' et le champ contenant les couleurs 'Couleur'

Pour lancer la fonction :

Citation :

gramlinz60 "Table", "Nom", "Prenom", "Couleur"

Résultat tu as une table nommée 'Multiligne' qui contient tes lignes avec une couleur a chaque fois.

C'est la virgule qui separe les couleurs.

Cordialement

Message cité 1 fois
Message édité par SuppotDeSaTante le 09-12-2008 à 15:41:31

---------------
Soyez malin, louez entre voisins !

otobox

SuppotDeSaTante a écrit :

Bonjour

OtObOx C'est assez génial de voir des posts comme le tiens ! :jap:

Oué, merci je m'ennuyais samedi matin

J'avais répondu un peu à coté, dans la mesure où je ne sors pas une table mais 3 + 1 requête. Redondance toussa... C'est plus long, peut être qu'il y a moyen de faire un peu plus simple, mais c'est plus propre je trouve que de tout mélanger dans une seule table.

SuppotDeSaTante

Aka dje69r

Ah oui c'est certain, mais ne sachant pas pourquoi c'etait faire, je me suis contenté de repondre a la question... :lol:

---------------
Soyez malin, louez entre voisins !

gramlinz60

Merci à vous deux.

J'ai utilisé la première méthodec d'otobox et cela a marché impec!

Merci !

FORUM HardWare.fr

Programmation

VB/VBA/VBS

Duplication enregistrement Access avec champs contenant plusieurs vale

Sujets relatifs
Import d'une table Access vers MySql	Cherche nouveau SGBD pour remplacer Access
récupérer les nom des champs avec pdo()	macro word qui divise 1 fichier en plusieurs fichiers
Access refuse !	Pb base de donnée sous access
mise à jour de deux champs	vector contenant object utilisant polymorphisme, help
[Actionscript & XML] acces a un champs texte d'un bouton	distribuer une application access sous réseau
Plus de sujets relatifs à : Duplication enregistrement Access avec champs contenant plusieurs vale

Page générée en 0.065 secondes