Perl

[Résolu] XML::DOM Comment récupérer une donnée?

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : [Résolu] XML::DOM Comment récupérer une donnée?

Sethenssen

Bonjour,

Voici mon fichier source:

Code :

<?xml version="1.0" encoding="UTF-8"?>
<File>
<track type="General">
<ID_String>0 (0x0)</ID_String>
<CompleteName>Files_Encoded.ts</CompleteName>
<Format>MPEG-TS</Format>
<FileSize_String>594 MiB</FileSize_String>
</track></File>

Ici mon script:

Code :

#!/usr/bin/perl -w
use strict;
use warnings;
use XML::DOM;
#************************************************************
# GlobalVariables
my $OUTFILE;
my $OUTDIR;
my $parser;
my $doc;
my @content;
my $element;
my $TFILE;
my $id_cont;
#************************************************************
# Script Starting...
$OUTDIR = "/cygdrive/d/_.compil/";
$OUTFILE = "Test.xml";
$parser = new XML::DOM::Parser();
$doc = $parser->parsefile ($OUTFILE);
print "$OUTDIR"."$OUTFILE"."\n\n";
@content = $doc->getElementsByTagName ("track" );
foreach $element (@content)
{
$id_cont = $element->getAttribute ("type" );
$TFILE = $element->toString();
print $id_cont . "\n";
}
$doc->dispose;
__END__

J'arrive a récupérer la track "General"
Mais je n'arrive pas à récupérer par exemple le nom de fichier Files_Encoded.ts appartenant au tag CompleteName

Comment faire?

Merci d'avance.

Message édité par Sethenssen le 22-09-2011 à 10:18:22

Publicité

gilou

Modérateur
Modzilla

Code :

@content = $doc->getElementsByTagName ("CompleteName" );
print $content[0]->getFirstChild()->toString();

A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Sethenssen

Merci Gilou !
Tu m'enlèves une épine du pied.

Que signifie le [0] ?
A quoi sert-il?

Encore merci.

gilou

Modérateur
Modzilla

