Bonjour
je suis nouveau dans la programation en shell aussi je vous remercie par avance.
ma question est la suivante:  
j'ai un fichier avec un nom XYZ.xxx
a l'interieur de ce fichier j'ai plusieurs ligne de caracteres sous forme de blocs:
1er blocs
sabb 56 hfjgkfjsdh
xxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxx
xxxxxxxxxxxxxxxxxxxxxxxxxxxxx
nnnn
2eme blocs
ftnc 76 fhgjfgklsdls
yyyyyyyyyyyyyyyyyyyyyyyyy
yyyyyyyyyyyyyyyyyyyyyyyyy
yyyyyyyyyyyyyyyyyyyyyyyyy
nnnn
3eme blocs
xynz 87 fjhfjgkfldl
wwwwwwwwwwwwwwwwww
wwwwwwwwwwwwwwwwww
wwwwwwwwwwwwwwwwww
nnn
.
.
.
etc
x blocs de caracteresl
e fichier se termine sur le dernier blocs par nnnn
 
comment puis je extraire chaque x block de caractere commencant (par exmeple le 3eme blocs)
xynz 87 fjhfjgkfldl et finissant par nnnn ???? comment puis je egalement ecrire chacun de ces blocs dans des fichier texte dont les nom de chacun des ces fichiers sera la 1er ligne de caractere du bloc extrait ???
j'ai quelques idée mais je ne sais pas trop par ou commencer
merci par avance de l'aide fourni

je precise que je voudrais automatiser cette operation

Pourquoi vouloir faire ça en shell/batch? Il y a une contrainte spécifique?
Il y a tout un tas de langages interprétés comme perl, python, voire même awk qui me paraissent plus adaptés pour ce type de tache.
A+,

merci pour cette &er reponse
je ne connais pas perl mais awk oui, et je suis prenneur de toutes solutions.....

Bon alors, il faudrait nous expliquer comment un bloc est délimité dans le fichier:
Les blocs sont séparés par une ligne vide?
La première ligne d'un bloc c'est du texte, un blanc, des chiffres, un blanc, du texte?
La dernière ligne d'un bloc est "nnnn" pour tous les blocs?

A+,

alors la 1er ligne c'est obligatoirement 6 lettre, 1 espace, 2 chiffre, 1 espace, 6 lettres
les ligne suivantes sont aleatoirement des chiffres et des lettres avec des espaces
la derniere ligne de chaque block est obligatoirement: nnnn
voili voila

oups desolé j'oubliais, il y a une ligne vide entre chaque block (apres le nnnn ou avant la 1er ligne de chaque block de données)

Désolé, une coupure de courant pendant que je rédigeais ma réponse vers 13h30 m'avait arrété dans mes élans.
 
Voici un exemple de solution possible en perl, a adapter a ses besoins:
 

#!/usr/bin/perl
#fichier blocksfile.pl
use strict;
use warnings;
use autodie qw(open close);   # open/close succeed or die
 
my $filename = "blocksfile.txt"; #nom du fichier en entrée
open my $fh, '<', $filename;
my $savedprefix = "savedblock"; #préfixe des fichiers sauvés
my $savedfh;
my $inblock = 0; #flag pour savoir si la ligne est dans un bloc ouvert
my $numblock = 0; # compte des débuts de blocs rencontrés
while (<$fh> ) {
  if (/^.{6}\s\d{2}\s.{6}$/o) { #pattern de ligne pour 6 caracteres, un blanc, deux chiffres, un blanc, 6 caracteres
    if ($inblock) { # on a trouvé un début alors qu'on est déja dans un bloc ouvert
      print "Warning: Block $numblock incorrectly closed:skipped\n";
      close $savedfh;
      unlink $savedprefix.$numblock.".txt"; #on efface le fichier de bloc incorrect
    }
    # bon on est maintenant prêt a traiter le cas de rencontre d'un nouveau bloc
    $inblock = 1; # flag mis à 1
    $numblock++; # cpteur incrémenté
    open $savedfh, '>', $savedprefix.$numblock.".txt"; # on ouvre un nouveau fichier de block à sauver
    binmode $savedfh; # mode binaire à tout hasard, comme je ne connais pas tes données
    print $savedfh $_; # on écrit la ligne dans le fichier de block à sauver (pas clair si ca doit être fait dans ton cas)
  }
  elsif (/^nnnn$/) {
    if ($inblock) { # on a rencontré une fin de block pour un block ouvert
      print $savedfh $_; # on écrit la ligne dans le fichier de block à sauver (pas clair si ca doit être fait dans ton cas)
      close $savedfh; #on ferme le fichier
      $inblock = 0; #on positionne le flag a 0
    }
    # et traitement en erreur sinon?
  }
  elsif ($inblock) { #ligne standard dans un bloc ouvert
    print $savedfh $_; # on écrit la ligne dans le fichier de block à sauver
  }
}
close $fh;
if ($inblock) {
  print "Warning: Block $numblock incorrectly closed:skipped\n";
  close $savedfh;
  unlink $savedprefix.$numblock.".txt";
}

J'ai testé sur un fichier exemple blocksfile.txt

C:\Perl>perl blocksfile.pl
ça m'a donné trois fichiers en sortie:
savedblock1.txt

savedblock2.txt

savedblock3.txt

A+,

excellent je teste et te tiens au courrant.....merci  merci