Problème de sélection de feuille VBA

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : Problème de sélection de feuille VBA

sebval26

Bonjour à tous,

J'ai un problème avec la sélection de feuille que je n'avais pas avant. En fait j'en ai deux qui me semblent être lié.

1/ Jusqu'à il y a quelque jour lorsque je voulais sélectionner une cellule ou une plage dans une feuille différente de celle sélectionner j'utilisais la ligne de commande suivante :

Worksheets("XXX" ).Range("B2" ). select

Aujourd'hui je suis obligé de le faire en deux lignes :

Worksheets("XXX" ).select

Range("B2" ).select

Si je le fais en une ligne j'obtiens l'erreur 1004 : la méthode sélect de la classe range à échoué.
Quelqu'un saurais ttil m'expliquer le pourquoi du comment?

2/ J'ai fait ce code :

Code :

Sub Bouton5_Cliquer()
Dim Effectif_entreprise As Worksheet
Set Effectif_entreprise = Worksheets("Effectif entreprise" )
'recherche de la colonne contenant les intitulés d'emploi et détermination de la variable correspondant à la cellule
Dim Colonne_Emploi As Range
Set Colonne_Emploi = Effectif_entreprise.UsedRange.Find("Emploi" )
Dim Colonne_Service As Range
Set Colonne_Service = Effectif_entreprise.UsedRange.Find("Service" )
'Détermination de la plage de cellule correspondant aux intitulés d'emploi
Dim Liste_emploi As Range
Set Liste_emploi = Range(Cells(Colonne_Emploi.Row + 1, Colonne_Emploi.Column), Range(Colonne_Emploi.Address).End(xlDown))
Dim Liste_Service As Range
Set Liste_Service = Range(Cells(Colonne_Service.Row + 1, Colonne_Service.Column), Range(Colonne_Service.Address).End(xlDown))
'copier les intitulés de service dans la feuilles "effectif service" et supprimer les doublons
Worksheets("effectif entreprise" ).Select
Liste_Service.Copy
Sheets("Effectif service" ).Select
Range("D3" ).PasteSpecial xlPasteValues
ActiveSheet.Range("D3", Range("D3" ).End(xlDown)).RemoveDuplicates Columns:=1, Header:=xlNo
End Sub

Lorsque je teste la macro depuis l'éditeur en étant sur déjà sur la feuille "Effectif entreprise", la macro s’exécute parfaitement. mais lorsque je lance la macro en étant sur une autre feuille, il m'emmène sur la feuille "effectif service", toutes les cellule de la colonne D à partir de D3 sont sélectionnées, mais rien n'as été copié. J'ai l'impression qu'il ignore l'instruction sheets("effectif entreprise" ).select et je ne comprends pas pourquoi.

Je vous remercie d'avance de votre aide qui pourrait m'éviter une plus forte calvitie ;-)

Publicité

Marc L

Bonjour !

1/ L'unique ligne de code n'a aucun sens car pour pouvoir activer une cellule il faut d'abord activer la feuille !
Donc les deux lignes de code sont la seule voie à suivre …

2/ Je n'ai pas le temps de décrypter ce code tant il y a de l'inutile et du superflu mais, là encore,
il faut juste se poser la question quelle est la feuille active
lorsque une variable objet Range est attribuée en oubliant de spécifier la feuille !

Pour rappel : une bonne procédure VBA n'a pas besoin d'activer ni de sélectionner ni feuille ni cellule,
donc votre code devrait tenir en moins de dix lignes …

Message édité par Marc L le 06-03-2024 à 14:20:36

Marc L

Avec cinq minutes de plus que prévu, une démonstration sans l'inutile :

Code :

Sub Demo1()
Dim Rc As Range, V
Set Rc = Worksheets("Effectif entreprise" ).UsedRange.Find("Service" )
If Rc Is Nothing Then Beep: Exit Sub
V = Range(Rc(2), Rc.End(xlDown)).Value
Set Rc = Nothing
With Worksheets("Effectif service" ).[D3].Resize(UBound(V))
.Value = V
.RemoveDuplicates
End With
End Sub

Marc L

Une variante :

Code :

Sub Demo1v()
Dim Rg As Range
Set Rg = Worksheets("Effectif entreprise" ).UsedRange.Find("Service" )
If Rg Is Nothing Then Beep: Exit Sub
Set Rg = Range(Rg(2), Rg.End(xlDown))
With Worksheets("Effectif service" ).[D3].Resize(Rg.Count)
.Value = Rg.Value
.RemoveDuplicates
End With
Set Rg = Nothing
End Sub

Marc L

A noter avec une en-tête de colonne commune aux deux feuilles la copie des cellules et la suppression des doublons
peuvent être remplacées par une unique ligne de code juste en utilisant un filtre avancé !

FORUM HardWare.fr

Programmation

VB/VBA/VBS

Problème de sélection de feuille VBA

Sujets relatifs
[PHP] DATE : Problème de formatage	VBA /Excel emplacements approuvés
probleme requete sql	VBA word : recopie champs formulaire vers signet
Problème à résoudre	(Résolu) VBA Word et suppression de marques de paragraphe (lignes)
Probleme copier/coller entre Excel et Word	Problème Curdate et date du serveur sql
Select dans plusieurs BDD avec UNION - Problème de doublons	[Nginx] Problème URL rewritting via regex
Plus de sujets relatifs à : Problème de sélection de feuille VBA

Page générée en 0.072 secondes