Aide modification d'un batch pour la carte reseau

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : Aide modification d'un batch pour la carte reseau

wsamael

Hello j'ai créer un point batch assez simple pour basculer d'un réseau a un autre simplement tout fonctionne bien mais voila maintenant j'aurais besoin de le faire évoluer car il se base sur le nom de la carte réseau hors en fonction d'ou je suis j'ai pas forcement le même adaptateur ( et donc le nom de carte réseau change) jusque la je changeait a chaque fois mais je voulais comment faire pour qu'un seul script gère les deux en fonction de la carte active? actuellement j'ai ceci mais il me faut soit le modifier soit deux script pour basculer a chaque fois de LAN a LAN 2 je me doute qu'il y a plsu simple mais je ne vois pas comment.

Code :

@echo off
set carte="LAN"
set adrfixe=192.168.1.65
set masque=255.255.255.0
set carte2="LAN"
set adrfixe2=10.0.10.3
set masque2=255.0.0.0
set carte3="LAN"
set adrfixe3=192.168.168.65
set masque3=255.255.255.0
set carte4="LAN"
set adrfixe4=10.1.10.11
set masque4=255.0.0.0
set passerelle4=10.1.10.12
set carte5="LAN"
set adrfixe5=192.168.0.11
set masque5=255.255.255.240
set passerelle5=192.168.0.1
set carte6="LAN"
set adrfixe6=172.31.255.100
set masque6=255.255.255.0
set passerelle6=172.31.255.1
set carte7="LAN"
set adrfixe7=192.168.1.10
set masque7=255.255.255.0
set passerelle7=192.168.1.1
set dns=8.8.8.8
set carte8="LAN"
set adrfixe8=192.0.2.11
set masque8=255.255.255.0
set passerelle8=192.0.2.1
:question
SET /P lan=Adressage IP 1/ DCHP 2/ 192.168.1.65 3/ 10.0.10.3 4/ 192.168.168.65 5/ 10.1.10.11 6/ 192.168.0.11 7/ 172.31.255.100 8/192.168.1.10 9/192.0.2.11 10/ QUITTER (1/2/3/4/5/6/7/8/9)? :
if %lan%==1 goto IPDHCP
if %lan%==2 goto IPfixe
if %lan%==3 goto IPfixe2
if %lan%==4 goto IPfixe3
if %lan%==5 goto IPfixe4
if %lan%==6 goto IPfixe5
if %lan%==7 goto IPfixe6
if %lan%==8 goto IPfixe7
if %lan%==9 goto IPfixe8
if %lan%==10 goto Nfin
goto question
:IPfixe8
SET /P lan=confirmer l'adressage en IP Fixe %adrfixe8% (O/N)? :
if %lan%==o goto OKFixe8
if %lan%==O goto OKFixe8
if %lan%==n goto Nfin
if %lan%==N goto Nfin
goto IPfixe8
:IPfixe7
SET /P lan=confirmer l'adressage en IP Fixe %adrfixe7% (O/N)? :
if %lan%==o goto OKFixe7
if %lan%==O goto OKFixe7
if %lan%==n goto Nfin
if %lan%==N goto Nfin
goto IPfixe7
:IPfixe6
SET /P lan=confirmer l'adressage en IP Fixe %adrfixe6% (O/N)? :
if %lan%==o goto OKFixe6
if %lan%==O goto OKFixe6
if %lan%==n goto Nfin
if %lan%==N goto Nfin
goto IPfixe6
:IPfixe5
SET /P lan=confirmer l'adressage en IP Fixe %adrfixe5% (O/N)? :
if %lan%==o goto OKFixe5
if %lan%==O goto OKFixe5
if %lan%==n goto Nfin
if %lan%==N goto Nfin
goto IPfixe5
:IPfixe4
SET /P lan=confirmer l'adressage en IP Fixe %adrfixe4% (O/N)? :
if %lan%==o goto OKFixe4
if %lan%==O goto OKFixe4
if %lan%==n goto Nfin
if %lan%==N goto Nfin
goto IPfixe4
:IPfixe3
SET /P lan=confirmer l'adressage en IP Fixe %adrfixe3% (O/N)? :
if %lan%==o goto OKFixe3
if %lan%==O goto OKFixe3
if %lan%==n goto Nfin
if %lan%==N goto Nfin
goto IPfixe3
:IPfixe2
SET /P lan=confirmer l'adressage en IP Fixe %adrfixe2% (O/N)? :
if %lan%==o goto OKFixe2
if %lan%==O goto OKFixe2
if %lan%==n goto Nfin
if %lan%==N goto Nfin
goto IPfixe2
:IPfixe
SET /P lan=confirmer l'adressage en IP Fixe %adrfixe% (O/N)? :
if %lan%==o goto OKFixe
if %lan%==O goto OKFixe
if %lan%==n goto Nfin
if %lan%==N goto Nfin
goto IPfixe
:OKFixe
netsh interface ipv4 set address %carte% static %adrfixe% %masque%
netsh inter ipv4 delete dnsservers LAN all > nul
goto Ofin
:OKFixe2
netsh interface ip set address %carte2% static %adrfixe2% %masque2%
netsh inter ip delete dnsservers LAN all > nul
goto Ofin
:OKFixe3
netsh interface ip set address %carte3% static %adrfixe3% %masque3%
netsh inter ip delete dnsservers LAN all > nul
goto Ofin
:OKFixe4
netsh interface ip set address %carte4% static %adrfixe4% %masque4% %passerelle4%
netsh inter ip delete dnsservers LAN all > nul
goto Ofin
:OKFixe5
netsh interface ip set address %carte5% static %adrfixe5% %masque5% %passerelle5%
netsh inter ip delete dnsservers LAN all > nul
goto Ofin
:OKFixe6
netsh interface ip set address %carte6% static %adrfixe6% %masque6% %passerelle6%
netsh inter ip delete dnsservers LAN all > nul
goto Ofin
:OKFixe7
netsh interface ip set address %carte7% static %adrfixe7% %masque7% %passerelle7%
netsh interface ip set address %carte7% dns %dns%
goto Ofin
:OKFixe8
netsh interface ip set address %carte8% static %adrfixe8% %masque8% %passerelle8%
netsh interface ip set address %carte8% dns %dns%
goto Ofin
:IPDHCP
SET /P lan=confirmer l'adressage en IP Dynamique (O/N)? :
if %lan%==o goto OKDHCP
if %lan%==O goto OKDHCP
if %lan%==n goto Nfin
if %lan%==N goto Nfin
goto IPDHCP
:OKDHCP
netsh interface ip set address %carte% dhcp
netsh inter ip delete dnsservers LAN all > nul
netsh inter ip set dnsservers LAN dhcp > nul
goto Ofin
:Nfin
@echo Aucune modification n'a ete appliquee
@echo -
SET /P lan=appuyez sur [ENTREE] pour quitter
goto fin
:Ofin
@echo La nouvelle configuration vient d'etre appliquee
@echo -
SET /P lan=appuyer sur [ENTREE] pour quitter
goto fin
:fin

