ASM

[Resolu] Interruption mode reel depuis mode protegé avec DPMI

Recherche :

Mot : Pseudo : Filtrer
Bas de page
Auteur	Sujet : [Resolu] Interruption mode reel depuis mode protegé avec DPMI

rocky77

Bonjour,

J'ai un programme en Borland Pascal 7 qui doit etre compilé en mode protégé. Dans ce programme, j'ai un appel a un interruption du mode réel. Donc j'ai besoin d'utiliser l'assembleur et les fonctions du DPMI.
Or mes connaissances en assembleur, DPMI et mémoire DOS sont proches du 0

J'ai trouvé dans les spécifications du DMPI, le "Simulate Real Mode Interrupt" 0300H. http://www.ctyme.com/intr/rb-5831.htm

J'ai même trouvé des exemples :

Code :

function Intr386(const int_number:byte; const stack_words:word;
var regs:DPMIRegisters) : word; assembler;
(* Make Real Mode interrupt while in Protected Mode. *)
asm
xor bx,bx { clear bx }
mov bl,int_number { load interrupt number }
mov cx,stack_words { get stack words }
les di,regs { load effective address of regs }
mov ax,0300h { function number 300h }
int 31h { call interrupt }
jc @pexit { if error jump to end of procedure }
xor ax,ax { clear ax; successful }
@pexit: { end of procedure }
end;

Code :

type DPMIRegisters = record { registers for DPMI int calls }
case byte of
1 : (EDI,ESI,EBP,EReserved,
EBX,EDX,ECX,EAX:longint;
Flags,ES,DS,FS,GS,
IP,CS,SP,SS:word);
2 : (DI,XDI,SI,XSI,BP,XBP,Reserved,
XReserved,BX,XBX,DX,XDX,CX,XCX,
AX,XAX:word);
3 : (DIL,DIH,XDIL,XDIH,
SIL,SIH,XSIL,XSIH,
BPL,BPH,XBPL,XBPH,
ReservedL,ReservedH,
XReservedL,XReservedH,
BL,BH,XBL,XBH,
DL,DH,XDL,XDH,
CL,CH,XCL,XCH,
AL,AH,XAL,XAH,
FlagsL,FlagsH,
ESL,ESH,DSL,DSH,FSL,FSH,
GSL,GSH,IPL,IPH,CSL,CSH,
SPL,SPH,SSL,SSH:byte);
end;

Mais voilà, le hic c'est que je dois faire passer lors de mon appel à mon interruption $65, la structure suivante, qui de plus contient des buffers !!

Code :

Type
urbtype = Record
transaction_token: byte (* control (2Dh), in (69h), out (E1h) as hex code *);
chain_end_flag : byte {another urb follow this urb in memory? zero=no,one=yes};
dev_add : byte;
end_point : byte;
error_code : byte;
status : byte (* returned by dosuhci *);
transaction_flags: word (* reserved *);
buffer_off : word (* for in/out *);
buffer_seg : word (* for in/out *);
buffer_length : word (* for in/out *);
actual_length : word (* for in/out *);
setup_buffer_off : word (* for control *);
setup_buffer_seg : word (* for control *);
start_frame : word (* reserved *);
nr_of_packets : word (* iso *);
int_interval : byte (* reserved *);
error_count : byte (* reserved *);
timeout : word (* reserved *);
next_urb_off : word (* reserved *);
next_urb_seg : word (* reserved *);
end (* 32 byte long *);

Code :

Procedure do_out; (* To PIC *)
Var
Reg: Registers;
Begin
(* set up out request *)
urb.transaction_token := $E1;(* $E1= Sortie*)
urb.chain_end_flag := 0;
urb.dev_add := the_dev_add;
urb.end_point := out_endpoint;
urb.error_code := 0;
urb.status := 0;
urb.transaction_flags := 0;
urb.buffer_off := ofs(buffer_o);
urb.buffer_seg := seg(buffer_o);
urb.buffer_length := packetlen;
urb.actual_length := 64;
urb.setup_buffer_off := 0;
urb.setup_buffer_seg := 0;
urb.start_frame := 0;
urb.nr_of_packets := 0;
urb.int_interval := 0;
urb.error_count := 0;
urb.timeout := 0;
urb.next_urb_off := 0;
urb.next_urb_seg := 0;
(* now call DosUHCI *)
Reg.DS := seg(urb);
Reg.DX := ofs(urb);
Intr($65, Reg); (*NE FONCTIONNE PAS EN MODE PROTEGE*)
Inc(ReqNr);
End (* do_out *);