@content est un array, comme le @ initial l'indique.
les éléments de cet array sont $content[0], $content[1], ... $content[n] (bon ici, comme le tableau n'a qu'un élément, c'est réduit à $content[0]). Comme les éléments d'un array sont des scalaires, on a un $ devant le nom et non pas un @.
C'est assez déconcertant au départ, quand on apprend le perl, que ça soit pas @content[0], @content[1], ... @content[n] mais $content[0], $content[1], ... $content[n] pour les éléments de l'array, mais on s'y fait.
Noter que dans le prochaine version de Perl, Perl6, dont la release n'a pas de date estimée depuis qques années, mais qui progresse pas mal ces temps ci, on reviendra a la notation intuitive @content[0], @content[1], ... @content[n].

Comme tu as vu, après l'appel à getElementsByTagName ("CompleteName" ), je fais un getFirstChild() sur le premier nœud, parce que le texte est dans un "nœud texte", premier fils du nœud CompleteName.
Ça se voit pas quand le noeud contient que du texte, mais ça se voit quand il a du contenu mixte, comme un
<nœudA>du texte<nœudB>blabla</nœudB>encore du texte</nœudA>
ou nœudA a 3 nœuds fils, un nœud Texte, un nœudB, et un second nœud Texte.
A+,

Message édité par gilou le 22-09-2011 à 10:49:31

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Sethenssen

Encore merci pour tes explications Gilou.

J'essaye maintenant d'aller encore plus loin dans les étapes de vérification.
Il se peut par exemple que l'attribut CompleteName n'existe pas dans l'XML que je vais traiter, et cela je ne le sais pas à l'avance.

Du coup j'essaye d'implémenter un "if exist; alors" je récupère la valeur.
Ceci pour éviter les messages du genre "Can't call method "getFirstChild" on an undefined value"

Voici ce que j'ai fais, mais cela ne fonctionne pas.
Dans tout les cas il m'affiche mon print

Code :

if (defined $doc->getElementsByTagName ("CompleteName" ) )
{
@tab = $doc->getElementsByTagName ("CompleteName" );
$CompleteName = $tab[0]->getFirstChild()->toString();
print "$CompleteName\n";
}

Sethenssen

C'est bon ce que j'ai fais fonctionne
Cependant je ne sais pas si c'est la bonne méthode ou bien si on peut faire plus court.

Voici le code:

Code :

foreach $element (@track)
{
$_ = $ligne;
$type = $element->getAttribute ("type" );
$ligne = $element->toString();
if($type eq "General" )
{
$chk=1;
@tab = $doc->getElementsByTagName ("CompleteName" );
if (defined $tab[0])
{
print "OK\n";
$CompleteName = $tab[0]->getFirstChild()->toString();
@tab = split/\\/,$CompleteName;
$CompleteName = $tab[2];
print "$CompleteName\n";
}
else
{
print "KO\n";
$CompleteName="";
}
}
}

Message édité par Sethenssen le 22-09-2011 à 11:27:10

Sethenssen

J'ai un autre problème

Dans le fichier source plus bas, j'ai dans différentes "track type" la valeur format.
Selon comment je me place dans le tableau
$tab[0] = je récupère le format de General
$tab[1] = je récupère le format de Video etc...

Avec le code:

Code :

@tab = $doc->getElementsByTagName ("Format" );
$format = $tab[0]->getFirstChild()->toString();
print "$format\n";

Cependant, j'ai des fichiers qui n'ont pas de track type="Audio" streamid="2"
Du coup mon $tab[4] est inconnu car il n'existe pas.

Comment faire pour ne récupérer que le format du track type="Text" par exemple?
Ainsi si je ne récupère que celle là, mon tab aura toujours la valeur $tab[0].
Et avec un "defined" je suis sauvé.

Avez-vous une astuce?

Fichier Source:

Code :

<?xml version="1.0" encoding="UTF-8"?>
<Encoded>
<File>
<track type="General">
<CompleteName>Video01.ts</CompleteName>
<Format>MPEG-TS</Format>
</track>
<track type="Video">
<Format>MPEG Video</Format>
</track>
<track type="Audio" streamid="1">
<Format>MPEG Audio</Format>
</track>
<track type="Audio" streamid="2">
<Format>MPEG Audio</Format>
</track>
<track type="Text">
<Format>Ceefax</Format>
</track>
</File>
</Encoded>

Message édité par Sethenssen le 22-09-2011 à 13:21:43

gilou

Modérateur
Modzilla

Citation :

if (defined $tab[0])

C'est plus logique de regarder si @tab a des éléments.
if (scalar(@tab))
ou ce qui est équivalent et plus simple,
if (0 + @tab)
l'addition forçant l'interprétation de @tab comme un scalaire qui est évalué comme son nombre d'éléments.

Citation :

Comment faire pour ne récupérer que le format du track type="Text" par exemple?

Comme tu l'as fait pour l'attribut General plus haut
Tu testes la valeur de l'attribut type sur ton element.
my $typeval = $tab[0]->getAttribute("type" );
if ($typeval eq "Text" ) ...

A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Sethenssen

Merci Gilou,

Malheureusement cela ne fonctionne pas.
Soit la valeur $typeval est vide, soit le tab[] contient toujours l'une des 4 valeurs précédentes (celle de General, Video etc...)

Je ne sais pas où cela coince,
Ci-dessous mon code

Code :

@track = $doc->getElementsByTagName ("track" );
foreach $element (@track)
{
$_ = $ligne;
$type = $element->getAttribute ("type" );
if($type eq "General" )
{
$chk=1;
@tab = $doc->getElementsByTagName ("FileName" );
if (0+@tab)
{
print "OK\n";
$CompleteName = $tab[0]->getFirstChild()->toString();
@tab = split/\\/,$CompleteName;
$CompleteName = $tab[0];
print "$CompleteName\n";
} else {
print "KO\n";
$CompleteName="";
}
}
if($type eq "Text" )
{
$chk=5;
@tab = $doc->getElementsByTagName ("Format" );
$Text_Codec = $tab[0]->getFirstChild()->toString();
@tab = $doc->getElementsByTagName ("Format" );
my $typeval = $tab[0]->getAttribute("type" );
print "$typeval\n";
$format = $tab[1]->getFirstChild()->toString();
print "$format\n";
}
}

Message édité par Sethenssen le 22-09-2011 à 15:19:48

gilou

Modérateur
Modzilla

Je comprends pas ce que tu cherches à faire.
Quelque chose comme ceci?

Code :

#!/usr/bin/perl
 
use strict;
use warnings;
use XML::DOM;
 
my $parser = new XML::DOM::Parser();
my $doc = $parser->parsefile('Test.xml');
my @tracks = $doc->getElementsByTagName('track');
foreach my $track (@tracks) {
  my $type = $track->getAttribute('type');
  if ($type eq "Text" ) {
    my @format = $track->getElementsByTagName('Format');
    if (0 + @format) {
      print $format[0]->getFirstChild()->toString();
    }
  }
}
$doc->dispose;

A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Publicité

Sethenssen

C'est exactement ça Gilou !

Milles merci

J'ai encore du progrès à faire

Sethenssen

Bonjour,

J'ai de nouveau un problème pour récupérer une donné à l'intérieur d'un XML avec XML::DOM

J'arrive à récupérer les premiers champs de la balise Content (cf XML ci-dessous)

Code :

my @content = $doc->getElementsByTagName ("Content" );
foreach $element (@content) {
            $id_cont = $element->getAttribute ("id" );
            $title_cont = $element->getAttribute ("title" );
}

Cependant je n'arrive pas à récupérer par exemple le champ "Definition" et le champ "fileName" de Media

Je me heurte à des messages d'erreur tel que:
Can't call method "getAttribute" on an undefined value
Can't call method "getFirstChild" on an undefined value

Quelle est la bonne logique là dessus?

Code :

<Content id="TST10428" title="Il était une fois" duration="3600" action="override">
    <EpgDescription locale="fr_FR">
      <EpgElement key="Title">Il était une fois</EpgElement>
      <EpgElement key="Synopsis"></EpgElement>
      <EpgElement key="Description"/>
      <EpgElement key="Copyright">©</EpgElement>
      <EpgElement key="ShortTitle">Il était une fois</EpgElement>
    </EpgDescription>
    <EpgDescription>
      <EpgElement key="Aspect">4:3</EpgElement>
      <EpgElement key="Definition">SD</EpgElement>
      <EpgElement key="AudioMode">Nicam Stereo</EpgElement>
      <EpgElement key="IsRecordable">0</EpgElement>
      <EpgElement key="Year">1998</EpgElement>
      <EpgElement key="Countries">FR</EpgElement>
      <EpgElement key="Categories">Humour</EpgElement>
      <EpgElement key="Rating">0</EpgElement>
      <EpgElement key="Actors"></EpgElement>
      <EpgElement key="Directors"></EpgElement>
      <EpgElement key="Producers"></EpgElement>
      <EpgElement key="Studio"></EpgElement>
      <EpgElement key="Language">fra</EpgElement>
      <EpgElement key="PromoImage">image.jpg</EpgElement>
      <EpgElement key="BestSalesIndex"/>
    </EpgDescription>
    <Media id="TST60626" title="Il était une fois" fileName="test.mpg" frameDuration="90000" fileSize="1" comment="comment" action="override"/>
  </Content>

Merci d'avance.

gilou

Modérateur
Modzilla

Premier cas:
1) tu fais une recherche des éléments de tag EpgElement (a partir de quoi, ça dépend de comment tu veux organiser cela en sortie: ça peut être a partir d'un noeud Content, d'un noeud EpgDescription etc)
2) pour chacun de ces éléments, tu vérifies si il a l'attribut key de valeur la valeur que tu cherches, par exemple définition
3) si oui, tu récupères le contenu du premier fils (le noeud texte) de l'élément

