Brad Pitt a écrit :
@gilou : je suis pas une truffe en anglais mais là le langage tech, j'ai pas tout suivi.
|
L'endroit ou tu fabriques tes numéros est le suivant:
set /a compte=%compte%+1
Donc tu peux essayer de remplacer cette ligne par
set /a compte=%compte%+1
set compte=0%compte%
set compte=%compte:~-2%
et ça devrait coller si tu n'as pas 100 fichiers ou plus.
set compte=0%compte% ça rajoute un zéro devant.
set compte=%compte:~-2% ça tronque à deux chiffres
Bon, faut aussi remplacer
for %%i in (*.xxx) do set VrChmFch=%%i& set VrExtnFch=%%~xi& call :renmFch
par
for /f "delims=" %%i in ('DIR /a-d /b *.xxx') do set VrChmFch=%%i& set VrExtnFch=%%~xi& call :renmFch
parce que (Merci MSDOS) il récupère le premier fichier modifié et comme il a toujours l'extension xxx, il lui ré-applique le script (un bug connu de ce genre de trucs en DOS: je teste chez moi avec a.xxx, b.xxx c.xx et ça fait ceci sinon: a.xxx -> NomFic01.xxx, b.xxx -> NomFic02.xxx, c.xxx -> NomFic03.xxx et en 4e, NomFic01.xxx -> NomFic04.xxx et ça s'arrète, donc au final j'ai NomFic02.xxx, NomFic03.xxx, NomFic04.xxx au lieu de NomFic01.xxx, NomFic02.xxx, NomFic03.xxx.)
Le for /f "delims=" %%i in ('DIR /a-d /b *.xxx') do ... est un truc connu qui permet de ne processer qu'une fois les noms de fichier lorsque les noms de fichiers en sortie remplissent les critères de sélection des noms de fichiers en entrée.
au final:
Citation :
@echo off & color 0A
set VrNvNom=NomFic
set compte=0
for /f "delims=" %%i in ('DIR /a-d /b *.xxx') do set VrChmFch=%%i& set VrExtnFch=%%~xi& call :renmFch
goto finRenmFch
:renmFch
set /a compte=%compte%+1
set compte=0%compte%
set compte=%compte:~-2%
ren "%VrChmFch%" "%VrNvNom%%compte%%VrExtnFch%"
goto :eof
:finRenmFch
pause>nul
|
Si tu as plus de 100 fichiers et moins de 1000, il faut remplacer
set compte=0%compte%
set compte=%compte:~-2%
par
set compte=00%compte%
set compte=%compte:~-3%
A+,
Message édité par gilou le 31-05-2015 à 14:27:39
---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --