bonjour
 
j'ai 2 fichiers: un est sur 2 colonnes et un autre sur 3 colonnes.
fichier 1 est de la forme: trou    profondeur
                                  trX      12
                                  trY      45
                                  trZ      01
                                  trA      152
                                  trB      78
                                  trC      13
le fichier 2 est lui de la forme trou1    trou2      distance
                                        trA       trX         03
                                        trZ       trC         89
                                        ..........................
je voudrais pouvoir obtenir ceci pour:
trou1    trou2      distance  profondeur(trou1)     profondeur(trou2)
 trA       trX         03           152                           12
 trZ       trC         89            01                            13
   .......................................................................
 
la question que je me pose est: ce calcul est il possible ?
 

Bien sur, c'est juste de la combinaison d'infos, il n'y a pas de calcul.
Adapter ceci s'il ne convient pas totalement:

#!/usr/bin/perl
use strict;
use warnings;
use autodie;
 
open my $fhin, "<", 'ftrou1.txt';
my %infos;
while (<$fhin> ) {
  next if $. < 2;         # a supprimer si pas d'en tête au fichier
  if (/^\s*(\S+)\s+(\d+)\s*$/) {
    $infos{$1} = $2;
  }
}
close $fhin;
 
open $fhin, "<", 'ftrou2.txt';
open my $fhout, ">", 'ftrou3.txt';
print $fhout "trou1\ttrou2\tdistance\tprofondeur(trou1)\tprofondeur(trou2)\n"; # a supprimer si pas d'en tête au fichier
while (<$fhin> ) {
  next if $. < 2;         # a supprimer si pas d'en tête au fichier
  if (/^\s*(\S+)\s+(\S+)\s+(\d+)\s*$/) {
    if (defined($infos{$1}) && defined($infos{$2})) {
      print $fhout "$1\t$2\t$3\t\t$infos{$1}\t\t\t$infos{$2}\n";
    }
  }
}
close $fhout;
close $fhin;

 
A+,

Ça fonctionne à merveille !  
Vous êtes mon héros
merci

Encore une petite question.
J'ai ajouté un petit calcul de logarithme comme ceci: log(($3)/(($infos{$1})*($infos{$1}))
 mais lorsque je vérifie les résultats je me rend compte qu'il est erroné    