my @Contents = $doc->getElementsByTagName ('Content');
foreach my $Content (@Contents) {
my @EpgElements = $Content->getElementsByTagName ('EpgElement');
foreach my $EpgElement (@EpgElements) {
next if ($EpgElement->getAttribute('key') ne 'Definition');
my $definition = $EpgElement->getFirstChild()->getNodeValue();
................
}
}

Second cas, tu récupères directement la valeur de l'attribut en testant si c'est pas une chaine vide:
my @Medias = $doc->getElementsByTagName ('Media');
foreach my $Media (@Medias) {
my $fname = $Media->getAttribute('fileName');
if ($fname ne "" ) {
............
}
}

A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Sethenssen

Merci Gilou,
Je trépigne d'impatience de tester cela

Sethenssen

Bonjour,
Merci Gilou c'est parfait.

J'ai une dernière requête, je me heurte à un problème de boucle foreach.
Précédemment tu avais qu'une balise "Content", maintenant j'ai une balise "Content" et une balise "VodItem" qui sont reliées toutes deux par un id commun (Content id= et le ContentRef).

J'essaye simplement de récupérer les données du même film dans ces 2 balises.
Voici l'exemple de 2 films:

Code :

<VODContentProvider id="TST" name="TEST" scheduleDate="2011-12-26T10:54:34Z">
<Content id="TST15815" title="Titre film 01" duration="5940" action="override">
    <EpgDescription locale="fr_FR">
      <EpgElement key="Title">Titre film 01</EpgElement>
      <EpgElement key="ShortTitle">Titre film 01</EpgElement>
    </EpgDescription>
    <EpgDescription>
      <EpgElement key="Definition">SD</EpgElement>
      <EpgElement key="PromoImage">15815.jpg</EpgElement>
    </EpgDescription>
    <Media id="TST190334" title="Titre film 01" fileName="15815_3800.mpg" frameDuration="148500" fileSize="1" comment="comments" action="override"/>
  </Content>
