Agent Fusion inventory

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : Agent Fusion inventory

Micko77666

Bonjour tout le monde,

Alors voilà, nous allons mettre Fusion inventory sur l'ensemble de notre parc informatique. Quand je lance mon script VBS à la mains aucun soucis, ça fonctionne sans soucis. Par contre quand je le fais depuis une GPO je ne peux pas, elle est bien dans le script du démarrage du PC pas de soucis, elle s'applique bien au PC en question (RSOP ok), mais je pense qu'il me manque l’élévation des droits ou l'UAC qui me dérange.

Une idée pour contourner ça ? ça doit être tout bête en plus

En vous remerciant par avance,

Publicité

nebulios

Comment tu lances ton script ?

Micko77666

Alors si je lance en local par exemple aucun soucis. Si depuis un utilisateur lambda je vais dans :

\\serveurAD\sysvol\etc.... et que lance le VBS ça marche mais faut que je rentre des infos admin. Et si je suis admin quand je fais ça bas juste accepter à cause de l'UAC.

Donc malgré que je le lance via une GPO ordinateur bas l'UAC ou les droits bloquent visiblement. Mais je vois pas en quoi, je publie des imprimantes sans le moindre soucis par exemple.

nebulios

Dans la GPO vérifie que tu appelles ton script avec cscript.exe
Je suppose que ton script n'a pas besoin d'une interaction pour s'exécuter.

Micko77666

Non c'est le VBS du site FusionInventory vraiment rien de bien méchant à la base quoi.

Je vérifie comment pour le cscript.exe ?

Message cité 1 fois

crachkiller

Micko77666 a écrit :

Non c'est le VBS du site FusionInventory vraiment rien de bien méchant à la base quoi.

Je vérifie comment pour le cscript.exe ?

En fait tu exécutes cscript.exe et tu mets ton fichier vbs en argument. Cscript est un exécutable présent dans les répertoires système de l'os.

Micko77666

Ah OK jamais eu besoin de le faire avant, je testerai ça lundi

Mais c'est vrai que c'est bizarre car la GPO est très simple et le VBS aussi.

Message cité 2 fois

crachkiller

Micko77666 a écrit :

Ah OK jamais eu besoin de le faire avant, je testerai ça lundi

Mais c'est vrai que c'est bizarre car la GPO est très simple et le VBS aussi.

En fait lorsque tu double clic sur ton fichier vbs ton os utilise l'exécutable cscript.exe pour l'exécuter. C'est pour cela que tu doit lui indiquer avec quoi exécuter ton code, un fichier vbs n'est pas un exécutable.

Micko77666

Et du coup si c'est bien cscript qui ouvre mon VBS, qu'est ce qu'il y a d'autres comme pistes ?

Un soucis sur mon VBS ?

crachkiller

Dans une GPO de type ordinateur tu n'as pas besoin d'élever les droits car le script est exécuté avec les droits systèmes.
Dans mon AD, le script fusion s'exécute correctement quel que soit la version d'os, et il est exécuté via cscript dans une gpo ordinateur.

Alors a priori je dirais que ça doit fonctionner de cette manière.

Publicité

Micko77666

Tu as un exemple de ton script pour stp et tu as pas de soucis avec l'UAC ?

Message cité 1 fois

crachkiller

Micko77666 a écrit :

Tu as un exemple de ton script pour stp et tu as pas de soucis avec l'UAC ?

J'utilise le script fourni avec le plugin fusioninventory. Si ça ne fonctionne toujours pas de ton côté lundi, je te file ça. Non aucun soucis

nebulios

Micko77666 a écrit :

Ah OK jamais eu besoin de le faire avant, je testerai ça lundi

Mais c'est vrai que c'est bizarre car la GPO est très simple et le VBS aussi.

Le moteur par défaut est wscript qui se comporte différement. Sinon tu balances un package MSI par un GPO ou tu fais un script en Powershell.

Micko77666

Bon j'ai regardé en arrivant au travail, en fait j'ai ce message d'erreur avec un gpresult :

" Les objets stratégie de groupe n'ont pas été appliqués
car ils ont été refusés"

Forcément ça aide pas .... par contre je ne vois pas pourquoi il me fait ça. Mon PC est dans la bonne OU, en filtre j'ai mis le nom de mon PC et j'ai bien assez au lecteur réseau avec les sources du logiciel à installer.

