XSLT très lent

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : XSLT très lent

Profil supprimé

Bonjour,
Je reproduis une carte SVG en modifiant certains attribuer (pour la colorier) mais c'est très lent (avec libsaxonb-java).
Sachant que mon fichier svg possède quelques dizaines de milliers de polygones, et que mon fichier "communes.xml" contient à peu près le même nombre d'entrées.
Il peut prendre plus de 10 minutes à s'exécuter...
Des idées ?

Merci d'avance!

Code :

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:doc="http://jlm2017.fr"
    xmlns:fn="http://www.w3.org/2005/xpath-functions"
    xmlns:dc="http://purl.org/dc/elements/1.1/"
   xmlns:cc="http://creativecommons.org/ns#"
   xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
   xmlns:svg="http://www.w3.org/2000/svg"
   xmlns="http://www.w3.org/2000/svg"
   xmlns:xlink="http://www.w3.org/1999/xlink"
   xmlns:sodipodi="http://sodipodi.sourceforge.net/DTD/sodipodi-0.dtd"
   xmlns:inkscape="http://www.inkscape.org/namespaces/inkscape"
   inkscape:version="0.48.2 r9819"
   sodipodi:docname="circonscriptions.svg"
    exclude-result-prefixes="xs doc">
    <xsl:output method="xml" indent="yes"/>

    <xsl:param name="communes" select="document('../communes.xml')"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="svg:polygon">
       <xsl:variable name="insee" select="substring-before(./@id, ' ')" />
       <xsl:variable name="red" select="$communes//fn:map[@key=$insee]/fn:number[@key='HOLL_PRES_2012']" />
        <xsl:copy>
          <xsl:choose>
            <xsl:when test="$red">
              <xsl:attribute name="fill">rgb(255, <xsl:value-of select="255-round(255 * $red div 100)" />, <xsl:value-of select="255-round(255 * $red div 100)" /> )</xsl:attribute>
            </xsl:when>
            <xsl:otherwise>
              <xsl:attribute name="fill">rgb(100, 100, 100)</xsl:attribute>
            </xsl:otherwise>
          </xsl:choose>
          <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Publicité

gilou

Modérateur
Modosaurus Rex

C'est clairement l'appel
select="$communes//fn:map[@key=$insee]/fn:number[@key='HOLL_PRES_2012']"
qui reparcourt ton arbre a chaque svg:polygon qui va être lent. Les // c'est coûteux en temps.

Il y a peut-être moyen de ne faire qu'une passe et indexer avec un xsl:key.
Par contre, il y a manifestement des bouts de code que tu n'as pas donné, car je ne comprends pas des choses comme:
fn:number[@key='HOLL_PRES_2012']
fn:number est une fonction, donc ca devrait etre qque chose comme fn:number(...)
Si tu expliques un peu mieux ce que tu veux faire, je devrais être en mesure de t'aider (si je trouve le temps, car la j'ai moi aussi plein de code xsl a écrire.)
On dirait du MarkLogic, tes fn:map et fn:number.

A+,

Message édité par gilou le 28-02-2017 à 16:55:50

---------------
There's more than what can be linked! -- Le capitaine qui ne veut pas obéir à la carte finira par obéir aux récifs. -- No jab ? No job ! -- (╯°□°)╯︵ ┻━┻

Profil supprimé

Merci pour ta réponse gilou,

En réponse à ta première remarque, j'ai modifié un peu le code

Code :

<xsl:stylesheet version="2.0"
    <xsl:variable name="communes" select="document('../communes.xml')/fn:map"/>
...
       <xsl:variable name="red" select="$communes/fn:map[@key=$insee]/fn:number[@key='NON_TCE']" />

Le code de communes.xml est généré automatiquement (de json en XML via basex)

Code :