<Content id="TST15812" title="Titre film 02" duration="6960" action="override">
    <EpgDescription locale="fr_FR">
      <EpgElement key="Title">Titre film 02</EpgElement>
      <EpgElement key="ShortTitle">Titre film 02</EpgElement>
    </EpgDescription>
    <EpgDescription>
      <EpgElement key="Definition">SD</EpgElement>
      <EpgElement key="PromoImage">15812.jpg</EpgElement>
    </EpgDescription>
    <Media id="TST193011" title="Titre film 02" fileName="test02.mpg" frameDuration="174000" fileSize="1" comment="comments" action="override"/>
  </Content>
<VodItem id="TST190334" action="override" title="Titre film 01" broadcasterId="TST" contentRef="TST15815" previewDate="2011-11-30T12:00:01Z" nodeRefList="TSTFRA1002">
    <EpgDescription locale="fr_FR">
      <EpgElement key="Title">Titre film 01</EpgElement>
      <EpgElement key="DisplayPriority">100</EpgElement>
    </EpgDescription>
    <Period start="2011-12-31T12:00:01Z" end="2012-11-30T00:00:00Z"/>
  </VodItem>
<VodItem id="TST193011" action="override" title="Titre film 02" broadcasterId="TST" contentRef="TST15812" previewDate="2011-11-30T12:00:01Z" nodeRefList="TSTFRA1002">
    <EpgDescription locale="fr_FR">
      <EpgElement key="Title">Titre film 02</EpgElement>
      <EpgElement key="DisplayPriority">100</EpgElement>
    </EpgDescription>
    <Period start="2011-12-31T12:00:01Z" end="2012-12-31T00:00:00Z"/>
  </VodItem>
</VODContentProvider>

Ici, je veux récupérer:
- le content id
- le titre du film
- la définition du film
- le nom de sa jaquette
- le voditem contentRef (qui est identique au content id)
- le voditem id
- la date de fin

Pour me donner en résultat final cet écran:

Code :

TST15815|Titre film 01|SD|15815.jpg|TST15815|TST190334|2012-11-30T00:00:00Z
TST15812|Titre film 02|SD|15812.jpg|TST15812|TST193011|2012-12-31T00:00:00Z

Hors, quand je rajoute le tableau @Periods j'obtiens:

Code :

TST15815|Titre film 01|SD|15815.jpg|TST15815|TST190334|2012-11-30T00:00:00Z
TST15815|Titre film 01|SD|15815.jpg|TST15815|TST190334|2012-12-31T00:00:00Z
TST15812|Titre film 02|SD|15812.jpg|TST15812|TST193011|2012-11-30T00:00:00Z
TST15812|Titre film 02|SD|15812.jpg|TST15812|TST193011|2012-12-31T00:00:00Z

C'est le fait de faire un foreach sur la @Periods qui je pense ne vas pas car il me donne chacun des dates de chacun des films alors qu'une seule est la bonne.
Pourtant je vérifie que je suis dans le "bon" @VodItems avec mon "if" mais cela n'a pas l'air de fonctionner.