Bref ça fait 2 semaines que je suis dessus et que je mouline. N'hesitez pas a me poser des questions. J'ai toujours des difficultés pour arriver à etre clair.

Merci

Message édité par rocky77 le 25-11-2015 à 00:15:50

Publicité

bjone

Insert booze to continue

Alors je regarderais ce que j'ai dans mes archives.
Comme je disais en MP, ça fait 15 ans que j'ai pas fait ça

bjone

Insert booze to continue

Une doc un peu plus claire:
http://www.delorie.com/djgpp/doc/dpmi/api/310300.html

Message édité par bjone le 20-11-2015 à 14:59:29

rocky77

J'avais deja reperé cette doc.

Je vais tenter par faire un truc simple.

Code :

asm
mov ah, 2Ch //Fonction 2Ch Gettime
int 21h //Dos Int.
mov hour, CH
mov minut, CL
end;
writeln('Heure',hour,':',minut);

Ce code fonctionne car dmpi converti automatiquement l'interruption en mode reel.(automatic mirroring of interrupts into real mode by DMPI). Donc je vais essayer de refaire ce code comme si DMPI ne prenait pas en charge cette conversion, et du coup essayer d'utiliser le 300h (simulation interruption mode reel)...Toute aide est le bienvenue

Message édité par rocky77 le 20-11-2015 à 14:19:01

bjone

Insert booze to continue

Désolé, j'ai pas pris le temps de regarder dans mes archives.

Par contre du cas tu en es où ?
Tu fait ton appel dpmi et ça crashe ?

rocky77

J'en suis a essayer de comprendre comment faire pour allouer ma structure et mes buffer dans le bloc memoire dos.
Donc dans un premier temps, j'essaie avec l'exemple de la fonction gettime ou il n'a que la fonction 2Ch à passer.
Puis j’essaierais avec la fonction 09h (afficher du texte) qui necessite en plus de transferrer du texte.

Et si ca marche je continue avec ma structure et mes buffers.

Code :

Program heure;
USES CRT,dos, winapi;
type
DPMIRegisters = Record {Registers for DPMI int callst}
DPMI_EDI, DPMI_ESI, DPMI_EBP, EReserved,
DPMI_EBX, DPMI_EDX, DPMI_ECX, DPMI_EAX : longint;
DPMI_Flags, DPMI_ES, DPMI_DS, DPMI_FS, DPMI_GS,
DPMI_IP, DPMI_CS, DPMI_SP, DPMI_SS : word;
end;
var
hour, minute : shortint;
dcs : DPMIRegisters;
transfer_Buf_Seg: word;
transfer_Buf : word;
function Intr386(const int_number:byte; const stack_words:word;
var regs:DPMIRegisters): word; assembler;
asm
xor bx, bx
mov bl, int_number
mov cx, stack_words
; mov dx, ds
; mov es, dx
les di,regs
mov ax, 0300h
int 31h
end;
BEGIN
asm
mov ax, 0100h
mov bx, 8
int 31h
mov [transfer_Buf], dx
mov [transfer_Buf_Seg], ax
mov word[dcs.DPMI_EAX], 2Ch
mov word[dcs.DPMI_EDX], 0
mov ax, [transfer_Buf_Seg]
mov word[dcs.DPMI_DS], ax
end;
writeln('debut appel');
intr386($21,0,dcs);
writeln('hour ',hour,':',minute);
END.

Je me retrouve avec une erreur d'allocation memoire

Message édité par rocky77 le 20-11-2015 à 16:00:14

bjone

Insert booze to continue

Si tu est bien en adressage flat 32bits, ça devrait être:

les edi, regs

mais lds sous-entends que "var regs:DPMIRegisters" devrait faire que "regs" résoudra vers une pointeur far de "dcs" en mode protégé (sélecteur 16bits:offset 32bits).

Si "regs" résous vers l'offset même de la structure "dcs" (sous-entendu par rapport à ds), alors il faut utiliser "lea edi,[dcs]".
(dans cas copier ds dans es, comme tu avais mis en commentaire)

rocky77

Première étape, la plus simple, enfin bonne. J'ai tout revu, je m’étais planté dans le placement de mon 2C.
J'arrive a récupérer l'heure système a partir d'une simulation d'interruption (300h)