Publicité

kyurakushunsui

Bonjour,
Voilà une version épurée de ton script, avec une ligne au début pour récupérer le nom du réseau :

Code :

@echo off
setlocal enableextensions enabledelayedexpansion
ver | find "10.0." >nul && chcp 65001 >nul || chcp 28591 >nul
color 0A
for /f "tokens=2 delims==" %%A in ('WMIC NIC WHERE ^(NetEnabled^=TRUE AND GUID is not Null^) GET NetConnectionID /FORMAT:LIST ^| findstr .') do if not defined carte set "carte=%%A"
if not defined carte (exit /b 1)
set static1=192.168.1.65;255.255.255.0;;;
set static2=10.0.10.3;255.0.0.0;;;
set static3=192.168.168.65;255.255.255.0;;;
set static4=10.1.10.11;255.0.0.0;10.1.10.12;;
set static5=192.168.0.11;255.255.255.240;192.168.0.1;;
set static6=172.31.255.100;255.255.255.0;172.31.255.1;;
set static7=192.168.1.10;255.255.255.0;192.168.1.1;8.8.8.8;
set static8=192.0.2.11;255.255.255.0;192.0.2.1;;
:question
cls
echo.-------------------------------------------------------------
echo.---------- CARTE RESEAU : "%carte%"
echo.-------------------------------------------------------------
set "lan="
set /p lan="Adressage IP 0/ DCHP 1/ 192.168.1.65 2/ 10.0.10.3 3/ 192.168.168.65 4/ 10.1.10.11 5/ 192.168.0.11 6/ 172.31.255.100 7/192.168.1.10 8/192.0.2.11 9/ QUITTER (0/1/2/3/4/5/6/7/8/9)? : "
if not defined lan (goto question)
timeout /t 1 /nobreak >nul
echo.
if "%lan%"=="9" (goto Nfin)
if "%lan%"=="0" (
set "val="
set /p val="confirmer l'adressage en IP Dynamique (O/N)? : "
if /i "!val!"=="O" (goto OKDHCP) else (goto question)
)
call :configuration "!static%lan%!" && goto Ofin
goto question
:configuration
for /f "tokens=1-4 delims=;" %%A in ("%~1" ) do (
set "address=%%~A"
set "mask=%%~B"
set "gateway=%%~C"
set "dns=%%~D"
)
set "conf="
set /p conf="confirmer l'adressage en IP Fixe "!address!" (O/N)? : "
if not "%conf%"=="O" (exit /b 1)
netsh int ipv4 set address %carte% static !address! !mask! !gateway!
if defined dns (netsh int ipv4 set dnsservers "%carte%" static !dns! no) else (netsh int ipv4 delete dnsservers "%carte%" all >nul)
exit /b 0
:OKDHCP
netsh int ipv4 set address %carte% dhcp
netsh int ipv4 delete dnsservers %carte% all >nul
netsh int ipv4 set dnsservers %carte% dhcp >nul
:Ofin
echo.
@echo La nouvelle configuration vient d'etre appliquee
@echo -
SET /P quit=appuyer sur [ENTREE] pour quitter
exit
:Nfin
echo.
@echo Aucune modification n'a ete appliquee
@echo -
SET /P quit=appuyez sur [ENTREE] pour quitter
exit

FORUM HardWare.fr

Programmation

Shell/Batch

Aide modification d'un batch pour la carte reseau

Sujets relatifs
Batch modifier profil de couleur du parametre d'affichage	Aide pour REGEX (débutant)
[un agent de dialogue] Apprendre basé sur un réseau de neurones	Problème batch avec deux %time%
[PowerShell] Aide syntaxe PS et affichage de résultats byte/texte	Correction Batch
Aide creation d'un batch pour modifier la carte reseau
Plus de sujets relatifs à : Aide modification d'un batch pour la carte reseau

Page générée en 0.074 secondes