Bref je ne suis pas sûr d'être clair car c'est assez difficile à expliquer, ce que je souhaite c'est de récupérer la bonne date du bon film tout en gardant les précédent champ.

Ci-dessous mon code.

Code :

#!/usr/bin/perl -w
use strict;
use warnings;
 
use XML::DOM;
 
my $SCRIPT_DIR="/cygdrive/d/_.compil/can/";
print $SCRIPT_DIR."\n\n";
 
opendir C_DIR, "$SCRIPT_DIR" or die "Message : $!\n";
my @INPUT_FILES = grep /.*\.xml/ , readdir C_DIR;
foreach my $files (@INPUT_FILES)    {
    my $parser = new XML::DOM::Parser();
    my $doc;
    eval { $doc = $parser->parsefile($SCRIPT_DIR.$files); } ;
    if ($@) {
        print "WARNING:       $files:                    not well-formed\n";
        next;
    }
    print "Traitement de: $files\n";
    my @Contents = $doc->getElementsByTagName ("Content" );
    foreach my $Content (@Contents) {
        my $id_cont = $Content->getAttribute ("id" );
        my $title_cont = $Content->getAttribute ("title" );
        my @EpgElements = $Content->getElementsByTagName ('EpgElement');
        foreach my $EpgElement (@EpgElements) { 
            next if ($EpgElement->getAttribute('key') ne 'Definition');
            my $definition = $EpgElement->getFirstChild()->getNodeValue();
            foreach my $EpgElement (@EpgElements) { 
                next if ($EpgElement->getAttribute('key') ne 'PromoImage');
                my $promo_image = $EpgElement->getFirstChild()->getNodeValue();
                my @VodItems = $doc->getElementsByTagName ("VodItem" );
                foreach my $VodItem (@VodItems) {
                    my $voditem_contRef = $VodItem->getAttribute ("contentRef" );
                    my $voditem_id = $VodItem->getAttribute ("id" );
                    if ($voditem_contRef eq $id_cont) {
                        my @Periods = $doc->getElementsByTagName ("Period" );
                        foreach my $Period (@Periods) {
                            my $enddate = $Period->getAttribute ("end" );
                            print "$id_cont|$title_cont|$definition|$promo_image|$voditem_contRef|$voditem_id|$enddate\n";
                        }
                    }
                }
            }
        }
    }
    $doc->dispose;
}
__END__

Message édité par Sethenssen le 28-12-2011 à 10:29:23

gilou

Modérateur
Modzilla

:hello:

Déjà une chose:
Quand tu veux ça

Citation :

Ici, je veux récupérer:
- le content id
- le titre du film
- la définition du film
- le nom de sa jaquette
- le voditem contentRef (qui est identique au content id)
- le voditem id

par record, il faut créer un hash perl pour stocker les valeurs, avec l'id comme clef, ça saute aux yeux.

J'ai la crève, alors je tacherai de te repondre cet aprem.

A+,

Message édité par gilou le 28-12-2011 à 12:36:57

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

gilou

Modérateur
Modzilla

Tiens, voici comment faire en passant par un hash (ou plutôt un hash de hash en fait)

Code :

#!/usr/local/bin/perl
 
use strict;
use warnings;
 
use XML::DOM;
 
my $parser = XML::DOM::Parser->new();
my $doc = $parser->parsefile('VOD.xml');
my %record;
my @Contents = $doc->getElementsByTagName ('Content');
foreach my $Content (@Contents) {
  my $id = $Content->getAttribute('id');
  my @EpgElements = $Content->getElementsByTagName ('EpgElement');
  foreach my $EpgElement (@EpgElements) {
    $record{$id}{$EpgElement->getAttribute('key')} = $EpgElement->getFirstChild()->getNodeValue();
  }
}
my @VodItems = $doc->getElementsByTagName ('VodItem');
foreach my $VodItem (@VodItems) {
  my $id = $VodItem->getAttribute('contentRef');
  $record{$id}{'Vodid'} = $VodItem->getAttribute('id');
  my @Periods = $VodItem->getElementsByTagName ('Period');
  $record{$id}{'end'} = $Periods[0]->getAttribute('end');
}
$doc->dispose;
 