<map xmlns="http://www.w3.org/2005/xpath-functions">
  <map key="89370">
    <number key="NONISTES_DROITE_PRES_2007">15.33</number>
    <number key="POUT_PRES_2012">1.92</number>
    <number key="BOVE_PRES_2007">0.70</number>
    <number key="NONISTES_2012">35.61</number>
    <number key="LEPE_PRES_2007">11.50</number>
    <number key="SCHI_PRES_2007">0.93</number>
    <number key="LAGU_PRES_2007">1.86</number>
    <number key="NON_TCE">59.08</number>
    <number key="SARK_PRES_2007">37.17</number>
    <number key="CHEM_PRES_2012">0.12</number>
    <number key="BAYR_PRES_2007">16.26</number>
    <number key="HOLL_PRES_2012">23.38</number>
    <number key="ARTH_PRES_2012">0.36</number>
    <number key="DUPO_PRES_2012">1.92</number>
    <number key="BUFF_PRES_2007">2.09</number>
    <number key="NIHO_PRES_2007">1.16</number>
    <number key="MELE_PRES_2012">10.67</number>
    <number key="BESA_PRES_2007">4.41</number>
    <number key="LEPE_PRES_2012">20.74</number>
    <number key="BAYR_PRES_2012">7.55</number>
    <number key="NONISTES_2007">22.76</number>
    <number key="VOYN_PRES_2007">0.70</number>
    <number key="OUI_TCE">40.92</number>
    <number key="NONISTES_DROITE_PRES_2012">22.66</number>
    <number key="ROYA_PRES_2007">20.56</number>
    <number key="JOLY_PRES_2012">2.16</number>
    <number key="SARK_PRES_2012">31.18</number>
    <number key="NONISTES_GAUCHE_PRES_2012">12.95</number>
    <number key="NONISTES_GAUCHE_PRES_2007">7.43</number>
    <number key="VILL_PRES_2007">2.67</number>
  </map>
etc.

Du coup comme tu le vois il y a un namespace dedans et si je n'utilise pas ce namespace fn: mes requêtes xpath échouent.
Du coup si c'est une partie du problème, je ne sais pas trop comment le régler :s

gilou

Modérateur
Modosaurus Rex

Ah! OK!
Mais ton namespace est bizarre alors: http://www.w3.org/2005/xpath-functions est le namespace des fonctions standard xpath, et a priori tu as ici des éléments, pas des fonctions.
Comme j'utilise SaxonEE et non Saxonb, je ne sais pas trop ce que c'est dans ton cas.

Bon, tu aurais xslt 3, tu pourrais utiliser les xsl:map, mais en xslt2, tu n'as que les xsl:key, et ils ne peuvent indexer que la source.

Ce que je ferais:
- importer tes deux fichier dans un englobant (technique comme ici par exemple) et passer celui ci comme source de données a ta feuille de style
- passer a la trappe ce qui vient de ../communes.xml qui ne sert qu'a créer un index dans ta feuille de style, index qui associe la valeur de fn:key au sous arbre fn:map
- faire une xsl:key qui indexe les elements map avec comme cle leur attribut key
<xsl:key name="citykey" match="lfn:map[@key]" use="@key"/>
- utiliser cette xsl:key dand ton <xsl:variable name="red" select="... afin de ne chercher la donnée que sur sa liste de number, ce qui est petit, et non sur tout $communes a chaque fois
<xsl:variable name="city" select="key('citykey', substring-before(@id, ' '))"/>
<xsl:variable name="red" select="$city/fn:number[@key='HOLL_PRES_2012']" />

A+,

---------------
There's more than what can be linked! -- Le capitaine qui ne veut pas obéir à la carte finira par obéir aux récifs. -- No jab ? No job ! -- (╯°□°)╯︵ ┻━┻

Profil supprimé

Merci beaucoup, super cette histoire de key, je fais ça demain!

gilou

Modérateur
Modosaurus Rex

Autre chose: éviter l'emploi de //
Dans le code initial,
$communes//fn:map[@key=$insee]/fn:number[@key='HOLL_PRES_2012']
passe en
$communes/fn:map/fn:map[@key=$insee]/fn:number[@key='HOLL_PRES_2012']
aurait sans doute été un poil plus efficace

