Bonjour,
 
J'ai une question sur l'optimisation de mon script ci-dessous.
Il a pour but de parser un grand nombre de fichier comportant des milliers de ligne.
 
Il ne fait que compter si la ligne 6 est égal ou différent de 0
Puis si c'est vrai il m'envoi un mail de résultat, sinon un mail comme quoi il y a eu un souci.
 
Je veux juste savoir si pour les experts que vous êtes, si cette approche est la bonne ou bien existe t-il une solution plus propre et/ou plus simple pour effectuer ce comptage?
 

opendir(DIR, $DIR) or die "Can't open $DIR: $!";
my $SEARCH_FILE = "billing_$mday-$mon-$year";
    @bil = grep(/$SEARCH_FILE/,readdir(DIR));
    if (scalar @bil)    {
        foreach my $ligne (@bil)    {
            $i=0;
            $y=0;
            open (FILE, "<", $ligne);
            while (my $line=<FILE> )    {
                $_ = $line;
                chomp $line;
                @tab=split(/;/,$line);
                if ($tab[5] == 0)    {
                    $i = $i + 1;
                }
                elsif ($tab[5] != 0)    {
                    $y = $y + 1;
                }
            }
            $Message = $Message . "$mday_hier/$mon_hier/$year_hier\t$y\t\t$i\n";
            print "$mday_hier/$mon_hier/$year_hier;$y;$i\n";
            close (FILE);
        }
        unlink join("\n", @bil), "\n";
    }
    # Vérification de la présence des données
    if ($#bil == -1)    {    
        print "\n$Err\n";
        print "ERROR: NO FILES\n";
        print "ERROR: __END__\n\n";
        # send email
        email_no_bil($To, $From, $Cc, $Bcc, $SubjectErr, $Message, $File);
        exit;
    }
    closedir(DIR) or warn "Can't close $DIR: $!";

Non. Pour chaque ligne, il regarde si le 6e champ vaut 0

J'ai pas testé, mais je ferais ainsi:

my $SEARCH_FILE = "billing_$mday-$mon-$year";
opendir(DIR, $DIR) or die "Can't open $DIR: $!";
my @bil = grep /$SEARCH_FILE/ readdir(DIR);
closedir(DIR) or warn "Can't close $DIR: $!";
 
if (@bil > 0)  {
  foreach my $file (@bil)    {
    my ($i, $y) = (0, 0);
    open (FILE, "<", $file);
    while (<FILE> )  {
      # chomp;  # mis en commentaire car probablement inutile
      (split(/;/, $_))[5]?++$y:++$i;
    }
    close (FILE);
    $Message = $Message . "$mday_hier/$mon_hier/$year_hier\t$y\t\t$i\n";
    print "$mday_hier/$mon_hier/$year_hier;$y;$i\n";
  }
  unlink join("\n", @bil), "\n"; # Je sais pas ce que vous voulez faire, mais c'est surement pas ça
  # si c'est pour supprimer les fichiers, un simple unlink @bil; suffit
}
else {
  print "\n$Err\n";
  print "ERROR: NO FILES\n";
  print "ERROR: __END__\n\n";
  # send email
  email_no_bil($To, $From, $Cc, $Bcc, $SubjectErr, $Message, $File);
  exit;
}

On ouvre le directory le plus tard possible, et on le ferme le plus tôt possible.

if (@bil > 0)
ça teste si l'array a des éléments ou non, et c'est lisible.
et on fait un else pour quand il n'y en a pas au lieu de faire if ($#bil == -1) ce qui est dangereux

on va pas faire de (my $line = <FILE> ) et ensuite $_ = $line, car ça fait faire une copie complète de ligne à chaque fois (et en plus $_ n'est pas utilisé dans votre code)
On va juste faire (<FILE> ) et on aura donc chaque ligne directement dans $_
(split(/;/, $_))[5]?++$y:++$i;
On teste le 6e champ de la ligne, (split(/;/, $_))[5], obtenu donc en splittant la ligne sur ;  et donc en évitant une coûteuse recopie dans un array
Si ce 6e champ est non nul, on incrémente $y, sinon, on incrémente $i.
C'est l'opérateur A?B:C  qu'on retrouve dans tous les langages modernes, depuis le C.

Ça devrait accélérer le script.

NOTE: avec le test (split(/;/, $_))[5] si on a un 6e champ vide ;; ou bien absent (moins de 6 champs) il compte comme s'il valait 0.
Par contre un 6e champ avec 00 ou 0.0 compte comme s'il ne vaut pas 0
On peut se modifier le test en fonction du comportement voulu pour ces cas limites.

A+,

waouh, ça c'est de l'explication
Merci Gilou,
 
Le (split(/;/, $_))[5]?++$y:++$i; est assez puissant, je ne connaissais pas. Je vais bosser sur ça.
 
Le my ($i, $y) = (0, 0); est sympas aussi, tellement simple qu'on y pense pas.