Code :

Program tmem;
USES CRT,dos, winapi;
type
DPMIRegisters = Record {Registers for DPMI int callst}
DPMI_EDI, DPMI_ESI, DPMI_EBP, EReserved,
DPMI_EBX, DPMI_EDX, DPMI_ECX, DPMI_EAX : longint;
DPMI_Flags, DPMI_ES, DPMI_DS, DPMI_FS, DPMI_GS,
DPMI_IP, DPMI_CS, DPMI_SP, DPMI_SS : word;
end;
var
hour, minute : shortint;
dcs : DPMIRegisters;
transfer_Buf_Seg: word;
transfer_Buf : word;
selector, segment : word;
selseg :longint;
function Intr386(const int_number:byte; const stack_words:word;
var regs:DPMIRegisters): word; assembler;
asm
push es
push di
xor bx, bx
mov bl, int_number
mov cx, stack_words
les di,regs
mov ax, 0300h
int 31h
pop di
pop es
end;
BEGIN
dcs.DPMI_EAX := $00002C00; {fonction 2C de int $21}
dcs.DPMI_EDI := 0;
writeln('debut appel');
intr386($21,0,dcs);
hour:=word(dcs.DPMI_ECX SHR 8);
minute:=word(dcs.DPMI_ECX AND $00FF);
writeln('dcs = ',word(dcs.DPMI_ECX));
writeln('hour ',hour,':',minute);
repeat until keypressed;
END.

Prochaine étape. Essayer d'envoyer la structure suivante sur l'interruption $65. Ca attendra lundi

Code :