Sinon, après avoir parlé avec le guru XML de ma boite, il y a une astuce avec key permettant de l'utiliser sur un document précis: c'est pas avec la définition xsl:key, mais a la première invocation avec le 3e paramètre.
Ça permet de se passer des contorsions indiquées vis a vis des fichiers comme indique dans mon post précédent.
Il suffit juste de transformer ton code comme suit:

Code :

<xsl:stylesheet version="2.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        xmlns:xs="http://www.w3.org/2001/XMLSchema"
        xmlns:doc="http://jlm2017.fr"
        xmlns:fn="http://www.w3.org/2005/xpath-functions"
        xmlns:dc="http://purl.org/dc/elements/1.1/"
        xmlns:cc="http://creativecommons.org/ns#"
        xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
        xmlns:svg="http://www.w3.org/2000/svg"
        xmlns="http://www.w3.org/2000/svg"
        xmlns:xlink="http://www.w3.org/1999/xlink"
        xmlns:sodipodi="http://sodipodi.sourceforge.net/DTD/sodipodi-0.dtd"
        xmlns:inkscape="http://www.inkscape.org/namespaces/inkscape"
        inkscape:version="0.48.2 r9819"
        sodipodi:docname="circonscriptions.svg"
        exclude-result-prefixes="xs doc">
  <xsl:output method="xml" indent="yes"/>

  <xsl:param name="communes" select="document('../communes.xml')"/>
  <xsl:key name="citykey" match="fn:map[@key]" use="@key"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="svg:polygon">
    <xsl:variable name="insee" select="substring-before(./@id, ' ')" />
    <xsl:variable name="city" select="key('citykey', substring-before(@id, ' '), $communes)"/>
    <xsl:variable name="red" select="$city/fn:number[@key='HOLL_PRES_2012']" />
    <xsl:copy>
      <xsl:choose>
    <xsl:when test="$red">
      <xsl:attribute name="fill">rgb(255, <xsl:value-of select="255-round(255 * $red div 100)" />, <xsl:value-of select="255-round(255 * $red div 100)" /> )</xsl:attribute>
    </xsl:when>
    <xsl:otherwise>
      <xsl:attribute name="fill">rgb(100, 100, 100)</xsl:attribute>
    </xsl:otherwise>
      </xsl:choose>
      <xsl:apply-templates select="@*|node()" />
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

Et tu peux peut etre encore gagner un chouia de perf en ne calculant qu'une fois, dans une variable la valeur 255-round(255 * $red div 100) et en la réutilisant.

A+,

Message édité par gilou le 14-12-2017 à 23:30:05

---------------
There's more than what can be linked! -- Le capitaine qui ne veut pas obéir à la carte finira par obéir aux récifs. -- No jab ? No job ! -- (╯°□°)╯︵ ┻━┻

Profil supprimé

Merci beaucoup! Tu as répondu avant que je puisse m'y atteler à nouveau.
Ça marche du tonnerre!
J'avais jamais utilisé les key, XSL m'étonne toujours, vraiment très puissant

gilou

Modérateur
Modosaurus Rex

Et xsl 3, qui devrait passer au statut de "proposed recommendation" d'ici un mois environ est bien plus puissant encore (try/catch, iterate...) en particulier avec les fonctions xpath évoluées.

A+,

---------------
There's more than what can be linked! -- Le capitaine qui ne veut pas obéir à la carte finira par obéir aux récifs. -- No jab ? No job ! -- (╯°□°)╯︵ ┻━┻

FORUM HardWare.fr

Programmation

XML/XSL

XSLT très lent

Sujets relatifs
Aide SQL très simple	Code VBA trop lent
Idée Programation jeux video TRES COMPLEXE	remplacer des mots par des liens (XML to HTML via XSLT)
Une très bête question "and" comme "or"?	Bonnes pratiques pour une gestion de stocks très basique
Script très léger pour activer les touches du clavier ?	Recherche script de grid tres performant
Programme qui est de plus en plus lent	Très étrange problème de sheets.select
Plus de sujets relatifs à : XSLT très lent

Page générée en 0.092 secondes