Message cité 1 fois
Message édité par Micko77666 le 02-01-2017 à 11:01:54

rattrappemoi

Micko77666 a écrit :

Quelle est la solution trouvée ?

Micko77666

Je reviens sur mon sujet, j'avais le soucis pour que la GPO s'applique correctement à l'utilisateur, car effectivement je n'avais pas mis utilisateur authentifié dans la délégations.

Par contre je rencontre toujours le soucis d'installation de l'agent.

- En gros avec RSOP.MSC ou gpresult /R je vois bien que ma GPO est ok , que le script est bien au bon endroit.
- Si je lance mon script à la main dans \\srv\sysvol\policies\etc.... l'agent s'installe bien, faut juste entrer un login et un mot de passe pour avoir les droits.

Donc mon script tout comme mon agent sont fonctionnent bien.

Qu'est-ce qu'il pourrait manquer ?

nnwldx

Si le programme te demande un mot de passe c'est que le programme doit se lancer dans une gpo utilisateur et que l'utilisateur n'est pas administrateur.
Tu peux faire une gpo ordinateur, tu vas ensuite dans exécuter un programme/script au démarrage.
Tu mets ton agent OCS sur un dossier partagé, tu lui donnes le chemin de ton agent \\serveur\partage_ocs\agent.exe
Ensuite dans les paramètres de script tu rentres les paramètres OCS : adresse serveur, https, installation silencieuses...

Message édité par nnwldx le 29-04-2017 à 11:58:24

Micko77666

Non j'ai la demande du mot de passe quand je lance le script à la main. Et FusionInventory comme les autres applications se fait depuis une GPO ordinateur pour justement pas avoir de login et mdp.

Mais j'arrive pas à voir pourquoi sur mes PCs rien ne se passe.

borntokiff

Essaye peut être avec un poste clean, fresh install désactive AV/FIREWALL/UAC ect ...

Micko77666

Je test actuellement justement avec un fixe et un portable qui viennent d'être refait, pour ça je comprends pas ce qui bloque du tout.

Micko77666

Personne n'a d'idée ou de pistes ? car la je sèche complet, je vois vraiment pas ce qui peut bloquer l'installation de FusionInventory

nnwldx

si tu essayes d'activer l'attente du réseau.
Computer Configuration -> Administrative Templates -> System -> Logon “Always Wait for the Network at Computer Startup and Logon”

Message édité par nnwldx le 02-05-2017 à 19:44:46

Micko77666

Je viens de faire la modification, je vois bien la nouvelle stratégie appliquée via RSOP, mais ça ne fonctionne malheureusement toujours pas.

Par contre si je mets un .MSI à installer ça fonctionne parfaitement. Et le script est OK vu que ça fonctionne quand je le lance à la main

bicoun

Et non pas Bicounet !!!

Salut,
Le script vbs va chercher ls msi sur Internet directement ou le fichier d'installation de l'agent Fusion Inventory est sur un partage de ton LAN ?

---------------
Pixel mort -> .

Micko77666

Sur un partage de mon LAN

Message cité 1 fois

crachkiller

Micko77666 a écrit :

Sur un partage de mon LAN

Tu as essayé en hébergeant le .msi Fusion Inventory directement sur le netlogon ? Chez nous le script d'install vbs, le .msi sont sur le netlogon et avec une gpo ordinateur ca fonctionne très bien.

Micko77666

J'ai essayé sur un partage et dans le SYSVOL, et dans les deux cas j'arrive à y accéder sur le pc et lancer le script qui s'installe bien et remonte le PC.

Je vais essayé quand même sur le NETLOGON, mais ce qui est étrange c'est que sur aucune doc ou tuto ça pose problème ce que je fais

Message cité 1 fois

nnwldx

sinon tu peux le déployer avec psexec.

Micko77666

Oui ça restera mon dernier recours, mais j'aimerai comprendre pourquoi ça fonctionne pas, car ça risque de revenir avec d'autre chose

crachkiller

Micko77666 a écrit :

Bon ca m'intrigue. Demain je jette un oeil sur la config que j'ai mis en place chez nous.

crachkiller