urb.transaction_token := $E1;(* $E1= Sortie*)
urb.chain_end_flag := 0;
urb.dev_add := the_dev_add; (* Adresse Microchip =1 si c'est le seul usb connecte à la carte mere*)
urb.end_point := out_endpoint; (* =1 *)
urb.error_code := 0;
urb.status := 0;
urb.transaction_flags := 0;
urb.buffer_off := ofs(buffer_o);
urb.buffer_seg := seg(buffer_o);
urb.buffer_length := packetlen;
urb.actual_length := 64;
urb.setup_buffer_off := 0;
urb.setup_buffer_seg := 0;
urb.start_frame := 0;
urb.nr_of_packets := 0;
urb.int_interval := 0;
urb.error_count := 0;
urb.timeout := 0;
urb.next_urb_off := 0;
urb.next_urb_seg := 0;

rocky77

J'ai vu sous Borland pascal une fonction qui me semble intéressante
GlobalDosAlloc qui me permet d'allouer un zone mémoire sous les 640k

Code :

var
selseg : longint;
segment, selector :word
.....
selseg := globaldosalloc (64) {64 bytes taille de l'espace memoire sous less 640k.}
selector := word(selseg and $FFFF); {conversion en word - le poids faible determine le selecteur pour utilisation mode protegé}
segment := word(selseg and SHR 16); {conversion en word - le poids fort determine le segment pour utilisation mode reel}

Mais là je ne sais pas trop comment m''y prendre. J'ai ma structure urb qui est actuellement en mémoire protegé. Il faudrait que je puisse la copier en mémoire réel ainsi que son contenu. Mais comment ?

Message édité par rocky77 le 23-11-2015 à 14:44:01

bjone

Insert booze to continue

GlobalDosAlloc ça permet effectivement de communiquer avec des services nécessitant des grosses structures en mémoire conventionnelle.

Après il y a un truc que je comprends pas : vu winapi et des registres -que- 16bits dans ton source, tu fais quoi avec BC7 ? un projet win16 ?

Ou alors ton projet est bien setupé pour du mode protégé (opérandes implicitement 32bits pour les même opcodes 16bits du mode réel), et tu utilises sciemment ce trick pour contourner les limites de BP7 ?

Normalement on faisait plutôt du DPMI pour un jeu/une démo sous à Dos à l'époque.

Si c'est pour attaquer un PIC en USB, normalement en Win32/64, tu as WinUSB & co...

Message édité par bjone le 23-11-2015 à 16:03:59

Publicité

rocky77

Oui c'est un projet qui doit tourner uniquement sous dos et qui doit obligatoirement être compilé en protected mode. Borland Pascal 7 sait gerer le DMPI.

Mon but est de pouvoir à partir de mon programme faire appel a un programme résident (un driver USB - DOSUSB.COM) via l'interruption 65 en envoyant la structure URB qui contient le segment et l'offset d'un buffer.

Tu me dis si je ne suis pas clair :pt1cable:

Je viens de trouver ça aussi, je vais voir si je peux m'en servir
ProtectedAddr := Ptr(L and $FFFF, 0);
Move( FontData, ProtectedAddr^, Size);

Edit : Ah qu'est ce que j'aurais voulu utliser WinUSB, ca m'aurait bien facilité la tache. Malheuresement, on m'impose BP7 (mon boss), Compilation en mode protected et bien sur que ca tourne sous dos, le vrai MS DOS

Message cité 1 fois
Message édité par rocky77 le 23-11-2015 à 16:13:22

rocky77

Je pense que je progresse, mais aussi que je me melange les pinceaux. J'ai toujours du mal avec les notions de segments, selector, offset ....malgré la lecture de documentation

Code :

Uses DOS, CRT, WINAPI;
Const
the_dev_add = 1; (*Adresse peripherique usb*)
in_endpoint = 1;
out_endpoint = 1; (* 2 avant *)
(* myFN = 'dosuhci.txt';*)
ATTENTE : INTEGER = 800 ;
type
DPMIRegisters = Record {Registers for DPMI int callst}
DPMI_EDI, DPMI_ESI, DPMI_EBP, EReserved,
DPMI_EBX, DPMI_EDX, DPMI_ECX, DPMI_EAX : longint;
DPMI_Flags, DPMI_ES, DPMI_DS, DPMI_FS, DPMI_GS,
DPMI_IP, DPMI_CS, DPMI_SP, DPMI_SS : word;
end;
(* define structure of URB *)
Type
urbtype = Record
transaction_token: byte (* control (2Dh), in (69h), out (E1h) as hex code *);
chain_end_flag : byte {another urb follow this urb in memory? zero=no,one=yes};
dev_add : byte;
end_point : byte;
error_code : byte;
status : byte (* returned by dosuhci *);
transaction_flags: word (* reserved *);
buffer_off : word (* for in/out *);
buffer_seg : word (* for in/out *);
buffer_length : word (* for in/out *);
actual_length : word (* for in/out *);
setup_buffer_off : word (* for control *);
setup_buffer_seg : word (* for control *);
start_frame : word (* reserved *);
nr_of_packets : word (* iso *);
int_interval : byte (* reserved *);
error_count : byte (* reserved *);
timeout : word (* reserved *);
next_urb_off : word (* reserved *);
next_urb_seg : word (* reserved *);
end (* 32 byte long *);
type
buffer = Array[0..255] Of Byte;
p_buffer = ^buffer;
Var
urb: urbtype;
buffer_o: Array[0..(*1024-1*)255] Of Byte;
buffer_i: Array[0..(*1024-1*)255] Of Byte;
packetlen: Word;
bStr: String;
f: File;
ReqNr: Word;
tab_out: Array[0..16] Of Byte; {To PIC}
tab_in: Array[0..32] Of Byte; {From PIC}
i,j,choix,val,quit_proc,quit_ok: integer;
SNOOPY, TEST_SNOOPY : BOOLEAN ;
selseg, selseg_buff :longint;
selector, selector_buff, segment, segment_buff : word;
P_PM : p_buffer;
P_PM_buff : p_buffer;
function Intr386(const int_number:byte; const stack_words:word;
var regs:DPMIRegisters): word; assembler;
asm
push es
push di
xor bx, bx
mov bl, int_number
mov cx, stack_words
les di,regs
mov ax, 0300h
int 31h
pop di
pop es
end;
{//////////////////////////// DO_OUT //////////////////////////////////}
Procedure do_out; { To PIC }
Var
DCS : DPMIRegisters;
Begin
selseg := globaldosalloc(40 );
selector := word(selseg and $FFFF);
segment := word(selseg SHR 16);
P_PM:=ptr(selector,0); {pointeur pour remplir ma structure dans la memoire <640k}
writeln('1 ');
selseg_buff := globaldosalloc(257);
selector_buff := word(selseg_buff and $FFFF);
segment_buff := word(selseg_buff SHR 16);
P_PM_buff:=ptr(selector_buff,0); {pointeur pour remplir mon buffer dans la memoire <640k}
writeln('2 - size de buffer_o = ',sizeof(buffer_o));
move(buffer_o,P_PM_Buff^,sizeof(buffer_o)); {copie des données du buffer dans la memoire <640k}
writeln('3 ',P_PM_Buff^[0],' ',P_PM_Buff^[1],' ',P_PM_Buff^[2]);
(* set up out request *)
urb.transaction_token := $E1;(* $E1= Sortie*)
urb.chain_end_flag := 0;
urb.dev_add := the_dev_add; (* Adresse Microchip =1 si c'est le seul usb connecte à la carte mere*)
urb.end_point := out_endpoint; (* =1 *)
urb.error_code := 0;
urb.status := 0;
urb.transaction_flags := 0;
urb.buffer_off := 0;(*ofs(P_PM_Buff^);*) {quoi mettre ??? ofs(P_PM_Buff^) ? 0? autre?}
urb.buffer_seg := selector_buff;(*(seg(P_PM_Buff^);*) {quoi mettre ??? seg(P_PM_Buff^) ? autre ?
urb.buffer_length := packetlen;
urb.actual_length := 64;
urb.setup_buffer_off := 0;
urb.setup_buffer_seg := 0;
urb.start_frame := 0;
urb.nr_of_packets := 0;
urb.int_interval := 0;
urb.error_count := 0;
urb.timeout := 0;
urb.next_urb_off := 0;
urb.next_urb_seg := 0;
(* now call DosUHCI *)
fillchar(dcs, sizeof(dcs), 0);
move(urb,P_PM^,sizeof(urb)); {copie des données de la struct. URB dans la memoire <640k}
writeln('4');
DCS.DPMI_ES := segment;{Est ce vraiment ca qu'il faut mettre}
DCS.DPMI_DS := seg(P_PM^); {Est ce vraiment ca qu'il faut mettre}
DCS.DPMI_EDX :=ofs(P_PM^);{Est ce vraiment ca qu'il faut mettre}
writeln('5');
intr386($65, 0, dcs);
GlobalDosFree(selector);
GlobalDosFree(selector_buff);
(* Reg.DS := seg(urb); {Ce que je cherche a remplacer depuis le debut !!!! Arghh}
Reg.DX := ofs(urb); {Ce que je cherche a remplacer depuis le debut !!!! Arghh}
Intr($65,Reg);*) {Ce que je cherche a remplacer depuis le debut !!!! Arghh}
Inc(ReqNr);
End (* do_out *);
(*//////////////////////////// MAIN ////////////////////////////////////*)
Begin
ReqNr:=0;
for i:=0 to 16 do tab_out[i]:=0;
tab_out[2] := 64;
packetlen:=17;
for i:=0 to 16 do buffer_o[i]:=tab_out[i];
do_out;
repeat until keypressed;
end. (* AXUSB.PAS *)

Message édité par rocky77 le 24-11-2015 à 10:55:53

Mackila

[:drapal]

rocky77

Probleme résolu !

Merci à tous, je posterais la soluce demain, tranquillement.

bjone

Insert booze to continue

rocky77 a écrit :

Edit : Ah qu'est ce que j'aurais voulu utliser WinUSB, ca m'aurait bien facilité la tache. Malheuresement, on m'impose BP7 (mon boss), Compilation en mode protected et bien sur que ca tourne sous dos, le vrai MS DOS

Dans un contexte professionnel, si c'est pour maintenir du vieux software utilisé en production je veux bien (typique de l'info indus), mais autrement ce serait plus sain de rebooter l'appli avec un outil moderne et pérenne.

rocky77

J'ai deja tenté de dire à mon boss qu'il serait temps de mettre à niveau le programme (qui doit bien avoir 50000 lignes de code). Mais il aime bien les vieux trucs et surtout veut pas se lancer dans cette mise à niveau.
Du coup, on se fait ch.., enfin je me fais ch... pour la maintenance de son programme indigeste :pt1cable: :fou:

bjone

Insert booze to continue

Le prob c'est que pour une réécriture d'un soft, il faut de la force de frappe.

Maintenant le premier truc à voir c'est le ratio code "fonctionnel" (ce qui est réellement utilie, ce qui traite vraiment de la donnée)/ code "inutile" (ce qui est imposé par les frameworks : ie par exemple les MFC sont responsables d'un gros tas de merde dans beaucoup de projets qui datent de la fin des années 90).

En réutilisant un framework moderne, tu élagues les lignes de caca en dégageant un gros volume de code useless. (ie Winforms vs MFC, etc...)

Bon là avec BP7, si vous voulez rester en Pascal pour pas perdre vos habitues, rebooter l'appli en Delphi (embarcadero) peut être une étape rentable : ça permettrait d'élaguer beaucoup de mochetés.

Spoiler :

Si vous êtes dans une PME, vous êtes typiquement verrouillés dans le soft écrit il y a 10 ans, que vous avez pas le budget pour le refacto, et que vous ferez une murale lorsqu'un concurrent refera un soft équivalent mais moderne, qui lui aussi repartira dans le cycle de 10~15ans avant de faire sprotch à son tour

Message édité par bjone le 25-11-2015 à 10:58:09

rocky77

Pour la forme, voici ma solution

Code :

function Intr386(const int_number:byte; const stack_words:word;
var regs:DPMIRegisters): word; assembler;
asm
push es
push di
xor bx, bx
mov bl, int_number
mov cx, stack_words
les di,regs
mov ax, 0300h
int 31h
pop di
pop es
end;
(*//////////////////////////// DO_OUT //////////////////////////////////*)
Procedure do_out; (* To PIC *)
Var
DCS : DPMIRegisters;
selseg, selseg_buff :longint;
selector, selector_buff, segment, segment_buff : word;
P_PM : p_buffer;
P_PM_buff : p_buffer;
Begin
selseg := globaldosalloc(40);
selector := word(selseg and $FFFF);
segment := word(selseg SHR 16);
P_PM:=ptr(selector,0);
selseg_buff := globaldosalloc(257);
selector_buff := word(selseg_buff and $FFFF);
segment_buff := word(selseg_buff SHR 16);
P_PM_buff:=ptr(selector_buff,0);
move(buffer_o,P_PM_Buff^,sizeof(buffer_o)); (*REMPLISSAGE AVEC POINTEUR PROTECTED VERS MEMOIRE AVEC DONNEES MODE REEL *)
(* set up out request *)
urb.transaction_token := $E1;(* $E1= Sortie*)
urb.chain_end_flag := 0;
urb.dev_add := the_dev_add; (* Adresse Microchip =1 si c'est le seul usb connecte à la carte mere*)
urb.end_point := out_endpoint; (* =1 *)
urb.error_code := 0;
urb.status := 0;
urb.transaction_flags := 0;
urb.buffer_off :=0; (* METTRE OFFSET A 0 *)
urb.buffer_seg := segment_buff; (* SEGMENT ADRESSE EN MODE REEL *)
urb.buffer_length := packetlen;
urb.actual_length := 64;
urb.setup_buffer_off := 0;
urb.setup_buffer_seg := 0;
urb.start_frame := 0;
urb.nr_of_packets := 0;
urb.int_interval := 0;
urb.error_count := 0;
urb.timeout := 0;
urb.next_urb_off := 0;
urb.next_urb_seg := 0;
(* now call DosUHCI *)
fillchar(dcs, sizeof(dcs), 0);
move(urb,P_PM^,sizeof(urb)); (*REMPLISSAGE AVEC POINTEUR PROTECTED VERS MEMOIRE AVEC DONNEES MODE REEL *)
DCS.DPMI_ES := 0;(*segment;*)
DCS.DPMI_DS := segment;(*ADRESSE SEGMENT MODE REEL DE MA STRUCTURE URB*)
DCS.DPMI_EDX := 0;
intr386($65, 0, dcs);
GlobalDosFree(selector);
GlobalDosFree(selector_buff);
(* Reg.DS := seg(urb);
Reg.DX := ofs(urb);
Intr($65,Reg);*)
Inc(ReqNr);
End (* do_out *);

FORUM HardWare.fr

Programmation

ASM

[Resolu] Interruption mode reel depuis mode protegé avec DPMI

Sujets relatifs
jena avec protégé	recuperer le nombre REEL de pixels d'un div
[C] Faire un mode multijoueur en ligne pour un jeu	Problème d'interruption externe sur PIC18
Interruption Timer 2 sur PIC18	Lancer iexplore en "mode caché" via un vbs ?
[C++ / Qt / Android] Mode debug qui ne fonctionne pas ?	[Ada] Ecrire un éditeur de texte en mode texte
Impossible d'ajouter une référence en mode admin	Bloquer le mode paysage (landscape) version mobile
Plus de sujets relatifs à : [Resolu] Interruption mode reel depuis mode protegé avec DPMI

Page générée en 0.124 secondes