foreach my $id (reverse (sort (keys %record))) {
  print $id, "|",
    $record{$id}{'Title'}, "|",
    $record{$id}{'Definition'}, "|",
    $record{$id}{'PromoImage'}, "|",
    $id, "|",
    $record{$id}{'Vodid'}, "|",
    $record{$id}{'end'}, "\n";
}

C:\Perl>perl VOD.pl
TST15815|Titre film 01|SD|15815.jpg|TST15815|TST190334|2012-11-30T00:00:00Z
TST15812|Titre film 02|SD|15812.jpg|TST15812|TST193011|2012-11-30T00:00:00Z

Bon, c'est a améliorer en tenant compte des tests a effectuer si les attributs id ou contentRef sont absents, ou que @Periods n'est pas vide.
Ca suppose que pour un content donné, il n'y a qu'un seul VodItem tels que le contentRef du VodItem = le id du Content, sinon ça ne marchera pas et il faudra faire une variante un tout petit peu plus compliquée avec un hash pour les Contents et un pour les VodItems.

A+,

Message édité par gilou le 28-12-2011 à 15:13:40

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Sethenssen

Merci Gilou !
Je vais tester cela de ce pas

Cependant je vois que dans ton résultat la date est identique alors qu'on devrait avoir une au 30/11 et l'autre au 31/12

gilou

Modérateur
Modzilla

Oui, je venais justement de voir ça dans mes tests.
C'estr un copier coller un peu trop hatif.
Remplacer
my @Periods = $doc->getElementsByTagName ('Period');
par
my @Periods = $VodItem->getElementsByTagName ('Period');
A+,

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

gilou

Modérateur
Modzilla

Bon, sinon, si tu peux avoir plusieurs VodItems referençant un même Content, il faudrait un code du style suivant:

Code :

#!/usr/local/bin/perl
 
use strict;
use warnings;
 
use XML::DOM;
 
my $parser = XML::DOM::Parser->new();
my $doc = $parser->parsefile('VOD.xml');
my %record;
my @Contents = $doc->getElementsByTagName ('Content');
foreach my $Content (@Contents) {
  my $id = $Content->getAttribute('id');
  my @EpgElements = $Content->getElementsByTagName ('EpgElement');
  foreach my $EpgElement (@EpgElements) {
    $record{$id}{$EpgElement->getAttribute('key')} = $EpgElement->getFirstChild()->getNodeValue();
  }
}
my %vrecord;
my @VodItems = $doc->getElementsByTagName ('VodItem');
foreach my $VodItem (@VodItems) {
  my $id = $VodItem->getAttribute('id');
  $vrecord{$id}{'contentRef'} = $VodItem->getAttribute('contentRef');
  my @Periods = $VodItem->getElementsByTagName ('Period');
  $vrecord{$id}{'end'} = $Periods[0]->getAttribute('end');
}
$doc->dispose;
 
foreach (reverse (sort (keys %vrecord))) {
  my $id = $vrecord{$_}{'contentRef'};
  print $id, "|",
    $record{$id}{'Title'}, "|",
    $record{$id}{'Definition'}, "|",
    $record{$id}{'PromoImage'}, "|",
    $id, "|",
    $_, "|",
    $vrecord{$_}{'end'}, "\n";
}

A+,

Message édité par gilou le 28-12-2011 à 14:51:11

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Sethenssen

Grand merci pour ton aide Gilou !
Je vais m'atteler à examiner tout cela.

Sethenssen

Cela fonctionne à la perfection.
Encore merci pour m'avoir débloqué.

Publicité

FORUM HardWare.fr

Programmation

Perl

[Résolu] XML::DOM Comment récupérer une donnée?

Sujets relatifs
[RESOLU] JQuery appel ajax, récuperer la valeur d'une selectbox	Récupérer valeur d'un select en fonction de son id
Comment récupérer le son d'une vidéo en texte	Conversion d'un fichier XML en fichier WXR
[VB] Modifier un fichier XML	Transformer du XML en WSDL avec XSLT ?
Comment récupérer la valeur choisie dans <select> ou <option>?	Afficher la derniere ligne entrée dans une base de donnée phpmyadmin
VBA CATIA V5 - Récupérer la langue de l'interface utilisateur
Plus de sujets relatifs à : [Résolu] XML::DOM Comment récupérer une donnée?

Page générée en 0.236 secondes