La déjà, la formule a une parenthèse manquante:
log(($3)/(($infos{$1})*($infos{$1}))  -> log(($3)/(($infos{$1})*($infos{$1})))
Après, je ne sais pas ce que vous auriez aimé obtenir, alors...
Le log ici est le log naturel, pas celui en base 10.
 
A+,

Bonjour,
pour la parenthèse c'est une erreur de frappe et pour le moment je laisse de coté ce problème de logarithme.
j'ai un autre souci de "combinaison d'info". à partir de la donnée ci-dessous je veux pouvoir obtenir un tableau à 2 dimensions (une matrice) pour continuer le traitement sous matlab.
trou1    trou2      logarithme  
 trA       trX         -4.12            
 trZ       trC         -1.57
 trB       trA         -2.12
 trX      trZ         -3.45
..............................
 
le résultat recherché est:
          trA     trB      trC     trX     trZ
trA       0        0        0      -4.12   0
trB      -2.12    0        0      0        0
trC      0         0        0       0       0
trX      0         0        0       0      -3.45
trZ      0         0    -1.57     0       0
 
merci de m'aider

A adapter selon tes besoins:

#!/usr/bin/perl
use strict;
use warnings;
use autodie;
 
open my $fhin, "<", 'ftrou4.txt';
my %donnees;
while (<$fhin> ) {
  next if $. < 2;         # a supprimer si pas d'en tête au fichier
  if (/^\s*(\S+)\s+(\S+)\s+([-+]?\d+(\.\d+)?)\s*$/) {
    $donnees{$1}{$2}  = $3;
    $donnees{$2} //= (); # ou  $donnees{$2}{$1}  = $3; si la matrice est symmetrique
  }
}
close $fhin;
 
 
my @trous = sort(keys %donnees);
 
open my $fhout, ">", 'ftrou5.txt';
print $fhout "\t", join("\t", @trous), "\n";
foreach my $trou (@trous) {
  my $started = 0;
  foreach (@trous) {
    unless ($started) {
      print $fhout $trou;
      $started = 1;
    }
    print $fhout "\t";
    if (defined($donnees{$trou}) && defined($donnees{$trou}{$_})) {
      print $fhout $donnees{$trou}{$_};
    } else {
      print $fhout 0;
    }
  }
  print $fhout "\n";
}
close $fhout;

 
 
A+,

Ça marche !
Merci

Bonjour
 
j'ai à peu pres le meme probleme que morocco sauf que pour moi les entetes des lignes et colonnes sont définies auparavant et contiennent plus d'éléments que les variables à placer.
j'ai essayé d'adapter le programme de Gilou mais ma table n'affiche que des zeros.
j'espere que mon probleme est clair
svp c'est urgent

Bonjour Céline,  
Postes des extraits de chacun de tes fichiers source et du fichier résultat souhaité en sortie parce que sans indications plus précises, impossible de t'aider.
A+,

les fichiers sont volumineux, donc je vous donne juste un exemple:
fichier source:
        mot1   mot5  mot7
mot1     0       5    2
mot2     1       0    4
mot5     1       0    3
 
fichier de sortie:
        mot1   mot2  mot3  mot4  mot5  mot6   mot7
mot1     0       0       0       0       5       0       2
mot2     1       0       0       0       0       0       4
mot3     0       0       0       0       0       0       0
mot4     0       0       0       0       0       0       0
mot5     1       0       0       0       0       0       3
mot6     0       0       0       0       0       0       0
mot7     0       0       0       0       0       0       0
 

Dans le fichier source, il y a que mot1   mot5  mot7  dans un sens, et mot1   mot2  mot5 dans l'ordre.
Ils sont pêchés ou les  mot3  mot4  et mot6?
A+,

pardon pour l'erreur de frappe , je suis  bete    
le fichier source est:
        mot1   mot5  mot7  
mot1     0       5    2  
mot5     1       0    4  
mot7     1       0    3  
 
 
et le fichier sortie est:
       mot1   mot2  mot3  mot4  mot5  mot6   mot7  
mot1     0       0       0       0       5       0       2  
mot2     0       0       0       0       0       0       0  
mot3     0       0       0       0       0       0       0  
mot4     0       0       0       0       0       0       0  
mot5     1       0       0       0       0       0       4  
mot6     0       0       0       0       0       0       0  
mot7     1       0       0       0       0       0       3

c'est bon j'ai trouvé la solution. c'est un peu long mais ca me donne le bon résultat
Merci

Si je comprends bien, ton fichier source st une matrice, et tu veux construire une matrice plus importante a partir de celle la, en gardant les coeffs de départ et en mettant a 0 les autres.
Mais ou pêches-tu les noms (et leur ordre) de tes coeffs?
 
Pour ton exemple, a toi d'adapter si nécessaire, un truc dans ce genre peut le faire:
 

#!/usr/bin/perl
use strict;
use warnings;
use autodie;
 
open my $fhin, "<", 'indata25.txt';
my @cols;
my %donnees;
while (<$fhin> ) {
  if ($. == 1) {
    @cols = split;
    next;
  }
  else {
    my @lines = split;
    my $line = shift @lines;
    foreach (@cols) {
      $donnees{$line}{$_} = shift @lines;
    }
  }
}
close $fhin;
 
my ($prefix, $maxval);
foreach (@cols) {
  if (/^(.*?)(\d+)$/) {
    unless (defined $prefix) {
      $prefix = $1;
      $maxval = $2;
    }
    if ( $1 ne $prefix) {
      die "Incorrect column prefix : $_ not $prefix!";
    }
    if ($2 > $maxval) {
      $maxval = $2;
    }
  }
  else {
    die "Incorrect column name: $_!";
  }
}
 
 
open my $fhout, ">", 'outdata25.txt';
foreach (1..$maxval) {
  print $fhout "\t".$prefix.$_;
}
print $fhout "\n";
foreach my $l (1..$maxval) {
  print $fhout $prefix.$l;
  foreach my $c (1..$maxval) {
    print $fhout "\t";
    if (defined $donnees{$prefix.$l}{$prefix.$c}) {
      print $fhout $donnees{$prefix.$l}{$prefix.$c};
    }
    else {
      print $fhout 0;
    }
  }
  print $fhout "\n";
}
 
close $fhout;

Bon, c'est codé à vue et testé sur ton exemple, on doit pouvoir améliorer un peu la lisibilité de tout cela.
 
A+,