Bon alors voici la config qui fonctionne chez nous :
- Contenu du netlogon :

-GPO Ordinateur sur l'OU qui contient tous les ordinateurs du domaine:
Filtrage de sécurité par défaut : Utilisateurs authentifiés

Voilà en espérant que ca pourra t'aider !!

Micko77666

Je viens de faire exactement comme toi, mais toujours rien. Si je vais dans mon \\srv\NETLOGON\fusion etc... et lance le script ça fonctionne (mise à part qu'il me demande l'autorisation mais c'est logique).

Je vois pas où ça bloque franchement

crachkiller

Est ce que par hasard ça ne viendrait pas de ce paramètre dans les propriétés de ton fichier vbs ?

Micko77666

Je le retrouve où ce paramètre ?

Message cité 1 fois

crachkiller

Micko77666 a écrit :

Je le retrouve où ce paramètre ?

Clic droit propriété sur le vbs. Ce paramètre ne s'affiche que si c'est un fichier téléchargé depuis internet, il est nécessaire de le débloquer, et une fois débloqué ce paramètre disparaît.

Micko77666

Je vais regarder ça car pas vu. Merci en tout cas pour l'aide

Micko77666

Je viens de regarder je n'ai pas l'option.

crachkiller

Tu as essayé de désactiver l'UAC sur ton poste de test ?

Micko77666

Oui mais rien de mieux malheureusement

crachkiller

Tu utilise quel script car sur la toile on en trouve plusieurs ?
Le mien est celui-ci :

Code :

'
' ------------------------------------------------------------------------
' fusioninventory-agent-deployment.vbs
'
' http://www.fusioninventory.org/ http://forge.fusioninventory.org/
' ------------------------------------------------------------------------
'
' LICENSE
'
' This file is part of FusionInventory project.
'
' This file is free software; you can redistribute it and/or modify it
' under the terms of the GNU General Public License as published by the
' Free Software Foundation; either version 2 of the License, or (at your
' option) any later version.
'
'
' This file is distributed in the hope that it will be useful, but WITHOUT
' ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
' FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for
' more details.
'
' You should have received a copy of the GNU General Public License
' along with this program; if not, write to the Free Software Foundation,
' Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA,
' or see <http://www.gnu.org/licenses/>.
'
' ------------------------------------------------------------------------
'
' @package FusionInventory Agent
' @file .\contrib\windows\fusioninventory-agent-deployment.vbs
' @author(s) Benjamin Accary <meldrone@orange.fr>
' Christophe Pujol <chpujol@gmail.com>
' Marc Caissial <marc.caissial@zenitique.fr>
' Tomas Abad <tabadgp@gmail.com>
' @license GNU GPL version 2 or (at your option) any later version
' http://www.gnu.org/licenses/old-li [...] alone.html
' @link http://www.fusioninventory.org/
' @link http://forge.fusioninventory.org/p [...] tory-agent
' @since 2012
'
' ------------------------------------------------------------------------
'
'
'
' Purpose:
' FusionInventory Agent Unatended Deployment.
'
'
Option Explicit
Dim Force, Verbose
Dim Setup, SetupArchitecture, SetupLocation, SetupOptions, SetupVersion
'
'
' USER SETTINGS
'
'
' SetupLocation
' Depending on your needs or your environment, you can use either a HTTP or
' CIFS/SMB.
'
' If you use HTTP, please, set to SetupLocation a URL:
'
' SetupLocation = "http://host[:port]/[absolut_path]" or
' SetupLocation = "https://host[:port]/[absolut_path]"
'
' If you use CIFS, please, set to SetupLocation a UNC path name:
'
' SetupLocation = "\\host\share\[path]"
'
' You also must be sure that you have removed the "Open File Security Warning"
' from programs accessed from that UNC.
'
SetupLocation = "\\my.domain\NETLOGON\fusioninventory-agent"
' SetupVersion
' Setup version with the pattern <major>.<minor>.<release>[-<package>]
'
'PENSER A RETIRER FORCE = YES PLUS BAS
SetupVersion = "2.3.18"
'PENSER A RETIRER FORCE = YES PLUS BAS
' SetupArchitecture
' The setup architecture can be 'x86', 'x64' or 'Auto'
'
' If you set SetupArchitecture = "Auto" be sure that both installers are in
' the same SetupLocation.
'
SetupArchitecture = "Auto"
' SetupOptions
' Consult the installer documentation to know its list of options.
'
' You should use simple quotes (') to set between quotation marks those values
' that require it; double quotes (" ) doesn't work with UNCs.
'
SetupOptions = "/installtasks=Full /acceptlicense /add-firewall-exception /runnow /server='http://my.glpi.server/plugins/fusioninventory/' /S"
' Setup
' The installer file name. You should not have to modify this variable ever.
'
Setup = "fusioninventory-agent_windows-" & SetupArchitecture & "_" & SetupVersion & ".exe"
' Force
' Force the installation even whether Setup is previously installed.
'
Force = "No"
' Verbose
' Enable or disable the information messages.
'
' It's advisable to use Verbose = "Yes" with 'cscript //nologo ...'.
'
Verbose = "No"
'
'
' DO NOT EDIT BELOW
'
'
Function AdvanceTime(nMinutes)
Dim nMinimalMinutes, dtmTimeFuture
' As protection
nMinimalMinutes = 5
If nMinutes < nMinimalMinutes Then
nMinutes = nMinimalMinutes
End If
' Add nMinutes to the current time
dtmTimeFuture = DateAdd ("n", nMinutes, Time)
' Format the result value
' The command AT accepts 'HH:MM' values only
AdvanceTime = Hour(dtmTimeFuture) & ":" & Minute(dtmTimeFuture)
End Function
Function baseName (strng)
Dim regEx, ret
Set regEx = New RegExp
regEx.Global = true
regEx.IgnoreCase = True
regEx.Pattern = ".*[/\\]([^/\\]+)$"
baseName = regEx.Replace(strng,"$1" )
End Function
Function GetSystemArchitecture()
Dim strSystemArchitecture
Err.Clear
' Get operative system architecture
On Error Resume Next
strSystemArchitecture = CreateObject("WScript.Shell" ).ExpandEnvironmentStrings("%PROCESSOR_ARCHITECTURE%" )
If Err.Number = 0 Then
' Check the operative system architecture
Select Case strSystemArchitecture
Case "x86"
' The system architecture is 32-bit
GetSystemArchitecture = "x86"
Case "AMD64"
' The system architecture is 64-bit
GetSystemArchitecture = "x64"
Case Else
' The system architecture is not supported
GetSystemArchitecture = "NotSupported"
End Select
Else
' It has been not possible to get the system architecture
GetSystemArchitecture = "Unknown"
End If
End Function
Function isHttp(strng)
Dim regEx, matches
Set regEx = New RegExp
regEx.Global = true
regEx.IgnoreCase = True
regEx.Pattern = "^(http(s?)).*"
If regEx.Execute(strng).count > 0 Then
isHttp = True
Else
isHttp = False
End If
Exit Function
End Function
Function IsInstallationNeeded(strSetupVersion, strSetupArchitecture, strSystemArchitecture)
Dim strCurrentSetupVersion
' Compare the current version, whether it exists, with strSetupVersion
If strSystemArchitecture = "x86" Then
' The system architecture is 32-bit
' Check if the subkey 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory Agent' exists
' This subkey is now deprecated
On error resume next
strCurrentSetupVersion = WshShell.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory Agent\DisplayVersion" )
If Err.Number = 0 Then
' The subkey 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory Agent' exists
If strCurrentSetupVersion <> strSetupVersion Then
ShowMessage("Installation needed: " & strCurrentSetupVersion & " -> " & strSetupVersion)
IsInstallationNeeded = True
End If
Exit Function
Else
' The subkey 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory Agent' doesn't exist
Err.Clear
' Check if the subkey 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory-Agent' exists
On error resume next
strCurrentSetupVersion = WshShell.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory-Agent\DisplayVersion" )
If Err.Number = 0 Then
' The subkey 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory-Agent' exists
If strCurrentSetupVersion <> strSetupVersion Then
ShowMessage("Installation needed: " & strCurrentSetupVersion & " -> " & strSetupVersion)
IsInstallationNeeded = True
End If
Exit Function
Else
' The subkey 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory-Agent' doesn't exist
Err.Clear
ShowMessage("Installation needed: " & strSetupVersion)
IsInstallationNeeded = True
End If
End If
Else
' The system architecture is 64-bit
' Check if the subkey 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory Agent' exists
' This subkey is now deprecated
On error resume next
strCurrentSetupVersion = WshShell.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory Agent\DisplayVersion" )
If Err.Number = 0 Then
' The subkey 'SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory Agent' exists
If strCurrentSetupVersion <> strSetupVersion Then
ShowMessage("Installation needed: " & strCurrentSetupVersion & " -> " & strSetupVersion)
IsInstallationNeeded = True
End If
Exit Function
Else
' The subkey 'SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory Agent' doesn't exist
Err.Clear
' Check if the subkey 'SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory-Agent' exists
On error resume next
strCurrentSetupVersion = WshShell.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory-Agent\DisplayVersion" )
If Err.Number = 0 Then
' The subkey 'SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory-Agent' exists
If strCurrentSetupVersion <> strSetupVersion Then
ShowMessage("Installation needed: " & strCurrentSetupVersion & " -> " & strSetupVersion)
IsInstallationNeeded = True
End If
Exit Function
Else
' The subkey 'SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory-Agent' doesn't exist
Err.Clear
' Check if the subkey 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory-Agent' exists
On error resume next
strCurrentSetupVersion = WshShell.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory-Agent\DisplayVersion" )
If Err.Number = 0 Then
' The subkey 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory-Agent' exists
If strCurrentSetupVersion <> strSetupVersion Then
ShowMessage("Installation needed: " & strCurrentSetupVersion & " -> " & strSetupVersion)
IsInstallationNeeded = True
End If
Exit Function
Else
' The subkey 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory-Agent' doesn't exist
Err.Clear
ShowMessage("Installation needed: " & strSetupVersion)
IsInstallationNeeded = True
End If
End If
End If
End If
End Function
Function IsSelectedForce()
If LCase(Force) <> "no" Then
ShowMessage("Installation forced: " & SetupVersion)
IsSelectedForce = True
Else
IsSelectedForce = False
End If
End Function
' http://www.ericphelps.com/scriptin [...] index.html
Function SaveWebBinary(strSetupLocation, strSetup)
Const adTypeBinary = 1
Const adSaveCreateOverWrite = 2
Const ForWriting = 2
Dim web, varByteArray, strData, strBuffer, lngCounter, ado, strUrl
strUrl = strSetupLocation & "/" & strSetup
'On Error Resume Next
'Download the file with any available object
Err.Clear
Set web = Nothing
Set web = CreateObject("WinHttp.WinHttpRequest.5.1" )
If web Is Nothing Then Set web = CreateObject("WinHttp.WinHttpRequest" )
If web Is Nothing Then Set web = CreateObject("MSXML2.ServerXMLHTTP" )
If web Is Nothing Then Set web = CreateObject("Microsoft.XMLHTTP" )
web.Open "GET", strURL, False
web.Send
If Err.Number <> 0 Then
SaveWebBinary = False
Set web = Nothing
Exit Function
End If
If web.Status <> "200" Then
SaveWebBinary = False
Set web = Nothing
Exit Function
End If
varByteArray = web.ResponseBody
Set web = Nothing
'Now save the file with any available method
On Error Resume Next
Set ado = Nothing
Set ado = CreateObject("ADODB.Stream" )
If ado Is Nothing Then
Set fs = CreateObject("Scripting.FileSystemObject" )
Set ts = fs.OpenTextFile(baseName(strUrl), ForWriting, True)
strData = ""
strBuffer = ""
For lngCounter = 0 to UBound(varByteArray)
ts.Write Chr(255 And Ascb(Midb(varByteArray,lngCounter + 1, 1)))
Next
ts.Close
Else
ado.Type = adTypeBinary
ado.Open
ado.Write varByteArray
ado.SaveToFile CreateObject("WScript.Shell" ).ExpandEnvironmentStrings("%TEMP%" ) & "\" & strSetup, adSaveCreateOverWrite
ado.Close
End If
SaveWebBinary = True
End Function
Function ShowMessage(strMessage)
If LCase(Verbose) <> "no" Then
WScript.Echo strMessage
End If
End Function
'
'
' MAIN
'
'
Dim nMinutesToAdvance, strCmd, strSystemArchitecture, strTempDir, WshShell
Set WshShell = WScript.CreateObject("WScript.shell" )
nMinutesToAdvance = 5
' Get system architecture
strSystemArchitecture = GetSystemArchitecture()
If (strSystemArchitecture <> "x86" ) And (strSystemArchitecture <> "x64" ) Then
ShowMessage("The system architecture is unknown or not supported." )
ShowMessage("Deployment aborted!" )
WScript.Quit 1
Else
ShowMessage("System architecture detected: " & strSystemArchitecture)
End If
' Check and auto detect SetupArchitecture
Select Case LCase(SetupArchitecture)
Case "x86"
' The setup architecture is 32-bit
SetupArchitecture = "x86"
Setup = Replace(Setup, "x86", SetupArchitecture, 1, 1, vbTextCompare)
ShowMessage("Setup architecture: " & SetupArchitecture)
Case "x64"
' The setup architecture is 64-bit
SetupArchitecture = "x64"
Setup = Replace(Setup, "x64", SetupArchitecture, 1, 1, vbTextCompare)
ShowMessage("Setup architecture: " & SetupArchitecture)
Case "auto"
' Auto detection of SetupArchitecture
SetupArchitecture = strSystemArchitecture
Setup = Replace(Setup, "Auto", SetupArchitecture, 1, 1, vbTextCompare)
ShowMessage("Setup architecture detected: " & SetupArchitecture)
Case Else
' The setup architecture is not supported
ShowMessage("The setup architecture '" & SetupArchitecture & "' is not supported." )
WScript.Quit 2
End Select
' Check the relation between strSystemArchitecture and SetupArchitecture
If (strSystemArchitecture = "x86" ) And (SetupArchitecture = "x64" ) Then
' It isn't possible to execute a 64-bit setup on a 32-bit operative system
ShowMessage("It isn't possible to execute a 64-bit setup on a 32-bit operative system." )
ShowMessage("Deployment aborted!" )
WScript.Quit 3
End If
If IsSelectedForce() Or IsInstallationNeeded(SetupVersion, SetupArchitecture, strSystemArchitecture) Then
If isHttp(SetupLocation) Then
ShowMessage("Downloading: " & SetupLocation & "/" & Setup)
If SaveWebBinary(SetupLocation, Setup) Then
strCmd = WshShell.ExpandEnvironmentStrings("%ComSpec%" )
strTempDir = WshShell.ExpandEnvironmentStrings("%TEMP%" )
ShowMessage("Running: """ & strTempDir & "\" & Setup & """ " & SetupOptions)
WshShell.Run """" & strTempDir & "\" & Setup & """ " & SetupOptions, 0, True
ShowMessage("Scheduling: DEL /Q /F """ & strTempDir & "\" & Setup & """" )
WshShell.Run "AT.EXE " & AdvanceTime(nMinutesToAdvance) & " " & strCmd & " /C ""DEL /Q /F """"" & strTempDir & "\" & Setup & """""", 0, True
ShowMessage("Deployment done!" )
Else
ShowMessage("Error downloading '" & SetupLocation & "\" & Setup & "'!" )
End If
Else
ShowMessage("Running: """ & SetupLocation & "\" & Setup & """ " & SetupOptions)
WshShell.Run "CMD.EXE /C """ & SetupLocation & "\" & Setup & """ " & SetupOptions, 0, True
ShowMessage("Deployment done!" )
End If
Else
ShowMessage("It isn't needed the installation of '" & Setup & "'." )
End If

Publicité

FORUM HardWare.fr

Systèmes & Réseaux Pro

Poste de travail

Agent Fusion inventory

Sujets relatifs
Fusion de structures et AD - approche -	OCS Inventory : les agents ne trouvent pas le serveur (pas de remontée
GPO Agent OCS Inventory	ocs inventory ng - erreur au déploiement
Desinstallation Fusion	Script d'installation OCS Agent Windows à partir d'un serveur Linux
Base de données d'OCS Inventory	OCS Inventory - SSL OK, mais pas de déploiement
Déployer Fusion inventory via GPO
Plus de sujets relatifs à : Agent Fusion inventory

Page générée en 0.192 secondes