[VBA]Numéro de colonne d'après son libellé

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : [VBA]Numéro de colonne d'après son libellé

BrisChri

Since 1956

J’ai une table Acess qui est une feuille excel.xlsx, ce xlsx est créé au départ d’un csv, ce csv est créé au départ de glpi.
L’ordre des colonnes du csv dépend de l’ordre des colonnes dans glpi et chacun peut organiser ces colonnes comme il veut (pas tout le monde, mais passons).
Résultat, la colonne 12 de l’un n’aura pas obligatoirement le même contenu que la colonne 12 du fichier créé par un autre…
Et je dois, dans une macro Excel, tripoter le contenu de certaines colonnes (ID par exemple) pour les rendre utilisables par Acess.
Pour l’instant, la macro utilise ceci :

Code :

nColID = 1
nColTitle = 2
nColEntity = 3
nColdOpen = 4
nColDescription = 5
nColStatus = 6
nColAssignedTech = 7
nColLinked = 8
nColRequester = 9
nColPriority = 10
nColAssignedGroup = 11
nColdUpdate = 12

Je m'en sers ainsi :

Code :

Cells(nLigne, nColID).Value = Val(Cells(nLigne, nColID))
Cells(nLigne, nColAssignedTech).Value = RTrim(LTrim(Cells(nLigne, nColAssignedTech)))
Cells(nLigne, nColLinked).Value = Val(Cells(nLigne, nColLinked))

J’aimerais remplacer ces valeurs fixes par
nColID = numéro de la colonne dont le titre est ID
nColAssignedTech = numéro de colonne dont le libellé est « Assigned to – Technician »
Je ne trouve pas la fonction qui le ferait.
Certains libellé de colonnes sont en plusieurs mots, ça facilite encore les choses, pire, quand il y a plusieurs mots, le premier peut être le même pour 2 colonnes (7 & 11 par exemple)

Message édité par BrisChri le 05-02-2016 à 10:39:06

---------------
Si une frite n'a pas de mayo, alors elle ne pourra pas aller à la piscine

Publicité

BrisChri

Since 1956

Je pense que RechercheV devrait convenir à ce que je veux faire
Je ne vois pas trop comment m'en servir en VBA
Si ça rend un range, je peux éclater le résultat (instruction split) pour séparer ligne et colonne
nCol = RechercheV(range(RangeLigneTitre); "ID" )
nColID = nCol
Le faire pour toutes les colonnes à modifier, boucler pour faire les modifs.

---------------
Si une frite n'a pas de mayo, alors elle ne pourra pas aller à la piscine

Chelmi18

Salut,

Tu peux effectivement le faire en VBA avec la fonction .Find

Code :

Col_TOTO = Sheets("maFeuille" ).Range("1:1" ).Find(What:="TOTO", after:=Cells(1, 1), LookIn:=xlFormulas, LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False).Column

Plus d'informations sur la syntaxe : http://www.commentcamarche.net/faq [...] la-syntaxe

BrisChri

Since 1956

Code :

Dim wb As Workbook
Dim ws As Worksheet
Dim rLib As Range
Dim rRes As Range
Dim nLigne As Long
Dim nMaxLigne As Long
Dim nCol As Long
Dim nMaxCol As Long
Dim nColID As Long
Dim nColLink As Long
Dim nColTech As Long
Sub maj_glpi()
Set wb = Workbooks.Open("\\GLPI\glpi2.xlsx" )
Set ws = wb.Worksheets(1)
nMaxCol = Cells(1, Columns.Count).End(xlToLeft).Column
nMaxLigne = Range("A" & Rows.Count).End(xlUp).Row
Set rLib = Range(Cells(1, 1), Cells(nMaxCol, 1))
Set rRes = Range(rLib).Find(what:="Assigned to - Technician", after:=Cells(1, 1), LookIn:=xlValues, LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False)
nColTech = Range(rRes).Adress.Column

Erreur '1004': la métode 'range' de l'objet _Global a échoué
ligne 23 en jaune fluo

Je ne vois pas où je faute

---------------
Si une frite n'a pas de mayo, alors elle ne pourra pas aller à la piscine

Marc L

Bonjour,

réalisable aussi via la fonction de feuille de calculs d'Excel EQUIV (cf l'aide d'Excel), Application.Match en VBA …

Exemple pour un bloc contigu de lignes et de colonnes à partir de la cellule A1 :

Code :

With Workbooks.Open("\\GLPI\glpi2.xlsx" ).Worksheets(1).Cells(1).CurrentRegion
V = Application.Match("ID", .Rows(1), 0)
If IsNumeric(V) Then nColID = V
End With

BrisChri

Since 1956

Je regarde ça lundi, oui, je suis déjà rentré.

Si je comprends ton code, ça devrait donner :

Code :

Dim vRes as variant
nColID = 0
nColTech = 0
nColLink = 0
...
activate cells(1,1) ' indispensable ? (pour le CurrentRegion vu qu'il y a du code avant)
with ws.Cells(1).CurrentRegion
vRes = Application.Match("ID", .Rows(1), 0)
If IsNumeric(vRes) Then nColID = vRes
vRes = Application.Match("Assigned to - Technician", .Rows(1), 0)
If IsNumeric(vRes) Then nColTech = vRes
vRes = Application.Match("??", .Rows(1), 0) ' je ne connais pas le texte par cœur
If IsNumeric(vRes) Then nColLink = vRes
end with
If (nColID <> 0) AND (nColTech <> 0) AND (nColLink <> 0)
for
...
netxt
end if

et si c'est bon, je peux supprimer mes définition rXXX as Range

:jap:

---------------
Si une frite n'a pas de mayo, alors elle ne pourra pas aller à la piscine

Marc L

La ligne de code n° 6 ne sert à rien et en général, Activate comme Select sont à proscrire …

CurrentRegion est juste un moyen simple de pointer sur une plage contigüe.
Et le reste du code devrait être à l'intérieur du bloc With …

Ligne n°15 : If nColID * nColTech * nColLink > 0 Then

BrisChri

Since 1956

:jap:

ça fonctionne bien, voici la version définitive

Code :

Option Explicit
Dim wb As Workbook
Dim ws As Worksheet
Dim nLigne As Long
Dim nMaxLigne As Long
Dim nCol As Long
Dim nMaxCol As Long
Dim vRes As Variant
Dim nColID As Long
Dim nColTitle As Long
Dim nColEntity As Long
Dim nColdOpen As Long
Dim nColDesc As Long
Dim nColStatus As Long
Dim nColTech As Long
Dim nColLink As Long
Dim nColReq As Long
Dim nColPriority As Long
Dim nColGroup As Long
Dim nColdUpd As Long
____________________________________________________________________________
Sub maj_glpi()
Set wb = Workbooks.Open("\\GLPI\glpi.xlsx" )
Set ws = wb.Worksheets(1)
nMaxCol = Cells(1, Columns.Count).End(xlToLeft).Column
nMaxLigne = Range("A" & Rows.Count).End(xlUp).Row
For nCol = 1 To nMaxCol
Cells(1, nCol).Value = LTrim(RTrim(Cells(1, nCol).Value))
Next nCol
With ws.Cells(1).CurrentRegion
vRes = Application.Match("ID", .Rows(1), 0)
If IsNumeric(vRes) Then nColID = vRes
vRes = Application.Match("Title", .Rows(1), 0)
If IsNumeric(vRes) Then nColTitle = vRes
vRes = Application.Match("Entity", .Rows(1), 0)
If IsNumeric(vRes) Then nColEntity = vRes
vRes = Application.Match("Opening date", .Rows(1), 0)
If IsNumeric(vRes) Then nColdOpen = vRes
vRes = Application.Match("Description", .Rows(1), 0)
If IsNumeric(vRes) Then nColDesc = vRes
vRes = Application.Match("Status", .Rows(1), 0)
If IsNumeric(vRes) Then nColStatus = vRes
vRes = Application.Match("Assigned to - Technician", .Rows(1), 0)
If IsNumeric(vRes) Then nColTech = vRes
vRes = Application.Match("Linked tickets - All", .Rows(1), 0)
If IsNumeric(vRes) Then nColLink = vRes
vRes = Application.Match("Requester", .Rows(1), 0)
If IsNumeric(vRes) Then nColReq = vRes
vRes = Application.Match("Priority", .Rows(1), 0)
If IsNumeric(vRes) Then nColPriority = vRes
vRes = Application.Match("Assigned to - Group", .Rows(1), 0)
If IsNumeric(vRes) Then nColGroup = vRes
vRes = Application.Match("Last update", .Rows(1), 0)
If IsNumeric(vRes) Then nColdUpd = vRes
End With
If nColID * nColTitle * nColEntity * nColdOpen * nColDesc * nColStatus * nColTech * nColLink * nColReq * nColPriority * nColGroup * nColdUpd > 0 Then
For nLigne = 2 To nMaxLigne
Cells(nLigne, nColID).Value = Val(Cells(nLigne, nColID))
Cells(nLigne, nColTech).Value = RTrim(LTrim(Cells(nLigne, nColTech)))
Cells(nLigne, nColLink).Value = Val(Cells(nLigne, nColLink))
Next nLigne
Else
MsgBox "Certaines colonnes sont manquantes" & Chr(10) & " " & Chr(10) & "Il faut modifier la vue dans GLPI et" & Chr(10) & "refaire l'extraction", vbCritical
End If
wb.Close savechanges:=True
End Sub

---------------
Si une frite n'a pas de mayo, alors elle ne pourra pas aller à la piscine

FORUM HardWare.fr

Programmation

VB/VBA/VBS

[VBA]Numéro de colonne d'après son libellé

Sujets relatifs
Fonction couper-coller VBA	[Excel] Incrémenter si doublon dans une colonne
Chronomètre en VBA	VBA Word prend son temps
Suppression de colonne d'une selection	Probleme compatibilité VBA MSFLEXGRID Excel 2013
Retourner une variable à un programme VBA appelant	VBA Word pile saturée
Code VBA trop lent	Conversion algorithme Python -> VBA (combinaisons de p élém. parmi n)
Plus de sujets relatifs à : [VBA]Numéro de colonne d'après son libellé

Page générée en 0.081 secondes